source: BLFS/xsl/scripts.xsl@ 24e2a6f

new_features
Last change on this file since 24e2a6f was 24e2a6f, checked in by Pierre Labastie <pierre@…>, 8 years ago

Fixes for BLFS porg:

  • add a special case for cacerts in packInstall.sh, so that a dummy version is generated, otherwise porgball does not work as intended
  • do not quote out apostrophes in scripts, when generating configuration instructions
  • Property mode set to 100644
File size: 20.7 KB
Line 
1<?xml version="1.0"?>
2
3<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
4 xmlns:exsl="http://exslt.org/common"
5 extension-element-prefixes="exsl"
6 version="1.0">
7
8<!-- $Id: scripts.xsl 34 2012-02-21 16:05:09Z labastie $ -->
9
10<!-- XSLT stylesheet to create shell scripts from "linear build" BLFS books. -->
11
12 <!-- Wrap "root" commands inside a wrapper function, allowing
13 "porg style" package management -->
14 <xsl:param name="wrap-install" select="'n'"/>
15
16 <!-- Build as user (y) or as root (n)? -->
17 <xsl:param name="sudo" select="'y'"/>
18
19 <xsl:template match="/">
20 <xsl:apply-templates select="//sect1"/>
21 </xsl:template>
22
23<!--=================== Master chunks code ======================-->
24
25 <xsl:template match="sect1">
26
27 <xsl:if test="@id != 'bootscripts'">
28 <!-- The file names -->
29 <xsl:variable name="filename" select="@id"/>
30
31 <!-- The build order -->
32 <xsl:variable name="position" select="position()"/>
33 <xsl:variable name="order">
34 <xsl:choose>
35 <xsl:when test="string-length($position) = 1">
36 <xsl:text>00</xsl:text>
37 <xsl:value-of select="$position"/>
38 </xsl:when>
39 <xsl:when test="string-length($position) = 2">
40 <xsl:text>0</xsl:text>
41 <xsl:value-of select="$position"/>
42 </xsl:when>
43 <xsl:otherwise>
44 <xsl:value-of select="$position"/>
45 </xsl:otherwise>
46 </xsl:choose>
47 </xsl:variable>
48
49 <!-- Depuration code -->
50 <xsl:message>
51 <xsl:text>SCRIPT is </xsl:text>
52 <xsl:value-of select="concat($order,'-z-',$filename)"/>
53 <xsl:text>&#xA; FTPDIR is </xsl:text>
54 <xsl:value-of select="$filename"/>
55 <xsl:text>&#xA;&#xA;</xsl:text>
56 </xsl:message>
57
58 <!-- Creating the scripts -->
59 <exsl:document href="{$order}-z-{$filename}" method="text">
60 <xsl:text>#!/bin/bash&#xA;set -e&#xA;&#xA;</xsl:text>
61 <xsl:choose>
62 <!-- Package page -->
63 <xsl:when test="sect2[@role='package']">
64 <!-- We build in a subdirectory, whose name may be needed
65 if using package management (see envars.conf), so
66 "export" it -->
67 <xsl:text>export PKG_DIR=</xsl:text>
68 <xsl:value-of select="$filename"/>
69 <xsl:text>&#xA;</xsl:text>
70 <!-- Download code and build commands -->
71 <xsl:apply-templates select="sect2"/>
72 <!-- Clean-up -->
73 <xsl:text>cd $SRC_DIR/$PKG_DIR&#xA;</xsl:text>
74 <!-- In some case, some files in the build tree are owned
75 by root -->
76 <xsl:if test="$sudo='y'">
77 <xsl:text>sudo </xsl:text>
78 </xsl:if>
79 <xsl:text>rm -rf $UNPACKDIR unpacked&#xA;&#xA;</xsl:text>
80 </xsl:when>
81 <!-- Non-package page -->
82 <xsl:otherwise>
83 <xsl:apply-templates select=".//screen"/>
84 </xsl:otherwise>
85 </xsl:choose>
86 <xsl:text>exit</xsl:text>
87 </exsl:document>
88 </xsl:if>
89 </xsl:template>
90
91<!--======================= Sub-sections code =======================-->
92
93 <xsl:template match="sect2">
94 <xsl:choose>
95 <xsl:when test="@role = 'package'">
96 <xsl:text>mkdir -p $SRC_DIR/$PKG_DIR&#xA;</xsl:text>
97 <xsl:text>cd $SRC_DIR/$PKG_DIR&#xA;</xsl:text>
98 <!-- Download information is in bridgehead tags -->
99 <xsl:apply-templates select="bridgehead[@renderas='sect3']"/>
100 <xsl:text>&#xA;</xsl:text>
101 </xsl:when>
102 <xsl:when test="@role = 'qt4-prefix' or @role = 'qt5-prefix'">
103 <xsl:apply-templates select=".//screen"/>
104 </xsl:when>
105 <xsl:when test="@role = 'installation'">
106 <xsl:text>
107find . -maxdepth 1 -mindepth 1 -type d | xargs </xsl:text>
108 <xsl:if test="$sudo='y'">
109 <xsl:text>sudo </xsl:text>
110 </xsl:if>
111 <xsl:text>rm -rf
112case $PACKAGE in
113 *.tar.gz|*.tar.bz2|*.tar.xz|*.tgz|*.tar.lzma)
114 tar -xvf $PACKAGE &gt; unpacked
115 UNPACKDIR=`grep '[^./]\+' unpacked | head -n1 | sed 's@^./@@;s@/.*@@'`
116 ;;
117 *.zip)
118 zipinfo -1 $PACKAGE &gt; unpacked
119 UNPACKDIR="$(sed 's@/.*@@' unpacked | uniq )"
120 if test $(wc -w &lt;&lt;&lt; $UNPACKDIR) -eq 1; then
121 unzip $PACKAGE
122 else
123 UNPACKDIR=${PACKAGE%.zip}
124 unzip -d $UNPACKDIR $PACKAGE
125 fi
126 ;;
127 *)
128 UNPACKDIR=$PKG_DIR-build
129 mkdir $UNPACKDIR
130 cp $PACKAGE $UNPACKDIR
131 ;;
132esac
133export UNPACKDIR
134cd $UNPACKDIR&#xA;
135</xsl:text>
136 <xsl:apply-templates select=".//screen | .//para/command"/>
137 <xsl:if test="$sudo = 'y'">
138 <xsl:text>sudo /sbin/</xsl:text>
139 </xsl:if>
140 <xsl:text>ldconfig&#xA;&#xA;</xsl:text>
141 </xsl:when>
142 <xsl:when test="@role = 'configuration'">
143 <xsl:apply-templates select=".//screen" mode="config"/>
144 </xsl:when>
145 </xsl:choose>
146 </xsl:template>
147
148<!--==================== Download code =======================-->
149
150 <!-- template for extracting the filename from an url in the form:
151 proto://internet.name/dir1/.../dirn/filename?condition.
152 Needed, because substring-after(...,'/') returns only the
153 substring after the first '/'. -->
154 <xsl:template name="package_name">
155 <xsl:param name="url" select="foo"/>
156 <xsl:param name="sub-url" select="substring-after($url,'/')"/>
157 <xsl:choose>
158 <xsl:when test="contains($sub-url,'/')">
159 <xsl:call-template name="package_name">
160 <xsl:with-param name="url" select="$sub-url"/>
161 </xsl:call-template>
162 </xsl:when>
163 <xsl:otherwise>
164 <xsl:choose>
165 <xsl:when test="contains($sub-url,'?')">
166 <xsl:value-of select="substring-before($sub-url,'?')"/>
167 </xsl:when>
168 <xsl:otherwise>
169 <xsl:value-of select="$sub-url"/>
170 </xsl:otherwise>
171 </xsl:choose>
172 </xsl:otherwise>
173 </xsl:choose>
174 </xsl:template>
175
176 <!-- Generates the code to download a package, an additional package or
177 a patch. -->
178 <xsl:template name="download-file">
179 <xsl:param name="httpurl" select="''"/>
180 <xsl:param name="ftpurl" select="''"/>
181 <xsl:param name="md5" select="''"/>
182 <xsl:param name="varname" select="''"/>
183 <xsl:variable name="package">
184 <xsl:call-template name="package_name">
185 <xsl:with-param name="url">
186 <xsl:choose>
187 <xsl:when test="string-length($httpurl) &gt; 10">
188 <xsl:value-of select="$httpurl"/>
189 </xsl:when>
190 <xsl:otherwise>
191 <xsl:value-of select="$ftpurl"/>
192 </xsl:otherwise>
193 </xsl:choose>
194 </xsl:with-param>
195 </xsl:call-template>
196 </xsl:variable>
197 <xsl:variable name="first_letter"
198 select="translate(substring($package,1,1),
199 'ABCDEFGHIJKLMNOPQRSTUVWXYZ',
200 'abcdefghijklmnopqrstuvwxyz')"/>
201 <xsl:text>&#xA;</xsl:text>
202 <xsl:value-of select="$varname"/>
203 <xsl:text>=</xsl:text>
204 <xsl:value-of select="$package"/>
205 <xsl:text>&#xA;if [[ ! -f $</xsl:text>
206 <xsl:value-of select="$varname"/>
207 <xsl:text> ]] ; then&#xA;</xsl:text>
208 <!-- SRC_ARCHIVE may have subdirectories or not -->
209 <xsl:text> if [[ -f $SRC_ARCHIVE/$PKG_DIR/$</xsl:text>
210 <xsl:value-of select="$varname"/>
211 <xsl:text> ]] ; then&#xA;</xsl:text>
212 <xsl:text> cp $SRC_ARCHIVE/$PKG_DIR/$</xsl:text>
213 <xsl:value-of select="$varname"/>
214 <xsl:text> $</xsl:text>
215 <xsl:value-of select="$varname"/>
216 <xsl:text>&#xA;</xsl:text>
217 <xsl:text> elif [[ -f $SRC_ARCHIVE/$</xsl:text>
218 <xsl:value-of select="$varname"/>
219 <xsl:text> ]] ; then&#xA;</xsl:text>
220 <xsl:text> cp $SRC_ARCHIVE/$</xsl:text>
221 <xsl:value-of select="$varname"/>
222 <xsl:text> $</xsl:text>
223 <xsl:value-of select="$varname"/>
224 <xsl:text>&#xA; else&#xA;</xsl:text>
225 <!-- The FTP_SERVER mirror -->
226 <xsl:text> wget -T 30 -t 5 ${FTP_SERVER}svn/</xsl:text>
227 <xsl:value-of select="$first_letter"/>
228 <xsl:text>/$</xsl:text>
229 <xsl:value-of select="$varname"/>
230 <xsl:if test="string-length($httpurl) &gt; 10">
231 <xsl:text> ||
232 wget -T 30 -t 5 </xsl:text>
233 <xsl:value-of select="$httpurl"/>
234 </xsl:if>
235 <xsl:if test="string-length($ftpurl) &gt; 10">
236 <xsl:text> ||
237 wget -T 30 -t 5 </xsl:text>
238 <xsl:value-of select="$ftpurl"/>
239 </xsl:if>
240 <xsl:text>
241 cp $</xsl:text>
242 <xsl:value-of select="$varname"/>
243 <xsl:text> $SRC_ARCHIVE
244 fi
245fi
246</xsl:text>
247 <xsl:if test="string-length($md5) &gt; 10">
248 <xsl:text>echo "</xsl:text>
249 <xsl:value-of select="$md5"/>
250 <xsl:text>&#x20;&#x20;$</xsl:text>
251 <xsl:value-of select="$varname"/>
252 <xsl:text>" | md5sum -c -
253</xsl:text>
254 </xsl:if>
255 </xsl:template>
256
257 <!-- Extract the MD5 sum information -->
258 <xsl:template match="para" mode="md5">
259 <xsl:choose>
260 <xsl:when test="contains(substring-after(string(),'sum: '),'&#xA;')">
261 <xsl:value-of select="substring-before(substring-after(string(),'sum: '),'&#xA;')"/>
262 </xsl:when>
263 <xsl:otherwise>
264 <xsl:value-of select="substring-after(string(),'sum: ')"/>
265 </xsl:otherwise>
266 </xsl:choose>
267 </xsl:template>
268
269 <!-- We have several templates itemizedlist, depending on whether we
270 expect the package information, or additional package(s) or patch(es)
271 information. Select the appropriate mode here. -->
272 <xsl:template match="bridgehead">
273 <xsl:choose>
274 <!-- Special case for Openjdk -->
275 <xsl:when test="contains(string(),'Source Package Information')">
276 <xsl:apply-templates
277 select="following-sibling::itemizedlist[1]//simplelist">
278 <xsl:with-param name="varname" select="'PACKAGE'"/>
279 </xsl:apply-templates>
280 <xsl:apply-templates select="following-sibling::itemizedlist
281 [preceding-sibling::bridgehead[1]=current()
282 and position() &gt;1]//simplelist">
283 <xsl:with-param name="varname" select="'PACKAGE1'"/>
284 </xsl:apply-templates>
285 </xsl:when>
286 <!-- Package information -->
287 <xsl:when test="contains(string(),'Package Information')">
288 <xsl:apply-templates select="following-sibling::itemizedlist
289 [preceding-sibling::bridgehead[1]=current()]"
290 mode="package"/>
291 </xsl:when>
292 <!-- Additional package information -->
293 <!-- special case for llvm -->
294 <xsl:when test="contains(string(),'Optional Download')">
295 <xsl:apply-templates select="following-sibling::itemizedlist"
296 mode="additional"/>
297 </xsl:when>
298 <!-- All other additional packages have "Additional" -->
299 <xsl:when test="contains(string(),'Additional')">
300 <xsl:apply-templates select="following-sibling::itemizedlist"
301 mode="additional"/>
302 </xsl:when>
303 <!-- Do not do anything if the dev has created another type of
304 bridgehead. -->
305 <xsl:otherwise/>
306 </xsl:choose>
307 </xsl:template>
308
309 <!-- Call the download code template with appropriate parameters -->
310 <xsl:template match="itemizedlist" mode="package">
311 <xsl:call-template name="download-file">
312 <xsl:with-param name="httpurl">
313 <xsl:value-of select="./listitem[1]/para/ulink/@url"/>
314 </xsl:with-param>
315 <xsl:with-param name="ftpurl">
316 <xsl:value-of select="./listitem/para[contains(string(),'FTP')]/ulink/@url"/>
317 </xsl:with-param>
318 <xsl:with-param name="md5">
319 <xsl:apply-templates select="./listitem/para[contains(string(),'MD5')]"
320 mode="md5"/>
321 </xsl:with-param>
322 <xsl:with-param name="varname" select="'PACKAGE'"/>
323 </xsl:call-template>
324 </xsl:template>
325
326 <xsl:template match="itemizedlist" mode="additional">
327 <!-- The normal layout is "one listitem"<->"one url", but some devs
328 find amusing to have FTP and/or MD5sum listitems, or to
329 enclose the download information inside a simplelist tag... -->
330 <xsl:for-each select="listitem[.//ulink]">
331 <xsl:choose>
332 <!-- hopefully, there was a HTTP line before -->
333 <xsl:when test="contains(string(./para),'FTP')"/>
334 <xsl:when test=".//simplelist">
335 <xsl:apply-templates select=".//simplelist">
336 <xsl:with-param name="varname" select="'PACKAGE1'"/>
337 </xsl:apply-templates>
338 </xsl:when>
339 <xsl:otherwise>
340 <xsl:call-template name="download-file">
341 <xsl:with-param name="httpurl">
342 <xsl:value-of select="./para/ulink/@url"/>
343 </xsl:with-param>
344 <xsl:with-param name="ftpurl">
345 <xsl:value-of
346 select="following-sibling::listitem[1]/
347 para[contains(string(),'FTP')]/ulink/@url"/>
348 </xsl:with-param>
349 <xsl:with-param name="md5">
350 <xsl:apply-templates
351 select="following-sibling::listitem[position()&lt;3]/
352 para[contains(string(),'MD5')]"
353 mode="md5"/>
354 </xsl:with-param>
355 <xsl:with-param name="varname">
356 <xsl:choose>
357 <xsl:when test="contains(./para/ulink/@url,'.patch')">
358 <xsl:text>PATCH</xsl:text>
359 </xsl:when>
360 <xsl:otherwise>
361 <xsl:text>PACKAGE1</xsl:text>
362 </xsl:otherwise>
363 </xsl:choose>
364 </xsl:with-param>
365 </xsl:call-template>
366 </xsl:otherwise>
367 </xsl:choose>
368 </xsl:for-each>
369 </xsl:template>
370
371 <!-- the simplelist case. Hopefully, the layout is one member for
372 url, one for md5 and others for various information, that we do not
373 use -->
374 <xsl:template match="simplelist">
375 <xsl:param name="varname" select="'PACKAGE1'"/>
376 <xsl:call-template name="download-file">
377 <xsl:with-param name="httpurl" select=".//ulink/@url"/>
378 <xsl:with-param name="md5">
379 <xsl:value-of select="substring-after(member[contains(string(),'MD5')],'sum: ')"/>
380 </xsl:with-param>
381 <xsl:with-param name="varname" select="$varname"/>
382 </xsl:call-template>
383 </xsl:template>
384<!--======================== Commands code ==========================-->
385
386 <xsl:template match="screen">
387 <xsl:if test="child::* = userinput and not(@role = 'nodump')">
388 <xsl:choose>
389 <xsl:when test="@role = 'root'">
390 <xsl:if test="not(preceding-sibling::screen[@role='root'])">
391 <xsl:if test="$sudo = 'y'">
392 <xsl:text>sudo -E sh &lt;&lt; ROOT_EOF&#xA;</xsl:text>
393 </xsl:if>
394 <xsl:if test="$wrap-install = 'y' and
395 ancestor::sect2[@role='installation']">
396 <xsl:text>if [ -r "$PACK_INSTALL" ]; then
397 source $PACK_INSTALL
398 export -f wrapInstall
399 export -f packInstall
400fi
401wrapInstall '
402</xsl:text>
403 </xsl:if>
404 </xsl:if>
405 <xsl:apply-templates mode="root"/>
406 <xsl:if test="not(following-sibling::screen[@role='root'])">
407 <xsl:if test="$wrap-install = 'y' and
408 ancestor::sect2[@role='installation']">
409 <xsl:text>'&#xA;packInstall</xsl:text>
410 </xsl:if>
411 <xsl:if test="$sudo = 'y'">
412 <xsl:text>&#xA;ROOT_EOF</xsl:text>
413 </xsl:if>
414 </xsl:if>
415 </xsl:when>
416 <xsl:otherwise>
417 <xsl:apply-templates select="userinput"/>
418 </xsl:otherwise>
419 </xsl:choose>
420 <xsl:text>&#xA;</xsl:text>
421 </xsl:if>
422 </xsl:template>
423
424 <xsl:template match="screen" mode="config">
425 <xsl:if test="preceding-sibling::para[1]/xref[@linkend='bootscripts']">
426 <xsl:text>[[ ! -d $SRC_DIR/blfs-bootscripts ]] &amp;&amp; mkdir $SRC_DIR/blfs-bootscripts
427pushd $SRC_DIR/blfs-bootscripts
428URL=</xsl:text>
429 <xsl:value-of select="id('bootscripts')//itemizedlist//ulink/@url"/><xsl:text>
430BOOTPACKG=$(basename $URL)
431if [[ ! -f $BOOTPACKG ]] ; then
432 if [[ -f $SRC_ARCHIVE/$PKG_DIR/$BOOTPACKG ]] ; then
433 cp $SRC_ARCHIVE/$PKG_DIR/$BOOTPACKG $BOOTPACKG
434 elif [[ -f $SRC_ARCHIVE/$BOOTPACKG ]] ; then
435 cp $SRC_ARCHIVE/$BOOTPACKG $BOOTPACKG
436 else
437 wget -T 30 -t 5 $URL
438 cp $BOOTPACKG $SRC_ARCHIVE
439 fi
440 rm -f unpacked
441fi
442
443if [[ -e unpacked ]] ; then
444 BOOTUNPACKDIR=`head -n1 unpacked | sed 's@^./@@;s@/.*@@'`
445 if ! [[ -d $BOOTUNPACKDIR ]]; then
446 rm unpacked
447 tar -xvf $BOOTPACKG > unpacked
448 BOOTUNPACKDIR=`head -n1 unpacked | sed 's@^./@@;s@/.*@@'`
449 fi
450else
451 tar -xvf $BOOTPACKG > unpacked
452 BOOTUNPACKDIR=`head -n1 unpacked | sed 's@^./@@;s@/.*@@'`
453fi
454cd $BOOTUNPACKDIR
455</xsl:text>
456 </xsl:if>
457 <xsl:apply-templates select='.'/>
458 <xsl:if test="preceding-sibling::para[1]/xref[@linkend='bootscripts']">
459 <xsl:text>
460popd</xsl:text>
461 </xsl:if>
462 <xsl:text>&#xA;</xsl:text>
463 </xsl:template>
464
465 <xsl:template match="para/command">
466 <xsl:variable name="ns" select="normalize-space(string())"/>
467 <xsl:if test="(contains($ns,'test') or
468 contains($ns,'check'))">
469 <xsl:text>#</xsl:text>
470 <xsl:value-of select="substring-before($ns,'make ')"/>
471 <xsl:text>make </xsl:text>
472 <xsl:if test="not(contains($ns,'-k'))">
473 <xsl:text>-k </xsl:text>
474 </xsl:if>
475 <xsl:value-of select="substring-after($ns,'make ')"/>
476 <xsl:text> || true&#xA;</xsl:text>
477 </xsl:if>
478 </xsl:template>
479
480 <xsl:template match="userinput">
481 <xsl:apply-templates/>
482 </xsl:template>
483
484 <xsl:template match="text()" mode="root">
485 <xsl:call-template name="output-root">
486 <xsl:with-param name="out-string" select="string()"/>
487 </xsl:call-template>
488 </xsl:template>
489
490 <xsl:variable name="APOS">'</xsl:variable>
491
492 <xsl:template name="output-root">
493 <xsl:param name="out-string" select="''"/>
494 <xsl:choose>
495 <xsl:when test="contains($out-string,'make ')">
496 <xsl:call-template name="output-root">
497 <xsl:with-param name="out-string"
498 select="substring-before($out-string,'make ')"/>
499 </xsl:call-template>
500 <xsl:text>make -j1 </xsl:text>
501 <xsl:call-template name="output-root">
502 <xsl:with-param name="out-string"
503 select="substring-after($out-string,'make ')"/>
504 </xsl:call-template>
505 </xsl:when>
506 <xsl:when test="contains($out-string,'$') and $sudo = 'y'">
507 <xsl:call-template name="output-root">
508 <xsl:with-param name="out-string"
509 select="substring-before($out-string,'$')"/>
510 </xsl:call-template>
511 <xsl:text>\$</xsl:text>
512 <xsl:call-template name="output-root">
513 <xsl:with-param name="out-string"
514 select="substring-after($out-string,'$')"/>
515 </xsl:call-template>
516 </xsl:when>
517 <xsl:when test="contains($out-string,'`') and $sudo = 'y'">
518 <xsl:call-template name="output-root">
519 <xsl:with-param name="out-string"
520 select="substring-before($out-string,'`')"/>
521 </xsl:call-template>
522 <xsl:text>\`</xsl:text>
523 <xsl:call-template name="output-root">
524 <xsl:with-param name="out-string"
525 select="substring-after($out-string,'`')"/>
526 </xsl:call-template>
527 </xsl:when>
528 <xsl:when test="contains($out-string,'\') and $sudo = 'y'">
529 <xsl:call-template name="output-root">
530 <xsl:with-param name="out-string"
531 select="substring-before($out-string,'\')"/>
532 </xsl:call-template>
533 <xsl:text>\\</xsl:text>
534 <xsl:call-template name="output-root">
535 <xsl:with-param name="out-string"
536 select="substring-after($out-string,'\')"/>
537 </xsl:call-template>
538 </xsl:when>
539 <xsl:when test="contains($out-string,string($APOS))
540 and $wrap-install = 'y'
541 and ancestor::sect2[@role='installation']">
542 <xsl:call-template name="output-root">
543 <xsl:with-param name="out-string"
544 select="substring-before($out-string,string($APOS))"/>
545 </xsl:call-template>
546 <xsl:text>'\''</xsl:text>
547 <xsl:call-template name="output-root">
548 <xsl:with-param name="out-string"
549 select="substring-after($out-string,string($APOS))"/>
550 </xsl:call-template>
551 </xsl:when>
552 <xsl:otherwise>
553 <xsl:value-of select="$out-string"/>
554 </xsl:otherwise>
555 </xsl:choose>
556 </xsl:template>
557
558 <xsl:template match="replaceable">
559 <xsl:text>**EDITME</xsl:text>
560 <xsl:apply-templates/>
561 <xsl:text>EDITME**</xsl:text>
562 </xsl:template>
563
564 <xsl:template match="replaceable" mode="root">
565 <xsl:text>**EDITME</xsl:text>
566 <xsl:apply-templates/>
567 <xsl:text>EDITME**</xsl:text>
568 </xsl:template>
569
570</xsl:stylesheet>
Note: See TracBrowser for help on using the repository browser.