source: LFS/lfs.xsl@ d933ab2

2.3 2.3.x 2.4 ablfs ablfs-more legacy new_features trunk
Last change on this file since d933ab2 was 1330ebc, checked in by Manuel Canales Esparcia <manuel@…>, 18 years ago

Fixed chroot environment to be more closed to the one expected by the books.
Need be full tested.
  • Property mode set to 100644
File size: 11.0 KB
Line 
1<?xml version="1.0"?>
2<!DOCTYPE xsl:stylesheet [
3 <!ENTITY % general-entities SYSTEM "FAKEDIR/general.ent">
4 %general-entities;
5]>
6
7<!-- $Id$ -->
8
9<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
10 xmlns:exsl="http://exslt.org/common"
11 extension-element-prefixes="exsl"
12 version="1.0">
13
14<!-- XSLT stylesheet to create shell scripts from LFS books. -->
15
16 <!-- Run test suites?
17 0 = none
18 1 = only chapter06 Glibc, GCC and Binutils testsuites
19 2 = all chapter06 testsuites
20 3 = all chapter05 and chapter06 testsuites
21 -->
22 <xsl:param name="testsuite" select="1"/>
23
24 <!-- Bomb on test suites failures?
25 n = no, I want to build the full system and review the logs
26 y = yes, bomb at the first test suite failure to can review the build dir
27 -->
28 <xsl:param name="bomb-testsuite" select="n"/>
29
30 <!-- Install vim-lang package? -->
31 <xsl:param name="vim-lang" select="y"/>
32
33 <!-- Time zone -->
34 <xsl:param name="timezone" select="GMT"/>
35
36 <!-- Page size -->
37 <xsl:param name="page" select="letter"/>
38
39 <!-- Locale settings -->
40 <xsl:param name="lang" select="C"/>
41
42 <xsl:template match="/">
43 <xsl:apply-templates select="//sect1"/>
44 </xsl:template>
45
46 <xsl:template match="sect1">
47 <xsl:if test="(../@id='chapter-temporary-tools' or
48 ../@id='chapter-building-system' or
49 ../@id='chapter-bootscripts' or
50 ../@id='chapter-bootable') and
51 count(descendant::screen/userinput) &gt; 0 and
52 count(descendant::screen/userinput) &gt;
53 count(descendant::screen[@role='nodump'])">
54 <!-- The dirs names -->
55 <xsl:variable name="pi-dir" select="../processing-instruction('dbhtml')"/>
56 <xsl:variable name="pi-dir-value" select="substring-after($pi-dir,'dir=')"/>
57 <xsl:variable name="quote-dir" select="substring($pi-dir-value,1,1)"/>
58 <xsl:variable name="dirname" select="substring-before(substring($pi-dir-value,2),$quote-dir)"/>
59 <!-- The file names -->
60 <xsl:variable name="pi-file" select="processing-instruction('dbhtml')"/>
61 <xsl:variable name="pi-file-value" select="substring-after($pi-file,'filename=')"/>
62 <xsl:variable name="filename" select="substring-before(substring($pi-file-value,2),'.html')"/>
63 <!-- The build order -->
64 <xsl:variable name="position" select="position()"/>
65 <xsl:variable name="order">
66 <xsl:choose>
67 <xsl:when test="string-length($position) = 1">
68 <xsl:text>00</xsl:text>
69 <xsl:value-of select="$position"/>
70 </xsl:when>
71 <xsl:when test="string-length($position) = 2">
72 <xsl:text>0</xsl:text>
73 <xsl:value-of select="$position"/>
74 </xsl:when>
75 <xsl:otherwise>
76 <xsl:value-of select="$position"/>
77 </xsl:otherwise>
78 </xsl:choose>
79 </xsl:variable>
80 <!-- Creating dirs and files -->
81 <exsl:document href="{$dirname}/{$order}-{$filename}" method="text">
82 <xsl:choose>
83 <xsl:when test="@id='ch-system-creatingdirs' or
84 @id='ch-system-createfiles'">
85 <xsl:text>#!/tools/bin/bash&#xA;set +h&#xA;</xsl:text>
86 </xsl:when>
87 <xsl:otherwise>
88 <xsl:text>#!/bin/bash&#xA;set +h&#xA;</xsl:text>
89 </xsl:otherwise>
90 </xsl:choose>
91 <xsl:if test="not(@id='ch-tools-stripping') and
92 not(@id='ch-system-strippingagain')">
93 <xsl:text>set -e&#xA;</xsl:text>
94 </xsl:if>
95 <xsl:text>&#xA;</xsl:text>
96 <xsl:if test="sect2[@role='installation']">
97 <xsl:text>cd $PKGDIR&#xA;</xsl:text>
98 <xsl:if test="@id='ch-system-vim' and $vim-lang = 'y'">
99 <xsl:text>tar -xvf ../vim-&vim-version;-lang.* --strip-components=1&#xA;</xsl:text>
100 </xsl:if>
101 </xsl:if>
102 <xsl:apply-templates select=".//para/userinput | .//screen"/>
103 <xsl:if test="$testsuite='3' and @id='ch-tools-glibc'">
104 <xsl:copy-of select="//sect1[@id='ch-system-glibc']/sect2[2]/screen[@role='nodump']"/>
105 <xsl:text>&#xA;</xsl:text>
106 </xsl:if>
107 <xsl:text>exit</xsl:text>
108 </exsl:document>
109 </xsl:if>
110 </xsl:template>
111
112 <xsl:template match="screen">
113 <xsl:if test="child::* = userinput and not(@role = 'nodump')">
114 <xsl:apply-templates select="userinput" mode="screen"/>
115 </xsl:if>
116 </xsl:template>
117
118 <xsl:template match="para/userinput">
119 <xsl:if test="(contains(string(),'test') or
120 contains(string(),'check')) and
121 (($testsuite = '2' and
122 ancestor::chapter[@id='chapter-building-system']) or
123 $testsuite = '3')">
124 <xsl:choose>
125 <xsl:when test="$bomb-testsuite = 'n'">
126 <xsl:value-of select="substring-before(string(),'make')"/>
127 <xsl:text>make -k</xsl:text>
128 <xsl:value-of select="substring-after(string(),'make')"/>
129 <xsl:text> &gt;&gt; $TEST_LOG 2&gt;&amp;1 || true&#xA;</xsl:text>
130 </xsl:when>
131 <xsl:otherwise>
132 <xsl:apply-templates/>
133 <xsl:text> &gt;&gt; $TEST_LOG 2&gt;&amp;1</xsl:text>
134 <xsl:if test="contains(string(),' -k ')">
135 <xsl:text> || true</xsl:text>
136 </xsl:if>
137 <xsl:text>&#xA;</xsl:text>
138 </xsl:otherwise>
139 </xsl:choose>
140 </xsl:if>
141 </xsl:template>
142
143 <xsl:template match="userinput" mode="screen">
144 <xsl:choose>
145 <!-- Estandarized package formats -->
146 <xsl:when test="contains(string(),'tar.gz')">
147 <xsl:value-of select="substring-before(string(),'tar.gz')"/>
148 <xsl:text>tar.*</xsl:text>
149 <xsl:value-of select="substring-after(string(),'tar.gz')"/>
150 <xsl:text>&#xA;</xsl:text>
151 </xsl:when>
152 <!-- Avoiding a race condition in a patch -->
153 <xsl:when test="contains(string(),'debian_fixes')">
154 <xsl:value-of select="substring-before(string(),'patch')"/>
155 <xsl:text>patch -Z</xsl:text>
156 <xsl:value-of select="substring-after(string(),'patch')"/>
157 <xsl:text>&#xA;</xsl:text>
158 </xsl:when>
159 <!-- Fix Udev reinstallation after a build failure -->
160 <xsl:when test="contains(string(),'firmware,udev')">
161 <xsl:text>if [[ ! -d /lib/udev/devices ]] ; then&#xA;</xsl:text>
162 <xsl:apply-templates/>
163 <xsl:text>&#xA;fi&#xA;</xsl:text>
164 </xsl:when>
165 <!-- Setting $LANG for /etc/profile -->
166 <xsl:when test="ancestor::sect1[@id='ch-scripts-profile'] and
167 contains(string(),'export LANG=')">
168 <xsl:value-of select="substring-before(string(),'export LANG=')"/>
169 <xsl:text>export LANG=</xsl:text>
170 <xsl:value-of select="$lang"/>
171 <xsl:value-of select="substring-after(string(),'modifiers>')"/>
172 <xsl:text>&#xA;</xsl:text>
173 </xsl:when>
174 <!-- Copying the kernel config file -->
175 <xsl:when test="string() = 'make mrproper'">
176 <xsl:text>make mrproper&#xA;</xsl:text>
177 <xsl:text>cp -v ../kernel-config .config&#xA;</xsl:text>
178 </xsl:when>
179 <!-- The Coreutils and Module-Init-Tools test suites are optional -->
180 <xsl:when test="(ancestor::sect1[@id='ch-system-coreutils'] or
181 ancestor::sect1[@id='ch-system-module-init-tools']) and
182 (contains(string(),'check') or
183 contains(string(),'dummy'))">
184 <xsl:choose>
185 <xsl:when test="$testsuite = '0' or $testsuite = '1'"/>
186 <xsl:otherwise>
187 <xsl:if test="not(contains(string(),'check'))">
188 <xsl:apply-templates/>
189 <xsl:text>&#xA;</xsl:text>
190 </xsl:if>
191 <xsl:if test="contains(string(),'check')">
192 <xsl:choose>
193 <xsl:when test="$bomb-testsuite = 'n'">
194 <xsl:value-of select="substring-before(string(),'check')"/>
195 <xsl:text>-k check</xsl:text>
196 <xsl:value-of select="substring-after(string(),'check')"/>
197 <xsl:text> &gt;&gt; $TEST_LOG 2&gt;&amp;1 || true&#xA;</xsl:text>
198 </xsl:when>
199 <xsl:otherwise>
200 <xsl:apply-templates/>
201 <xsl:text> &gt;&gt; $TEST_LOG 2&gt;&amp;1</xsl:text>
202 <xsl:if test="contains(string(),' -k ')">
203 <xsl:text> || true</xsl:text>
204 </xsl:if>
205 <xsl:text>&#xA;</xsl:text>
206 </xsl:otherwise>
207 </xsl:choose>
208 </xsl:if>
209 </xsl:otherwise>
210 </xsl:choose>
211 </xsl:when>
212 <!-- Fixing toolchain test suites run -->
213 <xsl:when test="string() = 'make check' or
214 string() = 'make -k check'">
215 <xsl:choose>
216 <xsl:when test="(($testsuite = '1' or $testsuite = '2') and
217 ancestor::chapter[@id='chapter-building-system']) or
218 $testsuite = '3'">
219 <xsl:choose>
220 <xsl:when test="$bomb-testsuite = 'n'">
221 <xsl:text>make -k check &gt;&gt; $TEST_LOG 2&gt;&amp;1 || true&#xA;</xsl:text>
222 </xsl:when>
223 <xsl:otherwise>
224 <xsl:apply-templates/>
225 <xsl:text> &gt;&gt; $TEST_LOG 2&gt;&amp;1</xsl:text>
226 <xsl:if test="contains(string(),' -k ')">
227 <xsl:text> || true</xsl:text>
228 </xsl:if>
229 <xsl:text>&#xA;</xsl:text>
230 </xsl:otherwise>
231 </xsl:choose>
232 </xsl:when>
233 </xsl:choose>
234 </xsl:when>
235 <xsl:when test="contains(string(),'glibc-check-log')">
236 <xsl:choose>
237 <xsl:when test="$testsuite != '0'">
238 <xsl:value-of select="substring-before(string(),'2&gt;&amp;1')"/>
239 <xsl:text>&gt;&gt; $TEST_LOG 2&gt;&amp;1 || true&#xA;</xsl:text>
240 </xsl:when>
241 </xsl:choose>
242 </xsl:when>
243 <xsl:when test="contains(string(),'test_summary') or
244 contains(string(),'expect -c')">
245 <xsl:choose>
246 <xsl:when test="(($testsuite = '1' or $testsuite = '2') and
247 ancestor::chapter[@id='chapter-building-system']) or
248 $testsuite = '3'">
249 <xsl:apply-templates/>
250 <xsl:text> &gt;&gt; $TEST_LOG&#xA;</xsl:text>
251 </xsl:when>
252 </xsl:choose>
253 </xsl:when>
254 <!-- Don't stop on strip run -->
255 <xsl:when test="contains(string(),'strip ')">
256 <xsl:apply-templates/>
257 <xsl:text> || true&#xA;</xsl:text>
258 </xsl:when>
259 <!-- The rest of commands -->
260 <xsl:otherwise>
261 <xsl:apply-templates/>
262 <xsl:text>&#xA;</xsl:text>
263 </xsl:otherwise>
264 </xsl:choose>
265 </xsl:template>
266
267 <xsl:template match="replaceable">
268 <xsl:choose>
269 <xsl:when test="ancestor::sect1[@id='ch-system-glibc']">
270 <xsl:value-of select="$timezone"/>
271 </xsl:when>
272 <xsl:when test="ancestor::sect1[@id='ch-system-groff']">
273 <xsl:value-of select="$page"/>
274 </xsl:when>
275 <xsl:otherwise>
276 <xsl:text>**EDITME</xsl:text>
277 <xsl:apply-templates/>
278 <xsl:text>EDITME**</xsl:text>
279 </xsl:otherwise>
280 </xsl:choose>
281 </xsl:template>
282
283</xsl:stylesheet>
Note: See TracBrowser for help on using the repository browser.