source: LFS/lfs.xsl@ 9a09336

trunk
Last change on this file since 9a09336 was 9a09336, checked in by Pierre Labastie <pierre.labastie@…>, 12 days ago

Revert "Remove --from lfs from chown for now"

This is not needed anymore since lfs user removal has been moved after
those commands now
This reverts commit 57a5e9acd19afa31ee631a8b6dd4cd8c9f3cb751.
  • Property mode set to 100644
File size: 51.2 KB
Line 
1<?xml version="1.0" encoding="ISO-8859-1"?>
2
3<xsl:stylesheet
4 xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
5 xmlns:exsl="http://exslt.org/common"
6 extension-element-prefixes="exsl"
7 version="1.0">
8
9<!-- Parameters -->
10
11 <!-- use package management ?
12 n = no, original behavior
13 y = yes, add PKG_DEST to scripts in install commands of chapter08-10
14 -->
15 <xsl:param name="pkgmngt" select="'n'"/>
16
17 <!-- Package management with "porg style" ?
18 n = no, same as pkgmngt description above
19 y = yes, wrap install commands of chapter08-10 into a bash function.
20 note that pkgmngt must be 'y' in this case
21 -->
22 <xsl:param name="wrap-install" select='"n"'/>
23
24 <!-- Run test suites?
25 0 = none
26 1 = only chapter08 critical testsuites
27 2 (or more) = all chapter08 testsuites
28 -->
29 <xsl:param name="testsuite" select="1"/>
30
31 <!-- Parallelism (LFS >= 12.1) -->
32 <xsl:param name="jobs" select="1"/>
33
34 <!-- value of jobs for binutils-pass1 -->
35 <xsl:param name="jobs-bp1" select="1"/>
36
37 <!-- Install non wide character ncurses 5? -->
38 <xsl:param name="ncurses5" select="'n'"/>
39
40 <!-- Should we strip excutables and libraries? -->
41 <xsl:param name='strip' select="'n'"/>
42
43 <!-- Should we remove .la files after chapter 5 and chapter 6? -->
44 <xsl:param name='del-la-files' select="'y'"/>
45
46 <!-- Time zone -->
47 <xsl:param name="timezone" select="'GMT'"/>
48
49 <!-- Page size -->
50 <xsl:param name="page" select="'letter'"/>
51
52 <!-- Locale settings -->
53 <xsl:param name="lang" select="'C'"/>
54
55 <!-- Install the whole set of locales -->
56 <xsl:param name='full-locale' select='"n"'/>
57
58 <!-- Hostname -->
59 <xsl:param name='hostname' select='"HOSTNAME"'/>
60
61 <!-- Network parameters: interface, ip, gateway, prefix, broadcast, domain
62 and nameservers -->
63 <xsl:param name='interface' select="'eth0'"/>
64 <xsl:param name='ip' select='"10.0.2.9"'/>
65 <xsl:param name='gateway' select='"10.0.2.2"'/>
66 <xsl:param name='prefix' select='24'/>
67 <xsl:param name='broadcast' select='"10.0.2.255"'/>
68 <xsl:param name='domain' select='"lfs.org"'/>
69 <xsl:param name='nameserver1' select='"10.0.2.3"'/>
70 <xsl:param name='nameserver2' select='"8.8.8.8"'/>
71
72 <!-- Console parameters: font, fontmap, unicode (y/n), keymap, local (y:
73 hardware clock set to local time/n:hardware clock set to UTC)
74 and log-level -->
75 <xsl:param name='font' select="'lat0-16'"/>
76 <xsl:param name='keymap' select="'us'"/>
77 <xsl:param name='local' select="'n'"/>
78 <xsl:param name='log-level' select="'4'"/>
79
80 <!-- The scripts root is needed for printing disk usage -->
81 <xsl:param name='script-root' select="'jhalfs'"/>
82
83<!-- End parameters -->
84
85<!-- bashdir is used at the beginning of chapter 6, for the #! line.
86 If we created a /tools directory in chapter 4, bash is in /tools/bin,
87otherwise it is in /bin.-->
88 <xsl:variable name="bashdir">
89 <xsl:choose>
90 <xsl:when test="//sect1[@id='ch-preps-creatingtoolsdir']">
91 <xsl:text>/tools</xsl:text>
92 </xsl:when>
93 <xsl:otherwise>
94 <xsl:text></xsl:text>
95 </xsl:otherwise>
96 </xsl:choose>
97 </xsl:variable>
98
99<!-- Start of templates -->
100 <xsl:template match="/">
101 <xsl:apply-templates select="//chapter[
102 @id='chapter-final-preps' or
103 @id='chapter-cross-tools' or
104 @id='chapter-temporary-tools' or
105 @id='chapter-chroot-temporary-tools' or
106 @id='chapter-building-system' or
107 @id='chapter-config' or
108 @id='chapter-bootscripts' or
109 @id='chapter-bootable']"/>
110 </xsl:template>
111
112 <xsl:template match="chapter">
113 <xsl:apply-templates select="./sect1[
114 .//screen[not(@role) or @role != 'nodump']/
115 userinput[not(starts-with(string(),'chroot'))]]">
116 <xsl:with-param name="chap-num" select="position()+3"/>
117 </xsl:apply-templates>
118<!-- The last condition is a hack to allow old versions of the
119 book where the chroot commands did not have role="nodump".
120 It only works if the chroot command is the only one on the page -->
121 </xsl:template>
122
123 <xsl:template match="sect1">
124 <xsl:param name="chap-num" select="'1'"/>
125 <!-- The dirs names -->
126 <xsl:variable name="pi-dir" select="../processing-instruction('dbhtml')"/>
127 <xsl:variable name="pi-dir-value" select="substring-after($pi-dir,'dir=')"/>
128 <xsl:variable name="quote-dir" select="substring($pi-dir-value,1,1)"/>
129 <xsl:variable name="dirname" select="substring-before(substring($pi-dir-value,2),$quote-dir)"/>
130 <!-- The file names -->
131 <xsl:variable name="pi-file" select="processing-instruction('dbhtml')"/>
132 <xsl:variable name="pi-file-value" select="substring-after($pi-file,'filename=')"/>
133 <xsl:variable name="filename" select="substring-before(substring($pi-file-value,2),'.html')"/>
134 <!-- The build order -->
135 <xsl:variable name="position" select="position()"/>
136 <xsl:variable name="order">
137 <xsl:value-of select="$chap-num"/>
138 <xsl:if test="string-length($position) = 1">
139 <xsl:text>0</xsl:text>
140 </xsl:if>
141 <xsl:value-of select="$position"/>
142 </xsl:variable>
143 <!-- Creating dirs and files -->
144 <exsl:document href="{$dirname}/{$order}-{$filename}" method="text">
145 <xsl:text>#!</xsl:text>
146 <xsl:if test="@id='ch-system-creatingdirs' or
147 @id='ch-system-createfiles' or
148 @id='ch-system-strippingagain' or
149 @id='ch-system-stripping'">
150 <xsl:copy-of select="$bashdir"/>
151 </xsl:if>
152 <xsl:text>/bin/bash&#xA;set +h&#xA;</xsl:text>
153 <xsl:if test="not(@id='ch-tools-stripping') and
154 not(@id='ch-system-strippingagain') and
155 not(@id='ch-system-stripping')">
156 <xsl:text>set -e&#xA;</xsl:text>
157 </xsl:if>
158 <xsl:text>&#xA;</xsl:text>
159 <xsl:if test="ancestor::chapter/@id != 'chapter-final-preps'">
160 <xsl:call-template name="start-script">
161 <xsl:with-param name="order" select="$order"/>
162 </xsl:call-template>
163 </xsl:if>
164 <xsl:apply-templates
165 select="sect2 |
166 screen[not(@role) or @role!='nodump']/userinput"/>
167 <xsl:if test="contains(@id,'creatingdirs') and $pkgmngt='y'">
168 <xsl:apply-templates
169 select="document('packageManager.xml')//sect1[
170 @id='ch-pkgmngt-creatingdirs'
171 ]//userinput"
172 mode="pkgmngt"/>
173 </xsl:if>
174 <xsl:if test="contains(@id,'createfiles') and $pkgmngt='y'">
175 <xsl:apply-templates
176 select="document('packageManager.xml')//sect1[
177 @id='ch-pkgmngt-createfiles'
178 ]//userinput"
179 mode="pkgmngt"/>
180 </xsl:if>
181 <xsl:if test="ancestor::chapter/@id != 'chapter-final-preps'">
182 <xsl:text>echo -e "\n\nTotalseconds: $SECONDS\n"&#xA;</xsl:text>
183 <xsl:call-template name="end-script"/>
184 </xsl:if>
185 <xsl:text>exit&#xA;</xsl:text>
186 </exsl:document>
187 <!-- Inclusion of package manager scriptlets -->
188 <xsl:if test="$pkgmngt='y' and
189 following-sibling::sect1[1][@id='ch-tools-stripping' or @id='ch-tools-cleanup']">
190 <xsl:apply-templates
191 select="document('packageManager.xml')//sect1[
192 contains(@id,'ch-chroot')]"
193 mode="pkgmngt">
194 <xsl:with-param name="order" select="$order+1"/>
195 <xsl:with-param name="dirname" select="$dirname"/>
196 </xsl:apply-templates>
197 </xsl:if>
198 <xsl:if test="$pkgmngt='y' and
199 following-sibling::sect1[2][@id='ch-system-strippingagain' or @id='ch-system-stripping']">
200 <xsl:apply-templates
201 select="document('packageManager.xml')//sect1[
202 contains(@id,'ch-system')]"
203 mode="pkgmngt">
204 <xsl:with-param name="order" select="$order+1"/>
205 <xsl:with-param name="dirname" select="$dirname"/>
206 </xsl:apply-templates>
207 </xsl:if>
208 </xsl:template>
209
210 <xsl:template match="sect2">
211 <xsl:apply-templates
212 select=".//screen[not(@role) or @role != 'nodump']/userinput[
213 @remap = 'pre' or
214 @remap = 'configure' or
215 @remap = 'make' or
216 @remap = 'test' and
217 not(current()/../@id='ch-tools-dejagnu') and
218 not(current()/../@id='ch-system-systemd')]"/>
219 <xsl:if
220 test="ancestor::chapter[@id = 'chapter-building-system' or
221 @id = 'chapter-config' or
222 @id = 'chapter-bootscripts' or
223 @id = 'chapter-bootable'] and
224 $pkgmngt = 'y' and
225 descendant::screen[not(@role) or
226 @role != 'nodump']/userinput[
227 @remap='install']">
228 <xsl:choose>
229 <xsl:when test="$wrap-install='y'">
230 <xsl:text>wrapInstall '
231</xsl:text>
232 </xsl:when>
233 <xsl:otherwise>
234<!-- We cannot know which directory(ies) are needed by the package. Create a
235 reasonable bunch of them. Should be close to "Creating Directories".
236 Create also symlinks from /lib, /bin, /sbin to their counterpart
237 in usr, so that the package only has files in /usr-->
238 <xsl:text>mkdir -pv $PKG_DEST/{boot,etc}
239mkdir -pv $PKG_DEST/usr/{bin,include,lib/pkgconfig,sbin}
240mkdir -pv $PKG_DEST/usr/share/{doc,info,bash-completion/completions}
241mkdir -pv $PKG_DEST/usr/share/man/man{1..8}
242case $(uname -m) in
243 x86_64) mkdir -v $PKG_DEST/lib64 ;;
244esac
245ln -sv usr/sbin $PKG_DEST
246ln -sv usr/bin $PKG_DEST
247ln -sv usr/lib $PKG_DEST
248</xsl:text>
249 </xsl:otherwise>
250 </xsl:choose>
251 </xsl:if>
252 <xsl:apply-templates
253 select=".//screen[not(@role) or @role != 'nodump']/
254 userinput[@remap = 'install']"/>
255 <xsl:if test="ancestor::chapter[@id = 'chapter-building-system' or
256 @id = 'chapter-config' or
257 @id = 'chapter-bootscripts' or
258 @id = 'chapter-bootable'] and
259 descendant::screen[not(@role) or
260 @role != 'nodump']/userinput[
261 @remap='install']">
262 <xsl:choose>
263 <xsl:when test="$pkgmngt='n'"/>
264 <xsl:when test="$wrap-install='y'">
265 <xsl:if test="../@id = 'ch-system-man-pages'">
266<!-- these files are provided by the shadow package -->
267 <xsl:text>rm -fv /usr/share/man/{man3/getspnam.3,man5/passwd.5}
268</xsl:text>
269 </xsl:if>
270<!-- nologin is installed by util-linux. remove it from shadow -->
271 <xsl:if test="../@id = 'ch-system-shadow'">
272 <xsl:text>rm -fv /usr/share/man/man8/nologin.8
273rm -fv /sbin/nologin
274</xsl:text>
275 </xsl:if>
276 <xsl:text>'
277PREV_SEC=${SECONDS}
278packInstall
279SECONDS=${PREV_SEC}
280</xsl:text>
281 </xsl:when>
282 <xsl:otherwise>
283 <xsl:if test="../@id = 'ch-system-man-pages'">
284<!-- these files are provided by the shadow package -->
285 <xsl:text>rm -fv $PKG_DEST/usr/share/man/{man3/getspnam.3,man5/passwd.5}
286</xsl:text>
287 </xsl:if>
288<!-- nologin is installed by util-linux. remove it from shadow -->
289 <xsl:if test="../@id = 'ch-system-shadow'">
290 <xsl:text>rm -fv $PKG_DEST/usr/share/man/man8/nologin.8
291rm -fv $PKG_DEST/sbin/nologin
292</xsl:text>
293 </xsl:if>
294<!-- remove empty directories and symlinks-->
295 <xsl:text>for dir in $PKG_DEST/usr/share/man/man{1..8} \
296 $PKG_DEST/usr/share/bash-completion{/completions,} \
297 $PKG_DEST/usr/share/{doc,info,man,} \
298 $PKG_DEST/usr/lib/pkgconfig \
299 $PKG_DEST/usr/{lib,bin,sbin,include} \
300 $PKG_DEST/{boot,etc}; do
301 [ -d "$dir" ] &amp;&amp; [ -z "$(ls $dir)" ] &amp;&amp; rmdir -v $dir
302done
303[ -d $PKG_DEST/lib64 ] &amp;&amp; [ -z "$(ls $PKG_DEST/lib64)" ] &amp;&amp;
304 rmdir -v $PKG_DEST/lib64
305rm -v $PKG_DEST/{lib,bin,sbin}
306<!-- prevent overwriting symlinks: if a package install something in
307 these directories, it'll be lost if not using package management,
308 since they are symlinks to tmpfs. So, remove it too if using PM. -->
309rm -rf $PKG_DEST/var/{run,lock}
310<!-- Remove /var if it is empty, then -->
311[ -d $PKG_DEST/var ] &amp;&amp; [ -z "$(ls $PKG_DEST/var)" ] &amp;&amp; rmdir -v $PKG_DEST/var
312PREV_SEC=${SECONDS}
313packInstall
314SECONDS=${PREV_SEC}
315rm -rf $PKG_DEST
316</xsl:text>
317 </xsl:otherwise>
318 </xsl:choose>
319 </xsl:if>
320 <xsl:if test="../@id='ch-system-glibc' and @role='installation'">
321 <xsl:choose>
322 <xsl:when test="$full-locale='y'">
323 <xsl:for-each select="//userinput[@remap='locale-full']">
324 <xsl:copy-of select="."/>
325 <xsl:text>&#xA;</xsl:text>
326 </xsl:for-each>
327 </xsl:when>
328 <xsl:otherwise>
329 <xsl:copy-of select="//userinput[@remap='locale-test']"/>
330 <xsl:text>&#xA;</xsl:text>
331 <xsl:if test="not(contains(string(//userinput[@remap='locale-test']),$lang)) and $lang!='C' and $lang!='POSIX'">
332 <xsl:text>if LOCALE=`grep "</xsl:text>
333 <xsl:value-of select="$lang"/>
334 <xsl:text>/" $PKGDIR/localedata/SUPPORTED`; then
335 CHARMAP=`echo $LOCALE | sed 's,[^/]*/\([^ ]*\) [\],\1,'`
336 INPUT=`echo $LOCALE | sed 's,[/.].*,,'`
337 LOCALE=`echo $LOCALE | sed 's,/.*,,'`
338 localedef -i $INPUT -f $CHARMAP $LOCALE
339fi
340</xsl:text>
341 </xsl:if>
342 </xsl:otherwise>
343 </xsl:choose>
344 </xsl:if>
345 <xsl:apply-templates
346 select=".//screen[not(@role) or @role != 'nodump']/userinput[
347 not(@remap) or
348 @remap='adjust' or
349 @remap='test' and current()/../@id='ch-tools-dejagnu' or
350 @remap='test' and current()/../@id='ch-system-systemd'
351 ]"/>
352 <xsl:if test="../@id='ch-system-ncurses' and $ncurses5='y'">
353 <xsl:apply-templates select=".//screen[@role='nodump']"/>
354 </xsl:if>
355 </xsl:template>
356
357 <xsl:template match="sect1" mode="pkgmngt">
358 <xsl:param name="dirname" select="'chapter05'"/>
359 <!-- The build order -->
360 <xsl:param name="order" select="'062'"/>
361<!-- The file names -->
362 <xsl:variable name="pi-file" select="processing-instruction('dbhtml')"/>
363 <xsl:variable name="pi-file-value" select="substring-after($pi-file,'filename=')"/>
364 <xsl:variable name="filename" select="substring-before(substring($pi-file-value,2),'.html')"/>
365 <xsl:variable name="pos">
366 <xsl:if test="string-length(position()) = 1">
367 <xsl:text>0</xsl:text>
368 </xsl:if>
369 <xsl:value-of select="position()"/>
370 </xsl:variable>
371 <!-- Creating dirs and files -->
372 <xsl:if test="count(descendant::screen/userinput) &gt; 0 and
373 count(descendant::screen/userinput) &gt;
374 count(descendant::screen[@role='nodump'])">
375 <exsl:document href="{$dirname}/{$order}-{$pos}-{$filename}"
376 method="text">
377 <xsl:text>#!/bin/bash
378set +h
379set -e
380</xsl:text>
381 <xsl:call-template name="start-script">
382 <xsl:with-param name="order" select="concat($order,'-',$pos)"/>
383 </xsl:call-template>
384 <xsl:apply-templates
385 select=".//screen[not(@role) or
386 @role != 'nodump']/userinput[@remap != 'adjust']"
387 mode="pkgmngt"/>
388 <xsl:if test="$dirname = 'chapter06' or $dirname = 'chapter08'">
389 <xsl:text>PREV_SEC=${SECONDS}
390packInstall
391SECONDS=${PREV_SEC}
392rm -rf "$PKG_DEST"
393</xsl:text>
394 </xsl:if>
395 <xsl:apply-templates
396 select=".//screen[not(@role) or
397 @role != 'nodump'
398 ]/userinput[not(@remap) or
399 @remap='adjust'
400 ]"
401 mode="pkgmngt"/>
402 <xsl:text>
403echo -e "\n\nTotalseconds: $SECONDS\n"
404</xsl:text>
405 <xsl:call-template name="end-script"/>
406 <xsl:text>exit
407</xsl:text>
408 </exsl:document>
409 </xsl:if>
410 </xsl:template>
411
412 <xsl:template match="userinput" mode="pkgmngt">
413 <xsl:apply-templates/>
414 <xsl:text>&#xA;</xsl:text>
415 </xsl:template>
416
417 <xsl:template match="userinput">
418 <xsl:choose>
419 <!-- Copying the kernel config file -->
420 <xsl:when test="string() = 'make mrproper'">
421 <xsl:text>make mrproper&#xA;</xsl:text>
422 <xsl:if test="ancestor::sect1[@id='ch-bootable-kernel']">
423 <xsl:text>cp -v ../kernel-config .config&#xA;</xsl:text>
424 <xsl:text>timeout 60 make oldconfig ||\&#xA;</xsl:text>
425 <xsl:text>{ echo kernel config is not up to date; exit 124; }&#xA;</xsl:text>
426 </xsl:if>
427 </xsl:when>
428<!-- test instructions -->
429 <xsl:when test="@remap = 'test'">
430 <xsl:call-template name="comment-test">
431 <xsl:with-param name="instructions" select="string()"/>
432 </xsl:call-template>
433 </xsl:when>
434<!-- End of test instructions -->
435<!-- If the instructions contain "strip ", it may mean they contain also .la
436 file removal (and possibly other clean up). We therefore call a template
437 to comment them out appropriately and also to not stop if stripping
438 fails. -->
439 <xsl:when test="contains(string(),'strip ') or
440 contains(string(),'\*.la')">
441 <xsl:call-template name="comment-strip">
442 <xsl:with-param name="instructions" select="string()"/>
443 </xsl:call-template>
444 </xsl:when>
445<!-- Package management for installation chapters -->
446<!-- Add $PKG_DEST to installation commands -->
447<!-- Also add -j1 to make install -->
448 <xsl:when test="@remap='install' and
449 ancestor::chapter[@id='chapter-building-system' or
450 @id = 'chapter-config' or
451 @id = 'chapter-bootscripts' or
452 @id = 'chapter-bootable']">
453 <xsl:choose>
454 <xsl:when test="$pkgmngt='n'">
455 <xsl:choose>
456 <xsl:when test="contains(string(),'firmware,udev')">
457 <xsl:text>if [[ ! -d /lib/udev/devices ]] ; then&#xA;</xsl:text>
458 <xsl:apply-templates/>
459 <xsl:text>&#xA;fi&#xA;</xsl:text>
460 </xsl:when>
461 <xsl:when test="contains(string(),'make ')">
462 <xsl:copy-of select="substring-before(string(), 'make ')"/>
463 <xsl:text>make -j1 </xsl:text>
464 <xsl:copy-of select="substring-after(string(), 'make ')"/>
465 <xsl:text>&#xA;</xsl:text>
466 </xsl:when>
467 <xsl:otherwise>
468 <xsl:apply-templates/>
469 <xsl:text>&#xA;</xsl:text>
470 </xsl:otherwise>
471 </xsl:choose>
472 </xsl:when>
473 <xsl:when test="$wrap-install='y'">
474 <xsl:choose>
475 <xsl:when test="./literal">
476 <xsl:call-template name="output-wrap">
477 <xsl:with-param name="commands" select="text()[1]"/>
478 </xsl:call-template>
479 <xsl:apply-templates select="literal"/>
480 <xsl:call-template name="output-wrap">
481 <xsl:with-param name="commands" select="text()[2]"/>
482 </xsl:call-template>
483 </xsl:when>
484 <xsl:otherwise>
485 <xsl:call-template name="output-wrap">
486 <xsl:with-param name="commands" select="string()"/>
487 </xsl:call-template>
488 </xsl:otherwise>
489 </xsl:choose>
490 <xsl:text>&#xA;</xsl:text>
491 </xsl:when>
492 <xsl:otherwise><!--pkgmngt = 'y' and wrap-install='n'-->
493 <xsl:choose>
494 <xsl:when test="./literal">
495 <xsl:call-template name="outputpkgdest">
496 <xsl:with-param name="outputstring" select="text()[1]"/>
497 </xsl:call-template>
498 <xsl:apply-templates select="literal"/>
499 <xsl:call-template name="outputpkgdest">
500 <xsl:with-param name="outputstring" select="text()[2]"/>
501 </xsl:call-template>
502 </xsl:when>
503 <xsl:otherwise>
504 <xsl:call-template name="outputpkgdest">
505 <xsl:with-param name="outputstring" select="string()"/>
506 </xsl:call-template>
507 </xsl:otherwise>
508 </xsl:choose>
509 <xsl:text>&#xA;</xsl:text>
510 </xsl:otherwise>
511 </xsl:choose>
512 </xsl:when> <!-- @remap='install' and not temporary tools -->
513 <!-- if package management, we should make an independant package for
514 tzdata. -->
515 <xsl:when test="contains(string(),'tzdata') and $pkgmngt='y'">
516 <xsl:text>
517OLD_PKG_DEST="$PKG_DEST"
518OLD_PKGDIR=$PKGDIR
519PKG_DEST=$(dirname $OLD_PKG_DEST)/001-tzdata
520PKGDIR=$(dirname $PKGDIR)/tzdata-</xsl:text>
521 <xsl:copy-of select="substring-before(
522 substring-after(string(),'tzdata'),
523 '.tar')"/>
524 <xsl:text>
525</xsl:text>
526 <xsl:choose>
527 <xsl:when test="$wrap-install='n'">
528 <xsl:copy-of select="substring-before(string(),'ZONEINFO=')"/>
529 <xsl:text>ZONEINFO=$PKG_DEST</xsl:text>
530 <xsl:copy-of select="substring-after(string(),'ZONEINFO=')"/>
531 <xsl:text>
532PREV_SEC=${SECONDS}
533packInstall
534SECONDS=${PREV_SEC}
535rm -rf $PKG_DEST
536</xsl:text>
537 </xsl:when>
538 <xsl:otherwise><!-- wrap-install='y' -->
539 <xsl:copy-of select="substring-before(string(),'ZONEINFO=')"/>
540 <xsl:text>
541wrapInstall '
542ZONEINFO=</xsl:text>
543 <xsl:copy-of select="substring-after(string(),'ZONEINFO=')"/>
544 <xsl:text>'
545PREV_SEC=${SECONDS}
546packInstall
547SECONDS=${PREV_SEC}
548</xsl:text>
549 </xsl:otherwise>
550 </xsl:choose>
551 <xsl:text>
552PKG_DEST=$OLD_PKG_DEST
553unset OLD_PKG_DEST
554PKGDIR=$OLD_PKGDIR
555unset OLD_PKGDIR
556</xsl:text>
557 </xsl:when><!-- addition for tzdata + package management -->
558 <!-- End addition for package management -->
559 <!-- add -j1 to make install in non final chapters -->
560 <xsl:when test="ancestor::chapter[@id='chapter-temporary-tools' or
561 @id='chapter-chroot-temporary-tools' or
562 @id='chapter-cross-tools'] and
563 @remap='install'">
564 <xsl:choose>
565 <xsl:when test="contains(string(),'make ')">
566 <xsl:copy-of select="substring-before(string(), 'make ')"/>
567 <xsl:text>make -j1 </xsl:text>
568 <xsl:copy-of select="substring-after(string(), 'make ')"/>
569 </xsl:when>
570 <xsl:otherwise>
571 <xsl:apply-templates/>
572 </xsl:otherwise>
573 </xsl:choose>
574 <xsl:text>&#xA;</xsl:text>
575 </xsl:when><!-- temp chapters install -->
576 <!-- The rest of commands -->
577 <xsl:otherwise>
578 <xsl:apply-templates/>
579 <xsl:text>&#xA;</xsl:text>
580 </xsl:otherwise>
581 </xsl:choose>
582 </xsl:template>
583
584 <xsl:template match="replaceable">
585 <xsl:choose>
586 <xsl:when test="ancestor::sect1[@id='ch-system-glibc']">
587 <xsl:value-of select="$timezone"/>
588 </xsl:when>
589 <xsl:when test="ancestor::sect1[@id='ch-system-groff']">
590 <xsl:value-of select="$page"/>
591 </xsl:when>
592 <xsl:when test="contains(string(.),'&lt;ll&gt;_&lt;CC&gt;')">
593 <xsl:value-of select="$lang"/>
594 </xsl:when>
595 <xsl:when test="contains(string(.),'Domain')">
596 <xsl:value-of select="$domain"/>
597 </xsl:when>
598 <xsl:when test="contains(string(.),'primary')">
599 <xsl:value-of select="$nameserver1"/>
600 </xsl:when>
601 <xsl:when test="contains(string(.),'secondary')">
602 <xsl:value-of select="$nameserver2"/>
603 </xsl:when>
604 <xsl:when test="contains(string(.),'192.168.1.1')">
605 <xsl:value-of select="$ip"/>
606 </xsl:when>
607 <xsl:when test="contains(string(.),'192.168.0.2')">
608 <xsl:value-of select="$ip"/>
609 </xsl:when>
610 <xsl:when test="contains(string(.),'eth0')">
611 <xsl:value-of select="$interface"/>
612 </xsl:when>
613<!-- Only adapted to LFS-20170310 and later -->
614 <xsl:when test="contains(string(.),'HOSTNAME')">
615 <xsl:value-of select="$hostname"/>
616 </xsl:when>
617 <xsl:when test="contains(string(.),'FQDN')">
618 <xsl:value-of select="$hostname"/>
619 <xsl:text>.</xsl:text>
620 <xsl:value-of select="$domain"/>
621 </xsl:when>
622 <xsl:when test="contains(string(.),'alias')"/>
623 <xsl:when test="contains(string(.),'&lt;lfs&gt;')">
624 <xsl:value-of select="$hostname"/>
625 </xsl:when>
626 <xsl:when test="contains(string(.),'$(nproc)')">
627 <xsl:value-of select="$jobs"/>
628 </xsl:when>
629 <xsl:otherwise>
630 <xsl:text>**EDITME</xsl:text>
631 <xsl:apply-templates/>
632 <xsl:text>EDITME**</xsl:text>
633 </xsl:otherwise>
634 </xsl:choose>
635 </xsl:template>
636
637 <xsl:template match="literal">
638 <xsl:choose>
639 <xsl:when test="contains(string(),'ONBOOT')">
640 <xsl:call-template name="outputnet">
641 <xsl:with-param name="netstring" select="string()"/>
642 </xsl:call-template>
643 </xsl:when>
644 <xsl:when test="contains(string(),'[Match]')">
645 <xsl:call-template name="outputsysdnet">
646 <xsl:with-param name="netstring" select="string()"/>
647 </xsl:call-template>
648 </xsl:when>
649 <xsl:when test="contains(string(),'0.0 0 0.0')">
650 <xsl:copy-of select="substring-before(string(),'LOCAL')"/>
651 <xsl:if test="$local='y'"><xsl:text>LOCAL</xsl:text></xsl:if>
652 <xsl:if test="$local='n'"><xsl:text>UTC</xsl:text></xsl:if>
653 </xsl:when>
654 <xsl:when test="contains(string(),'UTC=1')">
655 <xsl:copy-of select="substring-before(string(),'1')"/>
656 <xsl:if test="$local='y'"><xsl:text>0</xsl:text></xsl:if>
657 <xsl:if test="$local='n'"><xsl:text>1</xsl:text></xsl:if>
658 <xsl:copy-of select="substring-after(string(),'1')"/>
659 </xsl:when>
660 <xsl:when test="contains(string(),'bg_bds-')">
661 <xsl:call-template name="outputsysvconsole">
662 <xsl:with-param name="consolestring" select="string()"/>
663 </xsl:call-template>
664 </xsl:when>
665 <xsl:when test="contains(string(),'de-latin1')">
666 <xsl:call-template name="outputsysdconsole">
667 <xsl:with-param name="consolestring" select="string()"/>
668 </xsl:call-template>
669 </xsl:when>
670 <xsl:otherwise>
671 <xsl:apply-templates/>
672 </xsl:otherwise>
673 </xsl:choose>
674 </xsl:template>
675
676 <xsl:template name="outputnet">
677 <xsl:param name="netstring" select="''"/>
678 <!-- We suppose that book example has the following values:
679 - interface: eth0
680 - ip: 192.168.1.2
681 - gateway: 192.168.1.1
682 - prefix: 24
683 - broadcast: 192.168.1.255
684 Change below if book changes -->
685 <xsl:choose>
686 <xsl:when test="contains($netstring,'eth0')">
687 <xsl:call-template name="outputnet">
688 <xsl:with-param name="netstring"
689 select="substring-before($netstring,'eth0')"/>
690 </xsl:call-template>
691 <xsl:value-of select="$interface"/>
692 <xsl:call-template name="outputnet">
693 <xsl:with-param name="netstring"
694 select="substring-after($netstring,'eth0')"/>
695 </xsl:call-template>
696 </xsl:when>
697 <xsl:when test="contains($netstring,'192.168.1.1')">
698 <xsl:call-template name="outputnet">
699 <xsl:with-param name="netstring"
700 select="substring-before($netstring,'192.168.1.1')"/>
701 </xsl:call-template>
702 <xsl:value-of select="$gateway"/>
703 <xsl:call-template name="outputnet">
704 <xsl:with-param name="netstring"
705 select="substring-after($netstring,'192.168.1.1')"/>
706 </xsl:call-template>
707 </xsl:when>
708 <!-- must test this before the following, because 192.168.1.255 contains
709 192.168.1.2! -->
710 <xsl:when test="contains($netstring,'192.168.1.255')">
711 <xsl:call-template name="outputnet">
712 <xsl:with-param name="netstring"
713 select="substring-before($netstring,'192.168.1.255')"/>
714 </xsl:call-template>
715 <xsl:value-of select="$broadcast"/>
716 <xsl:call-template name="outputnet">
717 <xsl:with-param name="netstring"
718 select="substring-after($netstring,'192.168.1.255')"/>
719 </xsl:call-template>
720 </xsl:when>
721 <xsl:when test="contains($netstring,'192.168.1.2')">
722 <xsl:call-template name="outputnet">
723 <xsl:with-param name="netstring"
724 select="substring-before($netstring,'192.168.1.2')"/>
725 </xsl:call-template>
726 <xsl:value-of select="$ip"/>
727 <xsl:call-template name="outputnet">
728 <xsl:with-param name="netstring"
729 select="substring-after($netstring,'192.168.1.2')"/>
730 </xsl:call-template>
731 </xsl:when>
732 <xsl:when test="contains($netstring,'24')">
733 <xsl:call-template name="outputnet">
734 <xsl:with-param name="netstring"
735 select="substring-before($netstring,'24')"/>
736 </xsl:call-template>
737 <xsl:value-of select="$prefix"/>
738 <xsl:call-template name="outputnet">
739 <xsl:with-param name="netstring"
740 select="substring-after($netstring,'24')"/>
741 </xsl:call-template>
742 </xsl:when>
743 <xsl:otherwise>
744 <xsl:value-of select="$netstring"/>
745 </xsl:otherwise>
746 </xsl:choose>
747 </xsl:template>
748
749 <xsl:template name="outputsysdnet">
750 <xsl:param name="netstring" select="''"/>
751 <!-- We suppose that book example has the following values:
752 - interface: <network-device-name>
753 - ip: 192.168.0.2
754 - gateway: 192.168.0.1
755 - prefix: 24
756 - DNS: 192.168.0.1
757 - Domain: <Your Domain Name>
758 and gateway comes before DNS. Change below if book changes -->
759 <xsl:choose>
760 <xsl:when test="contains($netstring,'&lt;network-device-name&gt;')">
761 <xsl:call-template name="outputsysdnet">
762 <xsl:with-param name="netstring"
763 select="substring-before($netstring,'&lt;network-device-name&gt;')"/>
764 </xsl:call-template>
765 <xsl:value-of select="$interface"/>
766 <xsl:call-template name="outputsysdnet">
767 <xsl:with-param name="netstring"
768 select="substring-after($netstring,'&lt;network-device-name&gt;')"/>
769 </xsl:call-template>
770 </xsl:when>
771 <xsl:when test="contains($netstring,'192.168.0.1') and
772 contains($netstring,'Gateway')">
773 <xsl:call-template name="outputsysdnet">
774 <xsl:with-param name="netstring"
775 select="substring-before($netstring,'192.168.0.1')"/>
776 </xsl:call-template>
777 <xsl:value-of select="$gateway"/>
778 <xsl:call-template name="outputsysdnet">
779 <xsl:with-param name="netstring"
780 select="substring-after($netstring,'192.168.0.1')"/>
781 </xsl:call-template>
782 </xsl:when>
783 <xsl:when test="contains($netstring,'192.168.0.1') and
784 not(contains($netstring,'Gateway'))">
785 <xsl:call-template name="outputsysdnet">
786 <xsl:with-param name="netstring"
787 select="substring-before($netstring,'192.168.0.1')"/>
788 </xsl:call-template>
789 <xsl:value-of select="$nameserver1"/>
790 <xsl:text>
791DNS=</xsl:text>
792 <xsl:value-of select="$nameserver2"/>
793 <xsl:call-template name="outputsysdnet">
794 <xsl:with-param name="netstring"
795 select="substring-after($netstring,'192.168.0.1')"/>
796 </xsl:call-template>
797 </xsl:when>
798 <xsl:when test="contains($netstring,'192.168.0.2')">
799 <xsl:call-template name="outputsysdnet">
800 <xsl:with-param name="netstring"
801 select="substring-before($netstring,'192.168.0.2')"/>
802 </xsl:call-template>
803 <xsl:value-of select="$ip"/>
804 <xsl:call-template name="outputsysdnet">
805 <xsl:with-param name="netstring"
806 select="substring-after($netstring,'192.168.0.2')"/>
807 </xsl:call-template>
808 </xsl:when>
809 <xsl:when test="contains($netstring,'24')">
810 <xsl:call-template name="outputsysdnet">
811 <xsl:with-param name="netstring"
812 select="substring-before($netstring,'24')"/>
813 </xsl:call-template>
814 <xsl:value-of select="$prefix"/>
815 <xsl:call-template name="outputsysdnet">
816 <xsl:with-param name="netstring"
817 select="substring-after($netstring,'24')"/>
818 </xsl:call-template>
819 </xsl:when>
820 <xsl:when test="contains($netstring,'&lt;Your Domain Name&gt;')">
821 <xsl:call-template name="outputsysdnet">
822 <xsl:with-param name="netstring"
823 select="substring-before($netstring,'&lt;Your Domain Name&gt;')"/>
824 </xsl:call-template>
825 <xsl:value-of select="$domain"/>
826 <xsl:call-template name="outputsysdnet">
827 <xsl:with-param name="netstring"
828 select="substring-after($netstring,'&lt;Your Domain Name&gt;')"/>
829 </xsl:call-template>
830 </xsl:when>
831 <xsl:otherwise>
832 <xsl:value-of select="$netstring"/>
833 </xsl:otherwise>
834 </xsl:choose>
835 </xsl:template>
836
837 <xsl:template name="outputsysvconsole">
838 <!-- We suppose that book example has the following values:
839 - KEYMAP: bg_bds-utf8
840 - FONT: LatArCyrHeb-16
841 Change below if book changes -->
842 <xsl:param name="consolestring" select="''"/>
843 <xsl:choose>
844 <xsl:when test="contains($consolestring,'bg_bds-utf8')">
845 <xsl:call-template name="outputsysvconsole">
846 <xsl:with-param
847 name="consolestring"
848 select="substring-before($consolestring,'bg_bds-utf8')"/>
849 </xsl:call-template>
850 <xsl:value-of select="$keymap"/>
851 <xsl:call-template name="outputsysvconsole">
852 <xsl:with-param
853 name="consolestring"
854 select="substring-after($consolestring,'bg_bds-utf8')"/>
855 </xsl:call-template>
856 </xsl:when>
857 <xsl:when test="contains($consolestring,'LatArCyrHeb-16')">
858 <xsl:call-template name="outputsysvconsole">
859 <xsl:with-param
860 name="consolestring"
861 select="substring-before($consolestring,'LatArCyrHeb-16')"/>
862 </xsl:call-template>
863 <xsl:value-of select="$font"/>
864 <xsl:text>"
865LOGLEVEL="</xsl:text>
866 <xsl:copy-of select="$log-level"/>
867 <xsl:call-template name="outputsysvconsole">
868 <xsl:with-param
869 name="consolestring"
870 select="substring-after($consolestring,'LatArCyrHeb-16')"/>
871 </xsl:call-template>
872 </xsl:when>
873 <xsl:otherwise>
874 <xsl:copy-of select="$consolestring"/>
875 </xsl:otherwise>
876 </xsl:choose>
877 </xsl:template>
878
879 <xsl:template name="outputsysdconsole">
880 <!-- We suppose that book example has the following values:
881 - KEYMAP: de-latin1
882 - FONT: Lat2-Terminus16
883 Change below if book changes -->
884 <xsl:param name="consolestring" select="''"/>
885 <xsl:choose>
886 <xsl:when test="contains($consolestring,'de-latin1')">
887 <xsl:call-template name="outputsysdconsole">
888 <xsl:with-param
889 name="consolestring"
890 select="substring-before($consolestring,'de-latin1')"/>
891 </xsl:call-template>
892 <xsl:value-of select="$keymap"/>
893 <xsl:call-template name="outputsysdconsole">
894 <xsl:with-param
895 name="consolestring"
896 select="substring-after($consolestring,'de-latin1')"/>
897 </xsl:call-template>
898 </xsl:when>
899 <xsl:when test="contains($consolestring,'Lat2-Terminus16')">
900 <xsl:call-template name="outputsysdconsole">
901 <xsl:with-param
902 name="consolestring"
903 select="substring-before($consolestring,'Lat2-Terminus16')"/>
904 </xsl:call-template>
905 <xsl:value-of select="$font"/>
906 <xsl:call-template name="outputsysdconsole">
907 <xsl:with-param
908 name="consolestring"
909 select="substring-after($consolestring,'Lat2-Terminus16')"/>
910 </xsl:call-template>
911 </xsl:when>
912 <xsl:otherwise>
913 <xsl:copy-of select="$consolestring"/>
914 </xsl:otherwise>
915 </xsl:choose>
916 </xsl:template>
917
918 <xsl:template name="outputpkgdest">
919 <xsl:param name="outputstring" select="foo"/>
920 <xsl:choose>
921 <xsl:when test="contains($outputstring,'make ')">
922 <xsl:choose>
923 <xsl:when test="not(starts-with($outputstring,'make'))">
924 <xsl:call-template name="outputpkgdest">
925 <xsl:with-param name="outputstring"
926 select="substring-before($outputstring,'make')"/>
927 </xsl:call-template>
928 <xsl:call-template name="outputpkgdest">
929 <xsl:with-param
930 name="outputstring"
931 select="substring-after($outputstring,
932 substring-before($outputstring,'make'))"/>
933 </xsl:call-template>
934 </xsl:when>
935 <xsl:otherwise>
936 <xsl:choose>
937<!-- special cases (no DESTDIR) here -->
938 <xsl:when test="ancestor::sect1[@id='ch-system-glibc']">
939 <xsl:text>make install_root=$PKG_DEST -j1</xsl:text>
940 <xsl:value-of
941 select="substring-before(substring-after(string(),'make'),
942 'install')"/>
943 <xsl:text>install&#xA;</xsl:text>
944 </xsl:when>
945 <xsl:when test="ancestor::sect1[@id='ch-system-bzip2']">
946 <xsl:text>make -j1 PREFIX=$PKG_DEST/usr install&#xA;</xsl:text>
947 </xsl:when>
948 <xsl:when test="ancestor::sect1[@id='ch-system-sysklogd']">
949 <xsl:text>make -j1 BINDIR=$PKG_DEST/sbin prefix=$PKG_DEST install&#xA;</xsl:text>
950 </xsl:when>
951 <xsl:when test="ancestor::sect1[@id='ch-system-iproute2'] and
952 contains($outputstring,'DOCDIR')">
953 <xsl:text>make -j1 DESTDIR=$PKG_DEST DOCDIR=</xsl:text>
954 <xsl:value-of
955 select="substring-before(substring-after(string(),'DOCDIR='),
956 'install')"/>
957 <xsl:text>install&#xA;</xsl:text>
958 </xsl:when>
959 <xsl:when test="ancestor::sect1[@id='ch-system-sysvinit']">
960 <xsl:text>make -j1 ROOT=$PKG_DEST</xsl:text>
961 <xsl:value-of
962 select="substring-before(substring-after(string(),'make'),
963 'install')"/>
964 <xsl:text>install&#xA;</xsl:text>
965 </xsl:when>
966 <xsl:when test="ancestor::sect1[@id='ch-bootable-kernel']">
967 <xsl:text>make -j1 INSTALL_MOD_PATH=$PKG_DEST</xsl:text>
968 <xsl:value-of
969 select="substring-before(substring-after(string(),'make'),
970 'install')"/>
971 <xsl:text>install&#xA;</xsl:text>
972 </xsl:when>
973 <xsl:otherwise>
974 <xsl:text>make -j1 DESTDIR=$PKG_DEST</xsl:text>
975 <xsl:call-template name="outputpkgdest">
976 <xsl:with-param
977 name="outputstring"
978 select="substring-after($outputstring,'make')"/>
979 </xsl:call-template>
980 </xsl:otherwise>
981 </xsl:choose>
982 </xsl:otherwise>
983 </xsl:choose>
984 </xsl:when>
985 <xsl:when test="contains($outputstring,'ninja install')">
986 <xsl:choose>
987 <xsl:when test="not(starts-with($outputstring,'ninja install'))">
988 <xsl:call-template name="outputpkgdest">
989 <xsl:with-param name="outputstring"
990 select="substring-before($outputstring,'ninja install')"/>
991 </xsl:call-template>
992 <xsl:call-template name="outputpkgdest">
993 <xsl:with-param
994 name="outputstring"
995 select="substring-after($outputstring,
996 substring-before($outputstring,'ninja install'))"/>
997 </xsl:call-template>
998 </xsl:when>
999 <xsl:otherwise> <!-- "ninja" is the first word and is followed by
1000 "install"-->
1001 <xsl:text>DESTDIR=$PKG_DEST ninja</xsl:text>
1002 <xsl:call-template name="outputpkgdest">
1003 <xsl:with-param
1004 name="outputstring"
1005 select="substring-after($outputstring,'ninja')"/>
1006 </xsl:call-template>
1007 </xsl:otherwise>
1008 </xsl:choose>
1009 </xsl:when>
1010 <xsl:otherwise> <!-- no make nor ninja in this string -->
1011 <xsl:choose>
1012 <xsl:when test="contains($outputstring,'&gt;/') and
1013 not(contains(substring-before($outputstring,'&gt;/'),' /'))">
1014 <xsl:value-of select="substring-before($outputstring,'&gt;/')"/>
1015 <xsl:text>&gt;$PKG_DEST/</xsl:text>
1016 <xsl:call-template name="outputpkgdest">
1017 <xsl:with-param name="outputstring" select="substring-after($outputstring,'&gt;/')"/>
1018 </xsl:call-template>
1019 </xsl:when>
1020 <xsl:when test="contains($outputstring,' /')">
1021 <xsl:value-of select="substring-before($outputstring,' /')"/>
1022 <xsl:text> $PKG_DEST/</xsl:text>
1023 <xsl:call-template name="outputpkgdest">
1024 <xsl:with-param name="outputstring" select="substring-after($outputstring,' /')"/>
1025 </xsl:call-template>
1026 </xsl:when>
1027 <xsl:otherwise>
1028 <xsl:value-of select="$outputstring"/>
1029 </xsl:otherwise>
1030 </xsl:choose>
1031 </xsl:otherwise>
1032 </xsl:choose>
1033 </xsl:template>
1034
1035 <xsl:variable name="APOS">'</xsl:variable>
1036 <xsl:template name="output-wrap">
1037 <xsl:param name="commands" select="''"/>
1038 <xsl:choose>
1039 <xsl:when test="contains($commands,string($APOS))">
1040 <xsl:call-template name="output-wrap">
1041 <xsl:with-param name="commands"
1042 select="substring-before($commands,string($APOS))"/>
1043 </xsl:call-template>
1044 <xsl:text>'\''</xsl:text>
1045 <xsl:call-template name="output-wrap">
1046 <xsl:with-param name="commands"
1047 select="substring-after($commands,string($APOS))"/>
1048 </xsl:call-template>
1049 </xsl:when>
1050 <xsl:otherwise>
1051 <xsl:value-of select="$commands"/>
1052 </xsl:otherwise>
1053 </xsl:choose>
1054 </xsl:template>
1055
1056 <xsl:template name="comment-strip">
1057 <xsl:param name="instructions" select="''"/>
1058 <xsl:choose>
1059 <xsl:when test="contains($instructions,'&#xA;')">
1060 <xsl:call-template name="comment-strip">
1061 <xsl:with-param name="instructions"
1062 select="substring-before($instructions,'&#xA;')"/>
1063 </xsl:call-template>
1064 <xsl:call-template name="comment-strip">
1065 <xsl:with-param name="instructions"
1066 select="substring-after($instructions,'&#xA;')"/>
1067 </xsl:call-template>
1068 </xsl:when>
1069 <xsl:when test="contains($instructions,'\*.la')">
1070 <xsl:if test="$del-la-files='n'">
1071 <xsl:text># </xsl:text>
1072 </xsl:if>
1073 <xsl:value-of select="$instructions"/>
1074 <xsl:text>&#xA;</xsl:text>
1075 </xsl:when>
1076 <xsl:when test="contains($instructions,'strip ')">
1077 <xsl:if test="$strip='n'">
1078 <xsl:text># </xsl:text>
1079 </xsl:if>
1080 <xsl:value-of select="$instructions"/>
1081 <xsl:text> || true&#xA;</xsl:text>
1082 </xsl:when>
1083 <xsl:otherwise>
1084 <xsl:value-of select="$instructions"/>
1085 <xsl:text>&#xA;</xsl:text>
1086 </xsl:otherwise>
1087 </xsl:choose>
1088 </xsl:template>
1089
1090 <xsl:template name="comment-test">
1091 <xsl:param name="instructions" select="''"/>
1092 <xsl:param name="eof-seen" select="false()"/>
1093 <xsl:choose>
1094 <xsl:when test="contains($instructions,'&#xA;')">
1095 <xsl:call-template name="comment-test">
1096 <xsl:with-param name="instructions"
1097 select="substring-before($instructions,'&#xA;')"/>
1098 <xsl:with-param name="eof-seen" select="$eof-seen"/>
1099 </xsl:call-template>
1100 <xsl:choose>
1101 <xsl:when test="contains(substring-before($instructions,'&#xA;'),
1102 'EOF')">
1103 <xsl:call-template name="comment-test">
1104 <xsl:with-param name="instructions"
1105 select="substring-after($instructions,'&#xA;')"/>
1106 <xsl:with-param name="eof-seen" select="not($eof-seen)"/>
1107 </xsl:call-template>
1108 </xsl:when>
1109 <xsl:otherwise>
1110 <xsl:call-template name="comment-test">
1111 <xsl:with-param name="instructions"
1112 select="substring-after($instructions,'&#xA;')"/>
1113 <xsl:with-param name="eof-seen" select="$eof-seen"/>
1114 </xsl:call-template>
1115 </xsl:otherwise>
1116 </xsl:choose>
1117 </xsl:when>
1118 <xsl:otherwise>
1119 <xsl:if test="$testsuite = '0' or
1120 $testsuite = '1' and
1121 not(ancestor::sect1[@id='ch-system-gcc']) and
1122 not(ancestor::sect1[@id='ch-system-glibc']) and
1123 not(ancestor::sect1[@id='ch-system-gmp']) and
1124 not(ancestor::sect1[@id='ch-system-mpfr']) and
1125 not(ancestor::sect1[@id='ch-system-binutils'])">
1126 <xsl:text># </xsl:text>
1127 </xsl:if>
1128 <xsl:choose>
1129 <xsl:when test="contains(string(), 'make -k')">
1130 <xsl:value-of select="$instructions"/>
1131 <xsl:if test="not($eof-seen)">
1132 <xsl:text> &gt;&gt; $TEST_LOG 2&gt;&amp;1 || true</xsl:text>
1133 </xsl:if>
1134 <xsl:text>&#xA;</xsl:text>
1135 </xsl:when>
1136 <xsl:when test="contains($instructions, 'make')">
1137 <xsl:value-of select="substring-before($instructions, 'make')"/>
1138 <xsl:text>make -k</xsl:text>
1139 <xsl:value-of select="substring-after($instructions, 'make')"/>
1140 <xsl:if test="not($eof-seen)">
1141 <xsl:text> &gt;&gt; $TEST_LOG 2&gt;&amp;1 || true</xsl:text>
1142 </xsl:if>
1143 <xsl:text>&#xA;</xsl:text>
1144 </xsl:when>
1145 <xsl:otherwise>
1146 <xsl:value-of select="$instructions"/>
1147 <xsl:if
1148 test="not(contains($instructions, '&gt;&gt;')) and
1149 not(contains($instructions, '&gt; /')) and
1150 not($eof-seen) and
1151 substring($instructions,
1152 string-length($instructions)) != '\'">
1153 <xsl:text> &gt;&gt; $TEST_LOG 2&gt;&amp;1 || true</xsl:text>
1154 </xsl:if>
1155 <xsl:text>&#xA;</xsl:text>
1156 </xsl:otherwise>
1157 </xsl:choose>
1158 </xsl:otherwise>
1159 </xsl:choose>
1160 </xsl:template>
1161
1162 <xsl:template name="basename">
1163 <xsl:param name="path" select="''"/>
1164 <xsl:choose>
1165 <xsl:when test="contains($path,'/') and substring-after($path,'/')!=''">
1166 <xsl:call-template name="basename">
1167 <xsl:with-param name="path" select="substring-after($path,'/')"/>
1168 </xsl:call-template>
1169 </xsl:when>
1170 <xsl:when test="contains($path,'/') and substring-after($path,'/')=''">
1171 <xsl:value-of select="substring-before($path,'/')"/>
1172 </xsl:when>
1173 <xsl:otherwise>
1174 <xsl:value-of select="$path"/>
1175 </xsl:otherwise>
1176 </xsl:choose>
1177 </xsl:template>
1178
1179 <xsl:template name="start-script">
1180 <xsl:param name="order" select="'073'"/>
1181 <xsl:text>
1182<!-- save the timer, so that unpacking, and du is not counted -->
1183PREV_SEC=${SECONDS}
1184 <!-- get the location of the system root -->
1185ROOT=</xsl:text>
1186 <xsl:choose>
1187 <xsl:when test="starts-with(./@id, 'ch-tools') or
1188 contains (./@id, 'kernfs')">
1189 <xsl:text>$LFS/
1190</xsl:text>
1191 </xsl:when>
1192 <xsl:otherwise>
1193 <xsl:text>/
1194</xsl:text>
1195 </xsl:otherwise>
1196 </xsl:choose>
1197 <xsl:text>
1198SCRIPT_ROOT=</xsl:text>
1199 <xsl:copy-of select="$script-root"/>
1200 <xsl:text>
1201</xsl:text>
1202 <xsl:if test="sect2[@role='installation']">
1203 <xsl:text>
1204SRC_DIR=${ROOT}sources
1205<!-- Set variables, for use by the Makefile and package manager -->
1206VERSION=</xsl:text><!-- needed for Makefile, and may be used in PackInstall-->
1207 <xsl:copy-of select=".//sect1info/productnumber/text()"/>
1208 <xsl:text>
1209PKG_DEST=${SRC_DIR}/</xsl:text>
1210 <xsl:copy-of select="$order"/>
1211 <xsl:text>-</xsl:text>
1212 <xsl:copy-of select=".//sect1info/productname/text()"/>
1213 <xsl:text>
1214<!-- Get the tarball name from sect1info -->
1215PACKAGE=</xsl:text>
1216 <xsl:call-template name="basename">
1217 <xsl:with-param name="path" select=".//sect1info/address/text()"/>
1218 </xsl:call-template>
1219 <xsl:if test = "( ../@id = 'chapter-building-system' or
1220 ../@id = 'chapter-config' or
1221 ../@id = 'chapter-bootscripts' or
1222 ../@id = 'chapter-bootable' or
1223 starts-with(@id,'ch-system') ) and $pkgmngt = 'y'">
1224<!-- the last alternative for old books where some sections in
1225 chapter-config had ch-system -->
1226 <xsl:text>
1227source ${ROOT}${SCRIPT_ROOT}/packInstall.sh
1228export -f packInstall</xsl:text>
1229 <xsl:if test="$wrap-install='y'">
1230 <xsl:text>
1231export -f wrapInstall
1232</xsl:text>
1233 </xsl:if>
1234 </xsl:if>
1235<!-- Get the build directory name and clean remnants of previous attempts -->
1236 <xsl:text>
1237cd $SRC_DIR
1238PKGDIR=$(tar -tf $PACKAGE | head -n1 | sed 's@^./@@;s@/.*@@')
1239export PKGDIR VERSION PKG_DEST
1240
1241if [ -d "$PKGDIR" ]; then rm -rf $PKGDIR; fi
1242if [ -d "$PKG_DEST" ]; then rm -rf $PKG_DEST; fi
1243if [ -d "${PKGDIR%-*}-build" ]; then rm -rf ${PKGDIR%-*}-build; fi
1244</xsl:text>
1245 </xsl:if>
1246 <xsl:text>
1247echo "KB: $(du -skx --exclude=lost+found --exclude=var/lib --exclude=$SCRIPT_ROOT $ROOT)"
1248</xsl:text>
1249 <xsl:if test="sect2[@role='installation']">
1250 <xsl:text>
1251<!-- At last unpack and change directory -->
1252tar -xf $PACKAGE
1253cd $PKGDIR
1254</xsl:text>
1255 </xsl:if>
1256 <xsl:text>
1257export MAKEFLAGS="-j</xsl:text>
1258 <xsl:choose>
1259 <xsl:when test="@id='ch-tools-binutils-pass1'">
1260 <xsl:value-of select="$jobs-bp1"/>
1261 </xsl:when>
1262 <xsl:otherwise>
1263 <xsl:value-of select="$jobs"/>
1264 </xsl:otherwise>
1265 </xsl:choose>
1266 <xsl:text>"
1267</xsl:text>
1268 <xsl:text>SECONDS=${PREV_SEC}
1269
1270# Start of LFS book script
1271</xsl:text>
1272 </xsl:template>
1273
1274 <xsl:template name="end-script">
1275 <xsl:text>
1276# End of LFS book script
1277
1278echo "KB: $(du -skx --exclude=lost+found --exclude=var/lib --exclude=$SCRIPT_ROOT $ROOT)"
1279</xsl:text>
1280 <xsl:if test="sect2[@role='installation']">
1281 <xsl:text>cd $SRC_DIR
1282rm -rf $PKGDIR
1283if [ -d "${PKGDIR%-*}-build" ]; then rm -rf ${PKGDIR%-*}-build; fi
1284</xsl:text>
1285 </xsl:if>
1286 </xsl:template>
1287
1288</xsl:stylesheet>
Note: See TracBrowser for help on using the repository browser.