source: BLFS/xsl/gen_pkg_list.xsl@ e576789

2.4 ablfs-more legacy new_features trunk
Last change on this file since e576789 was e576789, checked in by Pierre Labastie <pierre@…>, 11 years ago

Merge ablfs branch. Normally, jhalfs should not perform differently
for building LFS
  • Property mode set to 100644
File size: 14.1 KB
RevLine 
[e576789]1<?xml version="1.0" encoding="ISO-8859-1"?>
2
3<!-- $Id: gen_pkg_list.xsl 21 2012-02-16 15:06:19Z labastie $ -->
4<!-- Takes the blfs-full.xml file and extract a list
5 of packages obeying packdesc.dtd + looks for already
6 installed packages in the tracking file (stringparam
7 'installed-packages') -->
8
9<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
10 version="1.0">
11
12 <xsl:param name="installed-packages" select="'../lib/instpkg.xml'"/>
13
14 <xsl:output method="xml"
15 encoding='ISO-8859-1'
16 doctype-system="./packdesc.dtd"/>
17
18<!-- specialCases.xsl is generated by a shell script:
19 allows for cases where version begins with a letter
20 and when there is no version (such as xorg7 packages) -->
21 <xsl:include href="./specialCases.xsl"/>
22
23 <xsl:template match="/">
24 <princList>
25 <xsl:text>&#xA;&#xA;</xsl:text>
26<!-- How to have blfs-bootscripts versionned? Do not know, so
27 avoid it (TODO ?) -->
28 <xsl:apply-templates select="//part[not(@id='introduction')]"/>
29 </princList>
30 </xsl:template>
31
32 <xsl:template match="part">
33 <xsl:if test="count(.//*[contains(translate(@xreflabel,
34 '123456789',
35 '000000000'),
36 '-0')
37 ]) &gt; 0">
38 <xsl:text> </xsl:text>
39 <list>
40 <xsl:attribute name="id"><xsl:value-of select="@id"/></xsl:attribute>
41 <xsl:text>&#xA; </xsl:text>
42 <xsl:element name="name">
43 <xsl:value-of select="title"/>
44 </xsl:element>
45 <xsl:text>&#xA;&#xA;</xsl:text>
46 <xsl:apply-templates select="chapter"/>
47 <xsl:text> </xsl:text>
48 </list>
49 <xsl:text>&#xA;&#xA;</xsl:text>
50 </xsl:if>
51 </xsl:template>
52
53 <xsl:template match="chapter">
54 <xsl:if test="count(.//*[contains(translate(@xreflabel,
55 '123456789',
56 '000000000'),
57 '-0')
58 ]) &gt; 0">
59 <xsl:text> </xsl:text>
60 <sublist>
61 <xsl:attribute name="id"><xsl:value-of select="@id"/></xsl:attribute>
62 <xsl:text>&#xA; </xsl:text>
63 <xsl:element name="name">
64 <xsl:value-of select="title"/>
65 </xsl:element>
66 <xsl:text>&#xA;</xsl:text>
67 <xsl:apply-templates select=".//sect1[@xreflabel]">
68 <xsl:sort select="@id"/>
69 </xsl:apply-templates>
70 <xsl:text> </xsl:text>
71 </sublist><xsl:text>&#xA;&#xA;</xsl:text>
72 </xsl:if>
73 </xsl:template>
74
75 <xsl:template match="sect1">
76 <xsl:choose>
77<!-- This test is to find sections containing modules (PERL, Python
78 DBus,...) -->
79 <xsl:when
80 test="not(contains(translate(@xreflabel,
81 '123456789',
82 '000000000'),
83 '-0')) and
84 count(descendant::node()[contains(translate(@xreflabel,
85 '123456789',
86 '000000000'),
87 '-0')
88 ]) &gt; 0">
89 <xsl:text> </xsl:text>
90 <package><xsl:text>&#xA; </xsl:text>
91 <xsl:element name="name">
92 <xsl:value-of select="title"/>
93 </xsl:element>
94 <xsl:text>&#xA;</xsl:text>
95<!-- Do not use .//*, which would include self.
96 Calls the template of specialCases.xsl,
97 which calls the "normal" template when the
98 case is normal. -->
99 <xsl:apply-templates
100 select="descendant::node()[contains(translate(@xreflabel,
101 '123456789',
102 '000000000'),
103 '-0')
104 ]"
105 mode="special">
106 <xsl:sort select="@id"/>
107 </xsl:apply-templates>
108 <xsl:text> </xsl:text>
109 </package><xsl:text>&#xA;&#xA;</xsl:text>
110 </xsl:when>
111 <xsl:otherwise>
112<!-- Calls the template of specialCases.xsl,
113 which calls the "normal" template when the
114 case is normal. -->
115 <xsl:apply-templates select='.' mode="special">
116 <xsl:sort select="@id"/>
117 </xsl:apply-templates>
118 </xsl:otherwise>
119 </xsl:choose>
120 </xsl:template>
121
122 <xsl:template match="*" mode="normal">
123 <xsl:variable name="version">
124 <xsl:call-template name="version">
125 <xsl:with-param name="label" select="./@xreflabel"/>
126 </xsl:call-template>
127 </xsl:variable>
128 <xsl:choose>
129<!-- If there is a "sect1" ancestor, this means that
130 we have a module -->
131 <xsl:when test="ancestor::sect1">
132 <xsl:text> </xsl:text>
133 <module><xsl:text>&#xA; </xsl:text>
134 <xsl:element name="name">
135 <xsl:value-of select="./@id"/>
136 </xsl:element>
137 <xsl:text>&#xA; </xsl:text>
138 <xsl:element name="version">
139 <xsl:value-of select="$version"/>
140 </xsl:element>
141 <xsl:if
142 test="document($installed-packages)//package[name=current()/@id]">
143 <xsl:text>&#xA; </xsl:text>
144 <xsl:element name="inst-version">
145 <xsl:value-of
146 select="document(
147 $installed-packages
148 )//package[name=current()/@id]/version"/>
149 </xsl:element>
150 </xsl:if>
151<!-- Dependencies -->
152<!-- First the case of python modules or d-bus bindings -->
153 <xsl:if test="self::sect2">
154<!-- dependencies -->
155 <xsl:apply-templates select=".//para[@role='required' or
156 @role='recommended' or
157 @role='optional']"
158 mode="dependency"/>
159 </xsl:if>
160<!-- For python modules, the preceding module is an optional dep -->
161 <xsl:if test="ancestor::sect1[@id='python-modules']">
162 <xsl:apply-templates
163 select="preceding-sibling::sect2[@role='package']
164 //listitem[para/xref/@linkend=current()/@id]"
165 mode="prec-dep"/>
166 </xsl:if>
167<!-- Now the case of perl modules: let us test our XSLT abilities.
168 Well, "use the sibling, Luke" -->
169 <xsl:if test="self::bridgehead">
170 <xsl:apply-templates select="following-sibling::itemizedlist[1]
171 /listitem/itemizedlist/listitem"
172 mode="perlmod-dep">
173 <xsl:sort select="position()"
174 data-type="number"
175 order="descending"/>
176 </xsl:apply-templates>
177 </xsl:if>
178<!-- End dependencies -->
179 <xsl:text>&#xA; </xsl:text>
180 </module><xsl:text>&#xA;</xsl:text>
181 </xsl:when>
182 <xsl:otherwise>
183 <xsl:text> </xsl:text>
184 <package><xsl:text>&#xA; </xsl:text>
185 <xsl:element name="name">
186 <xsl:value-of select="./@id"/>
187 </xsl:element>
188 <xsl:text>&#xA; </xsl:text>
189 <xsl:element name="version">
190 <xsl:value-of select="$version"/>
191 </xsl:element>
192 <xsl:if
193 test="document($installed-packages)//package[name=current()/@id]">
194 <xsl:text>&#xA; </xsl:text>
195 <xsl:element name="inst-version">
196 <xsl:value-of
197 select="document(
198 $installed-packages
199 )//package[name=current()/@id]/version"/>
200 </xsl:element>
201 </xsl:if>
202<!-- Dependencies -->
203<!-- If in Xorg or KDE chapter, consider that the preceding package is
204 the first dependency (not always noted in the book) -->
205 <xsl:if test="ancestor::chapter[@id='kde4-core'] or
206 (ancestor::chapter[@id='x-window-system'] and
207 preceding-sibling::sect1[@id != 'xorg7'])">
208 <xsl:text>
209 </xsl:text>
210 <xsl:choose>
211 <xsl:when test="contains(preceding-sibling::sect1[1]/@id,
212 'xorg7-') and not(@id='printproto')">
213 <xsl:call-template name="expand-deps">
214 <xsl:with-param name="section">
215 <xsl:value-of select="preceding-sibling::sect1[1]/@id"/>
216 </xsl:with-param>
217 <xsl:with-param name="status" select="'required'"/>
218 </xsl:call-template>
219 </xsl:when>
220 <xsl:otherwise>
221 <xsl:element name="dependency">
222 <xsl:attribute name="status">required</xsl:attribute>
223 <xsl:attribute name="name">
224 <xsl:choose>
225 <xsl:when test="@id='printproto'">xorg-server</xsl:when>
226 <xsl:otherwise>
227 <xsl:value-of
228 select="preceding-sibling::sect1[1]/@id"/>
229 </xsl:otherwise>
230 </xsl:choose>
231 </xsl:attribute>
232 <xsl:attribute name="type">ref</xsl:attribute>
233 </xsl:element>
234 </xsl:otherwise>
235 </xsl:choose>
236 </xsl:if>
237 <xsl:apply-templates select=".//para[@role='required' or
238 @role='recommended' or
239 @role='optional']"
240 mode="dependency"/>
241<!-- End dependencies -->
242 <xsl:text>&#xA; </xsl:text>
243 </package><xsl:text>&#xA;</xsl:text>
244 </xsl:otherwise>
245 </xsl:choose>
246 </xsl:template>
247
248 <xsl:template name="version">
249 <xsl:param name="label" select="abc-2"/>
250 <xsl:variable name="start" select="string-length(substring-before(translate($label,'123456789','000000000'),'-0'))+2"/>
251 <xsl:variable name="prelim-ver" select="substring($label,$start)"/>
252 <xsl:choose>
253 <xsl:when test="contains($prelim-ver,'onfiguration')"/>
254 <xsl:when test="contains($prelim-ver,'escription')"/>
255 <xsl:when test="contains($prelim-ver,'EggDBus')">
256 <xsl:value-of select="substring-before($prelim-ver,' (EggDBus)')"/>
257 </xsl:when>
258 <xsl:when test="contains($label,'JDK')">
259 <xsl:value-of select="translate($prelim-ver,' ','_')"/>
260 </xsl:when>
261 <xsl:otherwise>
262 <xsl:value-of select="$prelim-ver"/>
263 </xsl:otherwise>
264 </xsl:choose>
265 </xsl:template>
266
267 <xsl:template match="para" mode="dependency">
268 <xsl:variable name="status" select="./@role"/>
269<!-- No ulink for now (see special case for Perl modules) -->
270 <xsl:for-each select="./xref">
271 <xsl:choose>
272 <xsl:when test="contains(@linkend,'xorg7-')">
273 <xsl:call-template name="expand-deps">
274 <xsl:with-param name="section">
275 <xsl:value-of select="@linkend"/>
276 </xsl:with-param>
277 <xsl:with-param name="status">
278 <xsl:value-of select="$status"/>
279 </xsl:with-param>
280 </xsl:call-template>
281 </xsl:when>
282 <xsl:otherwise>
283 <xsl:text>
284 </xsl:text>
285 <xsl:element name="dependency">
286 <xsl:attribute name="status">
287 <xsl:value-of select="$status"/>
288 </xsl:attribute>
289 <xsl:attribute name="name">
290 <xsl:value-of select="@linkend"/>
291 </xsl:attribute>
292 <xsl:attribute name="type">ref</xsl:attribute>
293 </xsl:element>
294 </xsl:otherwise>
295 </xsl:choose>
296 </xsl:for-each>
297 </xsl:template>
298
299 <xsl:template match="listitem" mode="prec-dep">
300 <xsl:if test="preceding-sibling::listitem">
301 <xsl:text>
302 </xsl:text>
303 <xsl:element name="dependency">
304<!-- the dep on the preceding package used to be required for python.
305 It seems optional now -->
306 <xsl:attribute name="status">optional</xsl:attribute>
307 <xsl:attribute name="name">
308 <xsl:value-of select="preceding-sibling::listitem[1]//@linkend"/>
309 </xsl:attribute>
310 <xsl:attribute name="type">ref</xsl:attribute>
311 </xsl:element>
312 </xsl:if>
313 </xsl:template>
314
315 <xsl:template match="listitem" mode="perlmod-dep">
316 <xsl:param name="glue" select="'&#xA; '"/>
317 <xsl:choose>
318 <xsl:when test="para/xref|para[@id]/ulink">
319 <xsl:value-of select="$glue"/>
320 <xsl:element name="dependency">
321 <xsl:attribute name="status">
322 <xsl:choose>
323 <xsl:when
324 test="count(./para/text()[contains(string(),
325 'ptional')
326 ]
327 )&gt;0">optional</xsl:when>
328 <xsl:otherwise>required</xsl:otherwise>
329 </xsl:choose>
330 </xsl:attribute>
331 <xsl:attribute name="name">
332 <xsl:if test="para/xref">
333 <xsl:value-of select="para/xref/@linkend"/>
334 </xsl:if>
335 <xsl:if test="para/ulink">
336 <xsl:value-of select="para/@id"/>
337 </xsl:if>
338 </xsl:attribute>
339 <xsl:attribute name="type">
340 <xsl:if test="para/xref">ref</xsl:if>
341 <xsl:if test="para/ulink">link</xsl:if>
342 </xsl:attribute>
343 <xsl:apply-templates select="itemizedlist/listitem"
344 mode="perlmod-dep">
345 <xsl:sort select="position()"
346 data-type="number"
347 order="descending"/>
348 <xsl:with-param name="glue" select="concat($glue,' ')"/>
349 </xsl:apply-templates>
350 </xsl:element>
351 </xsl:when>
352 <xsl:otherwise>
353 <xsl:apply-templates select="itemizedlist/listitem"
354 mode="perlmod-dep">
355 <xsl:sort select="position()"
356 data-type="number"
357 order="descending"/>
358 <xsl:with-param name="glue" select="$glue"/>
359 </xsl:apply-templates>
360 </xsl:otherwise>
361 </xsl:choose>
362 </xsl:template>
363
364</xsl:stylesheet>
Note: See TracBrowser for help on using the repository browser.