source: LFS/lfs.xsl@ 5dd7bff

ablfs-more legacy trunk
Last change on this file since 5dd7bff was 49f8b03, checked in by Pierre Labastie <pierre@…>, 4 years ago

Fix package management for new book, and add a patch for porg
  • Property mode set to 100644
File size: 51.2 KB
Line 
1<?xml version="1.0" encoding="ISO-8859-1"?>
2
3<!-- $Id$ -->
4
5<xsl:stylesheet
6 xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
7 xmlns:exsl="http://exslt.org/common"
8 extension-element-prefixes="exsl"
9 version="1.0">
10
11<!-- Parameters -->
12
13 <!-- use package management ?
14 n = no, original behavior
15 y = yes, add PKG_DEST to scripts in install commands of chapter06-08
16 -->
17 <xsl:param name="pkgmngt" select="'n'"/>
18
19 <!-- Package management with "porg style" ?
20 n = no, same as pkgmngt description above
21 y = yes, wrap install commands of chapter06-08 into a bash function.
22 note that pkgmngt must be 'y' in this case
23 -->
24 <xsl:param name="wrap-install" select='"n"'/>
25
26 <!-- Run test suites?
27 0 = none
28 1 = only chapter06 critical testsuites
29 2 = all chapter06 testsuites
30 3 = all chapter05 and chapter06 testsuites
31 -->
32 <xsl:param name="testsuite" select="1"/>
33
34 <!-- Bomb on test suites failures?
35 n = no, I want to build the full system and review the logs
36 y = yes, bomb at the first test suite failure to can review the build dir
37 -->
38 <xsl:param name="bomb-testsuite" select="'n'"/>
39
40 <!-- Install non wide character ncurses 5? -->
41 <xsl:param name="ncurses5" select="'n'"/>
42
43 <!-- Should we strip excutables and libraries? -->
44 <xsl:param name='strip' select="'n'"/>
45
46 <!-- Should we remove .la files after chapter 5 and chapter 6? -->
47 <xsl:param name='del-la-files' select="'y'"/>
48
49 <!-- Time zone -->
50 <xsl:param name="timezone" select="'GMT'"/>
51
52 <!-- Page size -->
53 <xsl:param name="page" select="'letter'"/>
54
55 <!-- Locale settings -->
56 <xsl:param name="lang" select="'C'"/>
57
58 <!-- Install the whole set of locales -->
59 <xsl:param name='full-locale' select='"n"'/>
60
61 <!-- Hostname -->
62 <xsl:param name='hostname' select='"HOSTNAME"'/>
63
64 <!-- Network parameters: interface, ip, gateway, prefix, broadcast, domain
65 and nameservers -->
66 <xsl:param name='interface' select="'eth0'"/>
67 <xsl:param name='ip' select='"10.0.2.9"'/>
68 <xsl:param name='gateway' select='"10.0.2.2"'/>
69 <xsl:param name='prefix' select='24'/>
70 <xsl:param name='broadcast' select='"10.0.2.255"'/>
71 <xsl:param name='domain' select='"lfs.org"'/>
72 <xsl:param name='nameserver1' select='"10.0.2.3"'/>
73 <xsl:param name='nameserver2' select='"8.8.8.8"'/>
74
75 <!-- Console parameters: font, fontmap, unicode (y/n), keymap, local (y:
76 hardware clock set to local time/n:hardware clock set to UTC)
77 and log-level -->
78 <xsl:param name='font' select="'lat0-16'"/>
79 <xsl:param name='keymap' select="'us'"/>
80 <xsl:param name='local' select="'n'"/>
81 <xsl:param name='log-level' select="'4'"/>
82
83 <!-- The scripts root is needed for printing disk usage -->
84 <xsl:param name='script-root' select="'jhalfs'"/>
85
86<!-- End parameters -->
87
88<!-- bashdir is used at the beginning of chapter 6, for the #! line.
89 If we created a /tools directory in chapter 4, bash is in /tools/bin,
90otherwise it is in /bin.-->
91 <xsl:variable name="bashdir">
92 <xsl:choose>
93 <xsl:when test="//sect1[@id='ch-preps-creatingtoolsdir']">
94 <xsl:text>/tools</xsl:text>
95 </xsl:when>
96 <xsl:otherwise>
97 <xsl:text></xsl:text>
98 </xsl:otherwise>
99 </xsl:choose>
100 </xsl:variable>
101
102<!-- Start of templates -->
103 <xsl:template match="/">
104 <xsl:apply-templates select="//chapter[
105 @id='chapter-final-preps' or
106 @id='chapter-cross-tools' or
107 @id='chapter-temporary-tools' or
108 @id='chapter-chroot-temporary-tools' or
109 @id='chapter-building-system' or
110 @id='chapter-config' or
111 @id='chapter-bootscripts' or
112 @id='chapter-bootable']"/>
113 </xsl:template>
114
115 <xsl:template match="chapter">
116 <xsl:apply-templates select="./sect1[
117 .//screen[not(@role) or @role != 'nodump']/
118 userinput[not(starts-with(string(),'chroot'))]]">
119 <xsl:with-param name="chap-num" select="position()+3"/>
120 </xsl:apply-templates>
121<!-- The last condition is a hack to allow old versions of the
122 book where the chroot commands did not have role="nodump".
123 It only works if the chroot command is the only one on the page -->
124 </xsl:template>
125
126 <xsl:template match="sect1">
127 <xsl:param name="chap-num" select="'1'"/>
128 <!-- The dirs names -->
129 <xsl:variable name="pi-dir" select="../processing-instruction('dbhtml')"/>
130 <xsl:variable name="pi-dir-value" select="substring-after($pi-dir,'dir=')"/>
131 <xsl:variable name="quote-dir" select="substring($pi-dir-value,1,1)"/>
132 <xsl:variable name="dirname" select="substring-before(substring($pi-dir-value,2),$quote-dir)"/>
133 <!-- The file names -->
134 <xsl:variable name="pi-file" select="processing-instruction('dbhtml')"/>
135 <xsl:variable name="pi-file-value" select="substring-after($pi-file,'filename=')"/>
136 <xsl:variable name="filename" select="substring-before(substring($pi-file-value,2),'.html')"/>
137 <!-- The build order -->
138 <xsl:variable name="position" select="position()"/>
139 <xsl:variable name="order">
140 <xsl:value-of select="$chap-num"/>
141 <xsl:if test="string-length($position) = 1">
142 <xsl:text>0</xsl:text>
143 </xsl:if>
144 <xsl:value-of select="$position"/>
145 </xsl:variable>
146 <!-- Creating dirs and files -->
147 <exsl:document href="{$dirname}/{$order}-{$filename}" method="text">
148 <xsl:text>#!</xsl:text>
149 <xsl:if test="@id='ch-system-creatingdirs' or
150 @id='ch-system-createfiles' or
151 @id='ch-system-strippingagain'">
152 <xsl:copy-of select="$bashdir"/>
153 </xsl:if>
154 <xsl:text>/bin/bash&#xA;set +h&#xA;</xsl:text>
155 <xsl:if test="not(@id='ch-tools-stripping') and
156 not(@id='ch-system-strippingagain')">
157 <xsl:text>set -e&#xA;</xsl:text>
158 </xsl:if>
159 <xsl:text>&#xA;</xsl:text>
160 <xsl:if test="ancestor::chapter/@id != 'chapter-final-preps'">
161 <xsl:call-template name="start-script">
162 <xsl:with-param name="order" select="$order"/>
163 </xsl:call-template>
164 </xsl:if>
165 <xsl:apply-templates
166 select="sect2 |
167 screen[not(@role) or @role!='nodump']/userinput"/>
168 <xsl:if test="contains(@id,'creatingdirs') and $pkgmngt='y'">
169 <xsl:apply-templates
170 select="document('packageManager.xml')//sect1[
171 @id='ch-pkgmngt-creatingdirs'
172 ]//userinput"
173 mode="pkgmngt"/>
174 </xsl:if>
175 <xsl:if test="contains(@id,'createfiles')
176 and $pkgmngt='y'
177 and $bashdir='/tools'">
178 <xsl:apply-templates
179 select="document('packageManager.xml')//sect1[
180 @id='ch-pkgmngt-createfiles'
181 ]//userinput"
182 mode="pkgmngt"/>
183 </xsl:if>
184 <xsl:if test="ancestor::chapter/@id != 'chapter-final-preps'">
185 <xsl:text>echo -e "\n\nTotalseconds: $SECONDS\n"&#xA;</xsl:text>
186 <xsl:call-template name="end-script"/>
187 </xsl:if>
188 <xsl:text>exit&#xA;</xsl:text>
189 </exsl:document>
190 <!-- Inclusion of package manager scriptlets -->
191 <xsl:if test="$pkgmngt='y' and
192 following-sibling::sect1[1][@id='ch-tools-stripping']">
193 <xsl:choose>
194 <xsl:when test="$bashdir='/tools'">
195 <xsl:apply-templates
196 select="document('packageManager.xml')//sect1[
197 contains(@id,'ch-tools')]"
198 mode="pkgmngt">
199 <xsl:with-param name="order" select="$order+1"/>
200 <xsl:with-param name="dirname" select="$dirname"/>
201 </xsl:apply-templates>
202 </xsl:when>
203 <xsl:otherwise>
204 <xsl:apply-templates
205 select="document('packageManager.xml')//sect1[
206 contains(@id,'ch-chroot')]"
207 mode="pkgmngt">
208 <xsl:with-param name="order" select="$order+1"/>
209 <xsl:with-param name="dirname" select="$dirname"/>
210 </xsl:apply-templates>
211 </xsl:otherwise>
212 </xsl:choose>
213 </xsl:if>
214 <xsl:if test="$pkgmngt='y' and
215 following-sibling::sect1[2][@id='ch-system-strippingagain']">
216 <xsl:apply-templates
217 select="document('packageManager.xml')//sect1[
218 contains(@id,'ch-system')]"
219 mode="pkgmngt">
220 <xsl:with-param name="order" select="$order+1"/>
221 <xsl:with-param name="dirname" select="$dirname"/>
222 </xsl:apply-templates>
223 </xsl:if>
224 </xsl:template>
225
226 <xsl:template match="sect2">
227 <xsl:apply-templates
228 select=".//screen[not(@role) or @role != 'nodump']/userinput[
229 @remap = 'pre' or
230 @remap = 'configure' or
231 @remap = 'make' or
232 @remap = 'test' and
233 not(current()/../@id='ch-tools-dejagnu') and
234 not(current()/../@id='ch-system-systemd')]"/>
235 <xsl:if
236 test="ancestor::chapter[@id = 'chapter-building-system' or
237 @id = 'chapter-config' or
238 @id = 'chapter-bootable'] and
239 $pkgmngt = 'y' and
240 descendant::screen[not(@role) or
241 @role != 'nodump']/userinput[
242 @remap='install']">
243 <xsl:choose>
244 <xsl:when test="$wrap-install='y'">
245 <xsl:text>wrapInstall '
246</xsl:text>
247 </xsl:when>
248 <xsl:otherwise>
249<!-- We cannot know which directory(ies) are needed by the package. Create a
250 reasonable bunch of them. Should be close to "Creating Directories".-->
251 <xsl:text>mkdir -pv $PKG_DEST/{bin,boot,etc,lib,sbin}
252mkdir -pv $PKG_DEST/usr/{bin,include,lib/pkgconfig,sbin}
253mkdir -pv $PKG_DEST/usr/share/{doc,info,bash-completion/completions}
254mkdir -pv $PKG_DEST/usr/share/man/man{1..8}
255case $(uname -m) in
256 x86_64) mkdir -v $PKG_DEST/lib64 ;;
257esac
258</xsl:text>
259 </xsl:otherwise>
260 </xsl:choose>
261 </xsl:if>
262 <xsl:apply-templates
263 select=".//screen[not(@role) or @role != 'nodump']/
264 userinput[@remap = 'install']"/>
265 <xsl:if test="ancestor::chapter[@id = 'chapter-building-system' or
266 @id = 'chapter-config' or
267 @id = 'chapter-bootable'] and
268 descendant::screen[not(@role) or
269 @role != 'nodump']/userinput[
270 @remap='install']">
271 <xsl:choose>
272 <xsl:when test="$pkgmngt='n'"/>
273 <xsl:when test="$wrap-install='y'">
274 <xsl:if test="../@id = 'ch-system-man-pages'">
275<!-- these files are provided by the shadow package -->
276 <xsl:text>rm -fv /usr/share/man/{man3/getspnam.3,man5/passwd.5}
277</xsl:text>
278 </xsl:if>
279<!-- nologin is installed by util-linux. remove it from shadow -->
280 <xsl:if test="../@id = 'ch-system-shadow'">
281 <xsl:text>rm -fv /usr/share/man/man8/nologin.8
282rm -fv /sbin/nologin
283</xsl:text>
284 </xsl:if>
285 <xsl:text>'
286PREV_SEC=${SECONDS}
287packInstall
288SECONDS=${PREV_SEC}
289</xsl:text>
290 </xsl:when>
291 <xsl:otherwise>
292 <xsl:if test="../@id = 'ch-system-man-pages'">
293<!-- these files are provided by the shadow package -->
294 <xsl:text>rm -fv $PKG_DEST/usr/share/man/{man3/getspnam.3,man5/passwd.5}
295</xsl:text>
296 </xsl:if>
297<!-- nologin is installed by util-linux. remove it from shadow -->
298 <xsl:if test="../@id = 'ch-system-shadow'">
299 <xsl:text>rm -fv $PKG_DEST/usr/share/man/man8/nologin.8
300rm -fv $PKG_DEST/sbin/nologin
301</xsl:text>
302 </xsl:if>
303<!-- remove empty directories -->
304 <xsl:text>for dir in $PKG_DEST/usr/share/man/man{1..8} \
305 $PKG_DEST/usr/share/bash-completion{/completions,} \
306 $PKG_DEST/usr/share/{doc,info,man,} \
307 $PKG_DEST/usr/lib/pkgconfig \
308 $PKG_DEST/usr/{lib,bin,sbin,include} \
309 $PKG_DEST/{boot,etc,lib,bin,sbin}; do
310 [ -d "$dir" ] &amp;&amp; [ -z "$(ls $dir)" ] &amp;&amp; rmdir -v $dir
311done
312[ -d $PKG_DEST/lib64 ] &amp;&amp; [ -z "$(ls $PKG_DEST/lib64)" ] &amp;&amp;
313 rmdir -v $PKG_DEST/lib64
314PREV_SEC=${SECONDS}
315packInstall
316SECONDS=${PREV_SEC}
317rm -rf $PKG_DEST
318</xsl:text>
319 </xsl:otherwise>
320 </xsl:choose>
321 </xsl:if>
322 <xsl:if test="$testsuite='3' and
323 ../@id='ch-tools-glibc' and
324 @role='installation'">
325 <xsl:copy-of select="//userinput[@remap='locale-test']"/>
326 <xsl:text>&#xA;</xsl:text>
327 </xsl:if>
328 <xsl:if test="../@id='ch-system-glibc' and @role='installation'">
329 <xsl:choose>
330 <xsl:when test="$full-locale='y'">
331 <xsl:copy-of select="//userinput[@remap='locale-full']"/>
332 <xsl:text>&#xA;</xsl:text>
333 </xsl:when>
334 <xsl:otherwise>
335 <xsl:copy-of select="//userinput[@remap='locale-test']"/>
336 <xsl:text>&#xA;</xsl:text>
337 <xsl:if test="not(contains(string(//userinput[@remap='locale-test']),$lang)) and $lang!='C' and $lang!='POSIX'">
338 <xsl:text>if LOCALE=`grep "</xsl:text>
339 <xsl:value-of select="$lang"/>
340 <xsl:text>/" $PKGDIR/localedata/SUPPORTED`; then
341 CHARMAP=`echo $LOCALE | sed 's,[^/]*/\([^ ]*\) [\],\1,'`
342 INPUT=`echo $LOCALE | sed 's,[/.].*,,'`
343 LOCALE=`echo $LOCALE | sed 's,/.*,,'`
344 localedef -i $INPUT -f $CHARMAP $LOCALE
345fi
346</xsl:text>
347 </xsl:if>
348 </xsl:otherwise>
349 </xsl:choose>
350 </xsl:if>
351 <xsl:apply-templates
352 select=".//screen[not(@role) or @role != 'nodump']/userinput[
353 not(@remap) or
354 @remap='adjust' or
355 @remap='test' and current()/../@id='ch-tools-dejagnu' or
356 @remap='test' and current()/../@id='ch-system-systemd'
357 ]"/>
358 <xsl:if test="../@id='ch-system-ncurses' and $ncurses5='y'">
359 <xsl:apply-templates select=".//screen[@role='nodump']"/>
360 </xsl:if>
361 </xsl:template>
362
363 <xsl:template match="sect1" mode="pkgmngt">
364 <xsl:param name="dirname" select="'chapter05'"/>
365 <!-- The build order -->
366 <xsl:param name="order" select="'062'"/>
367<!-- The file names -->
368 <xsl:variable name="pi-file" select="processing-instruction('dbhtml')"/>
369 <xsl:variable name="pi-file-value" select="substring-after($pi-file,'filename=')"/>
370 <xsl:variable name="filename" select="substring-before(substring($pi-file-value,2),'.html')"/>
371 <!-- Creating dirs and files -->
372 <xsl:if test="count(descendant::screen/userinput) &gt; 0 and
373 count(descendant::screen/userinput) &gt;
374 count(descendant::screen[@role='nodump'])">
375 <exsl:document href="{$dirname}/{$order}-{position()}-{$filename}"
376 method="text">
377 <xsl:text>#!/bin/bash
378set +h
379set -e
380</xsl:text>
381 <xsl:call-template name="start-script">
382 <xsl:with-param name="order" select="concat($order,'-',position())"/>
383 </xsl:call-template>
384 <xsl:apply-templates
385 select=".//screen[not(@role) or
386 @role != 'nodump']/userinput[@remap != 'adjust']"
387 mode="pkgmngt"/>
388 <xsl:if test="$dirname = 'chapter06' or $dirname = 'chapter08'">
389 <xsl:text>PREV_SEC=${SECONDS}
390packInstall
391SECONDS=${PREV_SEC}
392rm -rf "$PKG_DEST"
393</xsl:text>
394 </xsl:if>
395 <xsl:apply-templates
396 select=".//screen[not(@role) or
397 @role != 'nodump'
398 ]/userinput[not(@remap) or
399 @remap='adjust'
400 ]"
401 mode="pkgmngt"/>
402 <xsl:text>
403echo -e "\n\nTotalseconds: $SECONDS\n"
404</xsl:text>
405 <xsl:call-template name="end-script"/>
406 <xsl:text>exit
407</xsl:text>
408 </exsl:document>
409 </xsl:if>
410 </xsl:template>
411
412 <xsl:template match="userinput" mode="pkgmngt">
413 <xsl:apply-templates/>
414 <xsl:text>&#xA;</xsl:text>
415 </xsl:template>
416
417 <xsl:template match="userinput">
418 <xsl:choose>
419 <!-- Copying the kernel config file -->
420 <xsl:when test="string() = 'make mrproper'">
421 <xsl:text>make mrproper&#xA;</xsl:text>
422 <xsl:if test="ancestor::sect1[@id='ch-bootable-kernel']">
423 <xsl:text>cp -v ../kernel-config .config&#xA;</xsl:text>
424 </xsl:if>
425 </xsl:when>
426<!-- test instructions -->
427 <xsl:when test="@remap = 'test'">
428 <xsl:call-template name="comment-test">
429 <xsl:with-param name="instructions" select="string()"/>
430 </xsl:call-template>
431 </xsl:when>
432<!-- End of test instructions -->
433<!-- If the instructions contain "strip ", it may mean they contain also .la
434 file removal (and possibly other clean up). We therefore call a template
435 to comment them out appropriately and also to not stop if stripping
436 fails. -->
437 <xsl:when test="contains(string(),'strip ') or
438 contains(string(),'\*.la')">
439 <xsl:call-template name="comment-strip">
440 <xsl:with-param name="instructions" select="string()"/>
441 </xsl:call-template>
442 </xsl:when>
443<!-- Package management -->
444<!-- Add $PKG_DEST to installation commands -->
445<!-- Also add -j1 to make install -->
446 <xsl:when test="@remap='install' and
447 not(ancestor::chapter[
448 @id='chapter-temporary-tools'
449 ])">
450 <xsl:choose>
451 <xsl:when test="$pkgmngt='n'">
452 <xsl:choose>
453 <xsl:when test="contains(string(),'firmware,udev')">
454 <xsl:text>if [[ ! -d /lib/udev/devices ]] ; then&#xA;</xsl:text>
455 <xsl:apply-templates/>
456 <xsl:text>&#xA;fi&#xA;</xsl:text>
457 </xsl:when>
458 <xsl:when test="contains(string(),'make ')">
459 <xsl:copy-of select="substring-before(string(), 'make ')"/>
460 <xsl:text>make -j1 </xsl:text>
461 <xsl:copy-of select="substring-after(string(), 'make ')"/>
462 <xsl:text>&#xA;</xsl:text>
463 </xsl:when>
464 <xsl:otherwise>
465 <xsl:apply-templates/>
466 <xsl:text>&#xA;</xsl:text>
467 </xsl:otherwise>
468 </xsl:choose>
469 </xsl:when>
470 <xsl:when test="$wrap-install='y'">
471 <xsl:choose>
472 <xsl:when test="./literal">
473 <xsl:call-template name="output-wrap">
474 <xsl:with-param name="commands" select="text()[1]"/>
475 </xsl:call-template>
476 <xsl:apply-templates select="literal"/>
477 <xsl:call-template name="output-wrap">
478 <xsl:with-param name="commands" select="text()[2]"/>
479 </xsl:call-template>
480 </xsl:when>
481 <xsl:otherwise>
482 <xsl:call-template name="output-wrap">
483 <xsl:with-param name="commands" select="string()"/>
484 </xsl:call-template>
485 </xsl:otherwise>
486 </xsl:choose>
487 <xsl:text>&#xA;</xsl:text>
488 </xsl:when>
489 <xsl:otherwise><!--pkgmngt = 'y' and wrap-install='n'-->
490 <xsl:choose>
491 <xsl:when test="./literal">
492 <xsl:call-template name="outputpkgdest">
493 <xsl:with-param name="outputstring" select="text()[1]"/>
494 </xsl:call-template>
495 <xsl:apply-templates select="literal"/>
496 <xsl:call-template name="outputpkgdest">
497 <xsl:with-param name="outputstring" select="text()[2]"/>
498 </xsl:call-template>
499 </xsl:when>
500 <xsl:otherwise>
501 <xsl:call-template name="outputpkgdest">
502 <xsl:with-param name="outputstring" select="string()"/>
503 </xsl:call-template>
504 </xsl:otherwise>
505 </xsl:choose>
506 <xsl:text>&#xA;</xsl:text>
507 </xsl:otherwise>
508 </xsl:choose>
509 </xsl:when> <!-- @remap='install' and not temporary tools -->
510 <!-- if package management, we should make an independant package for
511 tzdata. -->
512 <xsl:when test="contains(string(),'tzdata') and $pkgmngt='y'">
513 <xsl:text>
514OLD_PKG_DEST="$PKG_DEST"
515OLD_PKGDIR=$PKGDIR
516PKG_DEST=$(dirname $OLD_PKG_DEST)/001-tzdata
517PKGDIR=$(dirname $PKGDIR)/tzdata-</xsl:text>
518 <xsl:copy-of select="substring-before(
519 substring-after(string(),'tzdata'),
520 '.tar')"/>
521 <xsl:text>
522</xsl:text>
523 <xsl:choose>
524 <xsl:when test="$wrap-install='n'">
525 <xsl:copy-of select="substring-before(string(),'ZONEINFO=')"/>
526 <xsl:text>ZONEINFO=$PKG_DEST</xsl:text>
527 <xsl:copy-of select="substring-after(string(),'ZONEINFO=')"/>
528 <xsl:text>
529PREV_SEC=${SECONDS}
530packInstall
531SECONDS=${PREV_SEC}
532rm -rf $PKG_DEST
533</xsl:text>
534 </xsl:when>
535 <xsl:otherwise><!-- wrap-install='y' -->
536 <xsl:copy-of select="substring-before(string(),'ZONEINFO=')"/>
537 <xsl:text>
538wrapInstall '
539ZONEINFO=</xsl:text>
540 <xsl:copy-of select="substring-after(string(),'ZONEINFO=')"/>
541 <xsl:text>'
542PREV_SEC=${SECONDS}
543packInstall
544SECONDS=${PREV_SEC}
545</xsl:text>
546 </xsl:otherwise>
547 </xsl:choose>
548 <xsl:text>
549PKG_DEST=$OLD_PKG_DEST
550unset OLD_PKG_DEST
551PKGDIR=$OLD_PKGDIR
552unset OLD_PKGDIR
553</xsl:text>
554 </xsl:when><!-- addition for tzdata + package management -->
555 <!-- End addition for package management -->
556 <!-- add -j1 to make install in chapter 5 -->
557 <xsl:when test="ancestor::chapter[@id='chapter-temporary-tools'] and
558 @remap='install'">
559 <xsl:choose>
560 <xsl:when test="contains(string(),'make ')">
561 <xsl:copy-of select="substring-before(string(), 'make ')"/>
562 <xsl:text>make -j1 </xsl:text>
563 <xsl:copy-of select="substring-after(string(), 'make ')"/>
564 </xsl:when>
565 <xsl:otherwise>
566 <xsl:apply-templates/>
567 </xsl:otherwise>
568 </xsl:choose>
569 <xsl:text>&#xA;</xsl:text>
570 </xsl:when><!-- chapter 5 install -->
571 <!-- The rest of commands -->
572 <xsl:otherwise>
573 <xsl:apply-templates/>
574 <xsl:text>&#xA;</xsl:text>
575 </xsl:otherwise>
576 </xsl:choose>
577 </xsl:template>
578
579 <xsl:template match="replaceable">
580 <xsl:choose>
581 <xsl:when test="ancestor::sect1[@id='ch-system-glibc']">
582 <xsl:value-of select="$timezone"/>
583 </xsl:when>
584 <xsl:when test="ancestor::sect1[@id='ch-system-groff']">
585 <xsl:value-of select="$page"/>
586 </xsl:when>
587 <xsl:when test="contains(string(.),'&lt;ll&gt;_&lt;CC&gt;')">
588 <xsl:value-of select="$lang"/>
589 </xsl:when>
590 <xsl:when test="contains(string(.),'Domain')">
591 <xsl:value-of select="$domain"/>
592 </xsl:when>
593 <xsl:when test="contains(string(.),'primary')">
594 <xsl:value-of select="$nameserver1"/>
595 </xsl:when>
596 <xsl:when test="contains(string(.),'secondary')">
597 <xsl:value-of select="$nameserver2"/>
598 </xsl:when>
599 <xsl:when test="contains(string(.),'192.168.1.1')">
600 <xsl:value-of select="$ip"/>
601 </xsl:when>
602 <xsl:when test="contains(string(.),'192.168.0.2')">
603 <xsl:value-of select="$ip"/>
604 </xsl:when>
605 <xsl:when test="contains(string(.),'eth0')">
606 <xsl:value-of select="$interface"/>
607 </xsl:when>
608<!-- Only adapted to LFS-20170310 and later -->
609 <xsl:when test="contains(string(.),'HOSTNAME')">
610 <xsl:value-of select="$hostname"/>
611 </xsl:when>
612 <xsl:when test="contains(string(.),'FQDN')">
613 <xsl:value-of select="$hostname"/>
614 <xsl:text>.</xsl:text>
615 <xsl:value-of select="$domain"/>
616 </xsl:when>
617 <xsl:when test="contains(string(.),'alias')"/>
618 <xsl:when test="contains(string(.),'&lt;lfs&gt;')">
619 <xsl:value-of select="$hostname"/>
620 </xsl:when>
621 <xsl:otherwise>
622 <xsl:text>**EDITME</xsl:text>
623 <xsl:apply-templates/>
624 <xsl:text>EDITME**</xsl:text>
625 </xsl:otherwise>
626 </xsl:choose>
627 </xsl:template>
628
629 <xsl:template match="literal">
630 <xsl:choose>
631 <xsl:when test="contains(string(),'ONBOOT')">
632 <xsl:call-template name="outputnet">
633 <xsl:with-param name="netstring" select="string()"/>
634 </xsl:call-template>
635 </xsl:when>
636 <xsl:when test="contains(string(),'[Match]')">
637 <xsl:call-template name="outputsysdnet">
638 <xsl:with-param name="netstring" select="string()"/>
639 </xsl:call-template>
640 </xsl:when>
641 <xsl:when test="contains(string(),'0.0 0 0.0')">
642 <xsl:copy-of select="substring-before(string(),'LOCAL')"/>
643 <xsl:if test="$local='y'"><xsl:text>LOCAL</xsl:text></xsl:if>
644 <xsl:if test="$local='n'"><xsl:text>UTC</xsl:text></xsl:if>
645 </xsl:when>
646 <xsl:when test="contains(string(),'UTC=1')">
647 <xsl:copy-of select="substring-before(string(),'1')"/>
648 <xsl:if test="$local='y'"><xsl:text>0</xsl:text></xsl:if>
649 <xsl:if test="$local='n'"><xsl:text>1</xsl:text></xsl:if>
650 <xsl:copy-of select="substring-after(string(),'1')"/>
651 </xsl:when>
652 <xsl:when test="contains(string(),'bg_bds-')">
653 <xsl:call-template name="outputsysvconsole">
654 <xsl:with-param name="consolestring" select="string()"/>
655 </xsl:call-template>
656 </xsl:when>
657 <xsl:when test="contains(string(),'de-latin1')">
658 <xsl:call-template name="outputsysdconsole">
659 <xsl:with-param name="consolestring" select="string()"/>
660 </xsl:call-template>
661 </xsl:when>
662 <xsl:otherwise>
663 <xsl:apply-templates/>
664 </xsl:otherwise>
665 </xsl:choose>
666 </xsl:template>
667
668 <xsl:template name="outputnet">
669 <xsl:param name="netstring" select="''"/>
670 <!-- We suppose that book example has the following values:
671 - interface: eth0
672 - ip: 192.168.1.2
673 - gateway: 192.168.1.1
674 - prefix: 24
675 - broadcast: 192.168.1.255
676 Change below if book changes -->
677 <xsl:choose>
678 <xsl:when test="contains($netstring,'eth0')">
679 <xsl:call-template name="outputnet">
680 <xsl:with-param name="netstring"
681 select="substring-before($netstring,'eth0')"/>
682 </xsl:call-template>
683 <xsl:value-of select="$interface"/>
684 <xsl:call-template name="outputnet">
685 <xsl:with-param name="netstring"
686 select="substring-after($netstring,'eth0')"/>
687 </xsl:call-template>
688 </xsl:when>
689 <xsl:when test="contains($netstring,'192.168.1.1')">
690 <xsl:call-template name="outputnet">
691 <xsl:with-param name="netstring"
692 select="substring-before($netstring,'192.168.1.1')"/>
693 </xsl:call-template>
694 <xsl:value-of select="$gateway"/>
695 <xsl:call-template name="outputnet">
696 <xsl:with-param name="netstring"
697 select="substring-after($netstring,'192.168.1.1')"/>
698 </xsl:call-template>
699 </xsl:when>
700 <!-- must test this before the following, because 192.168.1.255 contains
701 192.168.1.2! -->
702 <xsl:when test="contains($netstring,'192.168.1.255')">
703 <xsl:call-template name="outputnet">
704 <xsl:with-param name="netstring"
705 select="substring-before($netstring,'192.168.1.255')"/>
706 </xsl:call-template>
707 <xsl:value-of select="$broadcast"/>
708 <xsl:call-template name="outputnet">
709 <xsl:with-param name="netstring"
710 select="substring-after($netstring,'192.168.1.255')"/>
711 </xsl:call-template>
712 </xsl:when>
713 <xsl:when test="contains($netstring,'192.168.1.2')">
714 <xsl:call-template name="outputnet">
715 <xsl:with-param name="netstring"
716 select="substring-before($netstring,'192.168.1.2')"/>
717 </xsl:call-template>
718 <xsl:value-of select="$ip"/>
719 <xsl:call-template name="outputnet">
720 <xsl:with-param name="netstring"
721 select="substring-after($netstring,'192.168.1.2')"/>
722 </xsl:call-template>
723 </xsl:when>
724 <xsl:when test="contains($netstring,'24')">
725 <xsl:call-template name="outputnet">
726 <xsl:with-param name="netstring"
727 select="substring-before($netstring,'24')"/>
728 </xsl:call-template>
729 <xsl:value-of select="$prefix"/>
730 <xsl:call-template name="outputnet">
731 <xsl:with-param name="netstring"
732 select="substring-after($netstring,'24')"/>
733 </xsl:call-template>
734 </xsl:when>
735 <xsl:otherwise>
736 <xsl:value-of select="$netstring"/>
737 </xsl:otherwise>
738 </xsl:choose>
739 </xsl:template>
740
741 <xsl:template name="outputsysdnet">
742 <xsl:param name="netstring" select="''"/>
743 <!-- We suppose that book example has the following values:
744 - interface: <network-device-name>
745 - ip: 192.168.0.2
746 - gateway: 192.168.0.1
747 - prefix: 24
748 - DNS: 192.168.0.1
749 - Domain: <Your Domain Name>
750 and gateway comes before DNS. Change below if book changes -->
751 <xsl:choose>
752 <xsl:when test="contains($netstring,'&lt;network-device-name&gt;')">
753 <xsl:call-template name="outputsysdnet">
754 <xsl:with-param name="netstring"
755 select="substring-before($netstring,'&lt;network-device-name&gt;')"/>
756 </xsl:call-template>
757 <xsl:value-of select="$interface"/>
758 <xsl:call-template name="outputsysdnet">
759 <xsl:with-param name="netstring"
760 select="substring-after($netstring,'&lt;network-device-name&gt;')"/>
761 </xsl:call-template>
762 </xsl:when>
763 <xsl:when test="contains($netstring,'192.168.0.1') and
764 contains($netstring,'Gateway')">
765 <xsl:call-template name="outputsysdnet">
766 <xsl:with-param name="netstring"
767 select="substring-before($netstring,'192.168.0.1')"/>
768 </xsl:call-template>
769 <xsl:value-of select="$gateway"/>
770 <xsl:call-template name="outputsysdnet">
771 <xsl:with-param name="netstring"
772 select="substring-after($netstring,'192.168.0.1')"/>
773 </xsl:call-template>
774 </xsl:when>
775 <xsl:when test="contains($netstring,'192.168.0.1') and
776 not(contains($netstring,'Gateway'))">
777 <xsl:call-template name="outputsysdnet">
778 <xsl:with-param name="netstring"
779 select="substring-before($netstring,'192.168.0.1')"/>
780 </xsl:call-template>
781 <xsl:value-of select="$nameserver1"/>
782 <xsl:text>
783DNS=</xsl:text>
784 <xsl:value-of select="$nameserver2"/>
785 <xsl:call-template name="outputsysdnet">
786 <xsl:with-param name="netstring"
787 select="substring-after($netstring,'192.168.0.1')"/>
788 </xsl:call-template>
789 </xsl:when>
790 <xsl:when test="contains($netstring,'192.168.0.2')">
791 <xsl:call-template name="outputsysdnet">
792 <xsl:with-param name="netstring"
793 select="substring-before($netstring,'192.168.0.2')"/>
794 </xsl:call-template>
795 <xsl:value-of select="$ip"/>
796 <xsl:call-template name="outputsysdnet">
797 <xsl:with-param name="netstring"
798 select="substring-after($netstring,'192.168.0.2')"/>
799 </xsl:call-template>
800 </xsl:when>
801 <xsl:when test="contains($netstring,'24')">
802 <xsl:call-template name="outputsysdnet">
803 <xsl:with-param name="netstring"
804 select="substring-before($netstring,'24')"/>
805 </xsl:call-template>
806 <xsl:value-of select="$prefix"/>
807 <xsl:call-template name="outputsysdnet">
808 <xsl:with-param name="netstring"
809 select="substring-after($netstring,'24')"/>
810 </xsl:call-template>
811 </xsl:when>
812 <xsl:when test="contains($netstring,'&lt;Your Domain Name&gt;')">
813 <xsl:call-template name="outputsysdnet">
814 <xsl:with-param name="netstring"
815 select="substring-before($netstring,'&lt;Your Domain Name&gt;')"/>
816 </xsl:call-template>
817 <xsl:value-of select="$domain"/>
818 <xsl:call-template name="outputsysdnet">
819 <xsl:with-param name="netstring"
820 select="substring-after($netstring,'&lt;Your Domain Name&gt;')"/>
821 </xsl:call-template>
822 </xsl:when>
823 <xsl:otherwise>
824 <xsl:value-of select="$netstring"/>
825 </xsl:otherwise>
826 </xsl:choose>
827 </xsl:template>
828
829 <xsl:template name="outputsysvconsole">
830 <!-- We suppose that book example has the following values:
831 - KEYMAP: bg_bds-utf8
832 - FONT: LatArCyrHeb-16
833 Change below if book changes -->
834 <xsl:param name="consolestring" select="''"/>
835 <xsl:choose>
836 <xsl:when test="contains($consolestring,'bg_bds-utf8')">
837 <xsl:call-template name="outputsysvconsole">
838 <xsl:with-param
839 name="consolestring"
840 select="substring-before($consolestring,'bg_bds-utf8')"/>
841 </xsl:call-template>
842 <xsl:value-of select="$keymap"/>
843 <xsl:call-template name="outputsysvconsole">
844 <xsl:with-param
845 name="consolestring"
846 select="substring-after($consolestring,'bg_bds-utf8')"/>
847 </xsl:call-template>
848 </xsl:when>
849 <xsl:when test="contains($consolestring,'LatArCyrHeb-16')">
850 <xsl:call-template name="outputsysvconsole">
851 <xsl:with-param
852 name="consolestring"
853 select="substring-before($consolestring,'LatArCyrHeb-16')"/>
854 </xsl:call-template>
855 <xsl:value-of select="$font"/>
856 <xsl:text>"
857LOGLEVEL="</xsl:text>
858 <xsl:copy-of select="$log-level"/>
859 <xsl:call-template name="outputsysvconsole">
860 <xsl:with-param
861 name="consolestring"
862 select="substring-after($consolestring,'LatArCyrHeb-16')"/>
863 </xsl:call-template>
864 </xsl:when>
865 <xsl:otherwise>
866 <xsl:copy-of select="$consolestring"/>
867 </xsl:otherwise>
868 </xsl:choose>
869 </xsl:template>
870
871 <xsl:template name="outputsysdconsole">
872 <!-- We suppose that book example has the following values:
873 - KEYMAP: de-latin1
874 - FONT: Lat2-Terminus16
875 Change below if book changes -->
876 <xsl:param name="consolestring" select="''"/>
877 <xsl:choose>
878 <xsl:when test="contains($consolestring,'de-latin1')">
879 <xsl:call-template name="outputsysdconsole">
880 <xsl:with-param
881 name="consolestring"
882 select="substring-before($consolestring,'de-latin1')"/>
883 </xsl:call-template>
884 <xsl:value-of select="$keymap"/>
885 <xsl:call-template name="outputsysdconsole">
886 <xsl:with-param
887 name="consolestring"
888 select="substring-after($consolestring,'de-latin1')"/>
889 </xsl:call-template>
890 </xsl:when>
891 <xsl:when test="contains($consolestring,'Lat2-Terminus16')">
892 <xsl:call-template name="outputsysdconsole">
893 <xsl:with-param
894 name="consolestring"
895 select="substring-before($consolestring,'Lat2-Terminus16')"/>
896 </xsl:call-template>
897 <xsl:value-of select="$font"/>
898 <xsl:call-template name="outputsysdconsole">
899 <xsl:with-param
900 name="consolestring"
901 select="substring-after($consolestring,'Lat2-Terminus16')"/>
902 </xsl:call-template>
903 </xsl:when>
904 <xsl:otherwise>
905 <xsl:copy-of select="$consolestring"/>
906 </xsl:otherwise>
907 </xsl:choose>
908 </xsl:template>
909
910 <xsl:template name="outputpkgdest">
911 <xsl:param name="outputstring" select="foo"/>
912 <xsl:choose>
913 <xsl:when test="contains($outputstring,'make ')">
914 <xsl:choose>
915 <xsl:when test="not(starts-with($outputstring,'make'))">
916 <xsl:call-template name="outputpkgdest">
917 <xsl:with-param name="outputstring"
918 select="substring-before($outputstring,'make')"/>
919 </xsl:call-template>
920 <xsl:call-template name="outputpkgdest">
921 <xsl:with-param
922 name="outputstring"
923 select="substring-after($outputstring,
924 substring-before($outputstring,'make'))"/>
925 </xsl:call-template>
926 </xsl:when>
927 <xsl:otherwise>
928 <xsl:choose>
929<!-- special cases (no DESTDIR) here -->
930 <xsl:when test="ancestor::sect1[@id='ch-system-glibc']">
931 <xsl:text>make install_root=$PKG_DEST -j1</xsl:text>
932 <xsl:value-of
933 select="substring-before(substring-after(string(),'make'),
934 'install')"/>
935 <xsl:text>install&#xA;</xsl:text>
936 </xsl:when>
937 <xsl:when test="ancestor::sect1[@id='ch-system-bzip2']">
938 <xsl:text>make -j1 PREFIX=$PKG_DEST/usr install&#xA;</xsl:text>
939 </xsl:when>
940 <xsl:when test="ancestor::sect1[@id='ch-system-sysklogd']">
941 <xsl:text>make -j1 BINDIR=$PKG_DEST/sbin prefix=$PKG_DEST install&#xA;</xsl:text>
942 </xsl:when>
943 <xsl:when test="ancestor::sect1[@id='ch-system-iproute2']">
944 <xsl:text>make -j1 DESTDIR=$PKG_DEST DOCDIR=</xsl:text>
945 <xsl:value-of
946 select="substring-before(substring-after(string(),'DOCDIR='),
947 'install')"/>
948 <xsl:text>install&#xA;</xsl:text>
949 </xsl:when>
950 <xsl:when test="ancestor::sect1[@id='ch-system-sysvinit']">
951 <xsl:text>make -j1 ROOT=$PKG_DEST</xsl:text>
952 <xsl:value-of
953 select="substring-before(substring-after(string(),'make'),
954 'install')"/>
955 <xsl:text>install&#xA;</xsl:text>
956 </xsl:when>
957 <xsl:when test="ancestor::sect1[@id='ch-bootable-kernel']">
958 <xsl:text>make -j1 INSTALL_MOD_PATH=$PKG_DEST</xsl:text>
959 <xsl:value-of
960 select="substring-before(substring-after(string(),'make'),
961 'install')"/>
962 <xsl:text>install&#xA;</xsl:text>
963 </xsl:when>
964 <xsl:otherwise>
965 <xsl:text>make -j1 DESTDIR=$PKG_DEST</xsl:text>
966 <xsl:call-template name="outputpkgdest">
967 <xsl:with-param
968 name="outputstring"
969 select="substring-after($outputstring,'make')"/>
970 </xsl:call-template>
971 </xsl:otherwise>
972 </xsl:choose>
973 </xsl:otherwise>
974 </xsl:choose>
975 </xsl:when>
976 <xsl:when test="contains($outputstring,'ninja install')">
977 <xsl:choose>
978 <xsl:when test="not(starts-with($outputstring,'ninja install'))">
979 <xsl:call-template name="outputpkgdest">
980 <xsl:with-param name="outputstring"
981 select="substring-before($outputstring,'ninja install')"/>
982 </xsl:call-template>
983 <xsl:call-template name="outputpkgdest">
984 <xsl:with-param
985 name="outputstring"
986 select="substring-after($outputstring,
987 substring-before($outputstring,'ninja install'))"/>
988 </xsl:call-template>
989 </xsl:when>
990 <xsl:otherwise> <!-- "ninja" is the first word and is followed by
991 "install"-->
992 <xsl:text>DESTDIR=$PKG_DEST ninja</xsl:text>
993 <xsl:call-template name="outputpkgdest">
994 <xsl:with-param
995 name="outputstring"
996 select="substring-after($outputstring,'ninja')"/>
997 </xsl:call-template>
998 </xsl:otherwise>
999 </xsl:choose>
1000 </xsl:when>
1001 <xsl:otherwise> <!-- no make nor ninja in this string -->
1002 <xsl:choose>
1003 <xsl:when test="contains($outputstring,'&gt;/') and
1004 not(contains(substring-before($outputstring,'&gt;/'),' /'))">
1005 <xsl:value-of select="substring-before($outputstring,'&gt;/')"/>
1006 <xsl:text>&gt;$PKG_DEST/</xsl:text>
1007 <xsl:call-template name="outputpkgdest">
1008 <xsl:with-param name="outputstring" select="substring-after($outputstring,'&gt;/')"/>
1009 </xsl:call-template>
1010 </xsl:when>
1011 <xsl:when test="contains($outputstring,' /')">
1012 <xsl:value-of select="substring-before($outputstring,' /')"/>
1013 <xsl:text> $PKG_DEST/</xsl:text>
1014 <xsl:call-template name="outputpkgdest">
1015 <xsl:with-param name="outputstring" select="substring-after($outputstring,' /')"/>
1016 </xsl:call-template>
1017 </xsl:when>
1018 <xsl:otherwise>
1019 <xsl:value-of select="$outputstring"/>
1020 </xsl:otherwise>
1021 </xsl:choose>
1022 </xsl:otherwise>
1023 </xsl:choose>
1024 </xsl:template>
1025
1026 <xsl:variable name="APOS">'</xsl:variable>
1027 <xsl:template name="output-wrap">
1028 <xsl:param name="commands" select="''"/>
1029 <xsl:choose>
1030 <xsl:when test="contains($commands,string($APOS))">
1031 <xsl:call-template name="output-wrap">
1032 <xsl:with-param name="commands"
1033 select="substring-before($commands,string($APOS))"/>
1034 </xsl:call-template>
1035 <xsl:text>'\''</xsl:text>
1036 <xsl:call-template name="output-wrap">
1037 <xsl:with-param name="commands"
1038 select="substring-after($commands,string($APOS))"/>
1039 </xsl:call-template>
1040 </xsl:when>
1041 <xsl:otherwise>
1042 <xsl:value-of select="$commands"/>
1043 </xsl:otherwise>
1044 </xsl:choose>
1045 </xsl:template>
1046
1047 <xsl:template name="comment-strip">
1048 <xsl:param name="instructions" select="''"/>
1049 <xsl:choose>
1050 <xsl:when test="contains($instructions,'&#xA;')">
1051 <xsl:call-template name="comment-strip">
1052 <xsl:with-param name="instructions"
1053 select="substring-before($instructions,'&#xA;')"/>
1054 </xsl:call-template>
1055 <xsl:call-template name="comment-strip">
1056 <xsl:with-param name="instructions"
1057 select="substring-after($instructions,'&#xA;')"/>
1058 </xsl:call-template>
1059 </xsl:when>
1060 <xsl:when test="contains($instructions,'\*.la')">
1061 <xsl:if test="$del-la-files='n'">
1062 <xsl:text># </xsl:text>
1063 </xsl:if>
1064 <xsl:value-of select="$instructions"/>
1065 <xsl:text>&#xA;</xsl:text>
1066 </xsl:when>
1067 <xsl:when test="contains($instructions,'strip ')">
1068 <xsl:if test="$strip='n'">
1069 <xsl:text># </xsl:text>
1070 </xsl:if>
1071 <xsl:value-of select="$instructions"/>
1072 <xsl:text> || true&#xA;</xsl:text>
1073 </xsl:when>
1074 <xsl:otherwise>
1075 <xsl:value-of select="$instructions"/>
1076 <xsl:text>&#xA;</xsl:text>
1077 </xsl:otherwise>
1078 </xsl:choose>
1079 </xsl:template>
1080
1081 <xsl:template name="comment-test">
1082 <xsl:param name="instructions" select="''"/>
1083 <xsl:param name="eof-seen" select="false()"/>
1084 <xsl:choose>
1085 <xsl:when test="contains($instructions,'&#xA;')">
1086 <xsl:call-template name="comment-test">
1087 <xsl:with-param name="instructions"
1088 select="substring-before($instructions,'&#xA;')"/>
1089 <xsl:with-param name="eof-seen" select="$eof-seen"/>
1090 </xsl:call-template>
1091 <xsl:choose>
1092 <xsl:when test="contains(substring-before($instructions,'&#xA;'),
1093 'EOF')">
1094 <xsl:call-template name="comment-test">
1095 <xsl:with-param name="instructions"
1096 select="substring-after($instructions,'&#xA;')"/>
1097 <xsl:with-param name="eof-seen" select="not($eof-seen)"/>
1098 </xsl:call-template>
1099 </xsl:when>
1100 <xsl:otherwise>
1101 <xsl:call-template name="comment-test">
1102 <xsl:with-param name="instructions"
1103 select="substring-after($instructions,'&#xA;')"/>
1104 <xsl:with-param name="eof-seen" select="$eof-seen"/>
1105 </xsl:call-template>
1106 </xsl:otherwise>
1107 </xsl:choose>
1108 </xsl:when>
1109 <xsl:otherwise>
1110 <xsl:if test="$testsuite = '0' or
1111 $testsuite = '1' and
1112 not(ancestor::sect1[@id='ch-system-gcc']) and
1113 not(ancestor::sect1[@id='ch-system-glibc']) and
1114 not(ancestor::sect1[@id='ch-system-gmp']) and
1115 not(ancestor::sect1[@id='ch-system-mpfr']) and
1116 not(ancestor::sect1[@id='ch-system-binutils']) or
1117 $testsuite = '2' and
1118 ancestor::chapter[@id='chapter-temporary-tools']">
1119 <xsl:text># </xsl:text>
1120 </xsl:if>
1121 <xsl:choose>
1122 <xsl:when test="$bomb-testsuite = 'n'">
1123 <xsl:choose>
1124 <xsl:when test="contains(string(), 'make -k')">
1125 <xsl:value-of select="$instructions"/>
1126 <xsl:if test="not($eof-seen)">
1127 <xsl:text> &gt;&gt; $TEST_LOG 2&gt;&amp;1 || true</xsl:text>
1128 </xsl:if>
1129 <xsl:text>&#xA;</xsl:text>
1130 </xsl:when>
1131 <xsl:when test="contains($instructions, 'make')">
1132 <xsl:value-of select="substring-before($instructions, 'make')"/>
1133 <xsl:text>make -k</xsl:text>
1134 <xsl:value-of select="substring-after($instructions, 'make')"/>
1135 <xsl:if test="not($eof-seen)">
1136 <xsl:text> &gt;&gt; $TEST_LOG 2&gt;&amp;1 || true</xsl:text>
1137 </xsl:if>
1138 <xsl:text>&#xA;</xsl:text>
1139 </xsl:when>
1140 <xsl:otherwise>
1141 <xsl:value-of select="$instructions"/>
1142 <xsl:if
1143 test="not(contains($instructions, '&gt;&gt;')) and
1144 not($eof-seen) and
1145 substring($instructions,
1146 string-length($instructions)) != '\'">
1147 <xsl:text> &gt;&gt; $TEST_LOG 2&gt;&amp;1 || true</xsl:text>
1148 </xsl:if>
1149 <xsl:text>&#xA;</xsl:text>
1150 </xsl:otherwise>
1151 </xsl:choose>
1152 </xsl:when>
1153 <xsl:otherwise>
1154 <!-- bomb-testsuite != 'n'-->
1155 <xsl:choose>
1156 <xsl:when test="contains($instructions, 'make -k')">
1157 <xsl:value-of select="$instructions"/>
1158 <xsl:if test="not($eof-seen)">
1159 <xsl:text> &gt;&gt; $TEST_LOG 2&gt;&amp;1 || true</xsl:text>
1160 </xsl:if>
1161 <xsl:text>&#xA;</xsl:text>
1162 </xsl:when>
1163 <xsl:otherwise>
1164 <xsl:value-of select="$instructions"/>
1165 <xsl:if test="not(contains($instructions, '&gt;&gt;')) and
1166 not($eof-seen) and
1167 substring($instructions,
1168 string-length($instructions)) != '\'">
1169 <xsl:text> &gt;&gt; $TEST_LOG 2&gt;&amp;1</xsl:text>
1170 </xsl:if>
1171 <xsl:text>&#xA;</xsl:text>
1172 </xsl:otherwise>
1173 </xsl:choose>
1174 </xsl:otherwise> <!-- end not bomb-test=n -->
1175 </xsl:choose>
1176 </xsl:otherwise>
1177 </xsl:choose>
1178 </xsl:template>
1179
1180 <xsl:template name="basename">
1181 <xsl:param name="path" select="''"/>
1182 <xsl:choose>
1183 <xsl:when test="contains($path,'/') and substring-after($path,'/')!=''">
1184 <xsl:call-template name="basename">
1185 <xsl:with-param name="path" select="substring-after($path,'/')"/>
1186 </xsl:call-template>
1187 </xsl:when>
1188 <xsl:when test="contains($path,'/') and substring-after($path,'/')=''">
1189 <xsl:value-of select="substring-before($path,'/')"/>
1190 </xsl:when>
1191 <xsl:otherwise>
1192 <xsl:value-of select="$path"/>
1193 </xsl:otherwise>
1194 </xsl:choose>
1195 </xsl:template>
1196
1197 <xsl:template name="start-script">
1198 <xsl:param name="order" select="'073'"/>
1199 <xsl:text>
1200<!-- save the timer, so that unpacking, and du is not counted -->
1201PREV_SEC=${SECONDS}
1202 <!-- get the location of the system root -->
1203ROOT=</xsl:text>
1204 <xsl:choose>
1205 <xsl:when test="starts-with(./@id, 'ch-tools') or
1206 contains (./@id, 'kernfs')">
1207 <xsl:text>$LFS/
1208</xsl:text>
1209 </xsl:when>
1210 <xsl:otherwise>
1211 <xsl:text>/
1212</xsl:text>
1213 </xsl:otherwise>
1214 </xsl:choose>
1215 <xsl:text>
1216SCRIPT_ROOT=</xsl:text>
1217 <xsl:copy-of select="$script-root"/>
1218 <xsl:text>
1219</xsl:text>
1220 <xsl:if test="sect2[@role='installation']">
1221 <xsl:text>
1222SRC_DIR=${ROOT}sources
1223<!-- Set variables, for use by the Makefile and package manager -->
1224VERSION=</xsl:text><!-- needed for Makefile, and may be used in PackInstall-->
1225 <xsl:copy-of select=".//sect1info/productnumber/text()"/>
1226 <xsl:text>
1227PKG_DEST=${SRC_DIR}/</xsl:text>
1228 <xsl:copy-of select="$order"/>
1229 <xsl:text>-</xsl:text>
1230 <xsl:copy-of select=".//sect1info/productname/text()"/>
1231 <xsl:text>
1232<!-- Get the tarball name from sect1info -->
1233PACKAGE=</xsl:text>
1234 <xsl:call-template name="basename">
1235 <xsl:with-param name="path" select=".//sect1info/address/text()"/>
1236 </xsl:call-template>
1237 <xsl:if test = "( ../@id = 'chapter-building-system' or
1238 ../@id = 'chapter-config' or
1239 ../@id = 'chapter-bootable' or
1240 starts-with(@id,'ch-system') ) and $pkgmngt = 'y'">
1241<!-- the last alternative for old books where some sections in
1242 chapter-config had ch-system -->
1243 <xsl:text>
1244source ${ROOT}${SCRIPT_ROOT}/packInstall.sh
1245export -f packInstall</xsl:text>
1246 <xsl:if test="$wrap-install='y'">
1247 <xsl:text>
1248export -f wrapInstall
1249</xsl:text>
1250 </xsl:if>
1251 </xsl:if>
1252<!-- Get the build directory name and clean remnants of previous attempts -->
1253 <xsl:text>
1254cd $SRC_DIR
1255PKGDIR=$(tar -tf $PACKAGE | head -n1 | sed 's@^./@@;s@/.*@@')
1256export PKGDIR VERSION PKG_DEST
1257
1258if [ -d "$PKGDIR" ]; then rm -rf $PKGDIR; fi
1259if [ -d "${PKGDIR%-*}-build" ]; then rm -rf ${PKGDIR%-*}-build; fi
1260</xsl:text>
1261 </xsl:if>
1262 <xsl:text>
1263echo "KB: $(du -skx --exclude=lost+found --exclude=var/lib --exclude=$SCRIPT_ROOT $ROOT)"
1264</xsl:text>
1265 <xsl:if test="sect2[@role='installation']">
1266 <xsl:text>
1267<!-- At last unpack and change directory -->
1268tar -xf $PACKAGE
1269cd $PKGDIR
1270</xsl:text>
1271 </xsl:if>
1272 <xsl:text>SECONDS=${PREV_SEC}
1273
1274# Start of LFS book script
1275</xsl:text>
1276 </xsl:template>
1277
1278 <xsl:template name="end-script">
1279 <xsl:text>
1280# End of LFS book script
1281
1282echo "KB: $(du -skx --exclude=lost+found --exclude=var/lib --exclude=$SCRIPT_ROOT $ROOT)"
1283</xsl:text>
1284 <xsl:if test="sect2[@role='installation']">
1285 <xsl:text>cd $SRC_DIR
1286rm -rf $PKGDIR
1287if [ -d "${PKGDIR%-*}-build" ]; then rm -rf ${PKGDIR%-*}-build; fi
1288</xsl:text>
1289 </xsl:if>
1290 </xsl:template>
1291
1292</xsl:stylesheet>
Note: See TracBrowser for help on using the repository browser.