source: LFS/lfs.xsl@ 06bb141

2.4 ablfs-more legacy new_features trunk
Last change on this file since 06bb141 was e40a68e, checked in by Pierre Labastie <pierre@…>, 12 years ago

Fix the procps-ng check instructions so that the result is logged into
$TEST_LOG
  • Property mode set to 100644
File size: 22.2 KB
Line 
1<?xml version="1.0" encoding="ISO-8859-1"?>
2
3<!-- $Id$ -->
4
5<xsl:stylesheet
6 xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
7 xmlns:exsl="http://exslt.org/common"
8 extension-element-prefixes="exsl"
9 version="1.0">
10
11 <!-- use package management ?
12 n = no, original behavior
13 y = yes, add PKG_DEST to scripts in install commands of chapter06-08
14 -->
15 <xsl:param name="pkgmngt" select="n"/>
16
17 <!-- Run test suites?
18 0 = none
19 1 = only chapter06 Glibc, GCC and Binutils testsuites
20 2 = all chapter06 testsuites
21 3 = all chapter05 and chapter06 testsuites
22 -->
23 <xsl:param name="testsuite" select="1"/>
24
25 <!-- Bomb on test suites failures?
26 n = no, I want to build the full system and review the logs
27 y = yes, bomb at the first test suite failure to can review the build dir
28 -->
29 <xsl:param name="bomb-testsuite" select="n"/>
30
31 <!-- Install vim-lang package? OBSOLETE should always be 'n'-->
32 <xsl:param name="vim-lang" select="n"/>
33
34 <!-- Time zone -->
35 <xsl:param name="timezone" select="GMT"/>
36
37 <!-- Page size -->
38 <xsl:param name="page" select="letter"/>
39
40 <!-- Locale settings -->
41 <xsl:param name="lang" select="C"/>
42
43 <!-- Install the whole set of locales -->
44 <xsl:param name='full-locale' select='n'/>
45
46 <xsl:template match="/">
47 <xsl:apply-templates select="//sect1"/>
48 </xsl:template>
49
50 <xsl:template match="sect1">
51 <xsl:if test="(../@id='chapter-temporary-tools' or
52 ../@id='chapter-building-system' or
53 ../@id='chapter-bootscripts' or
54 ../@id='chapter-bootable') and
55 count(descendant::screen/userinput) &gt; 0 and
56 count(descendant::screen/userinput) &gt;
57 count(descendant::screen[@role='nodump'])">
58 <!-- The dirs names -->
59 <xsl:variable name="pi-dir" select="../processing-instruction('dbhtml')"/>
60 <xsl:variable name="pi-dir-value" select="substring-after($pi-dir,'dir=')"/>
61 <xsl:variable name="quote-dir" select="substring($pi-dir-value,1,1)"/>
62 <xsl:variable name="dirname" select="substring-before(substring($pi-dir-value,2),$quote-dir)"/>
63 <!-- The file names -->
64 <xsl:variable name="pi-file" select="processing-instruction('dbhtml')"/>
65 <xsl:variable name="pi-file-value" select="substring-after($pi-file,'filename=')"/>
66 <xsl:variable name="filename" select="substring-before(substring($pi-file-value,2),'.html')"/>
67 <!-- The build order -->
68 <xsl:variable name="position" select="position()"/>
69 <xsl:variable name="order">
70 <xsl:choose>
71 <xsl:when test="string-length($position) = 1">
72 <xsl:text>00</xsl:text>
73 <xsl:value-of select="$position"/>
74 </xsl:when>
75 <xsl:when test="string-length($position) = 2">
76 <xsl:text>0</xsl:text>
77 <xsl:value-of select="$position"/>
78 </xsl:when>
79 <xsl:otherwise>
80 <xsl:value-of select="$position"/>
81 </xsl:otherwise>
82 </xsl:choose>
83 </xsl:variable>
84 <!-- Inclusion of package manager scriptlets -->
85 <xsl:if test="@id='ch-tools-stripping' and $pkgmngt='y'">
86 <xsl:apply-templates
87 select="document('packageManager.xml')//sect1[contains(@id,'ch-tools')]"
88 mode="pkgmngt">
89 <xsl:with-param name="order" select="$order"/>
90 <xsl:with-param name="dirname" select="$dirname"/>
91 </xsl:apply-templates>
92 </xsl:if>
93 <xsl:if test="@id='ch-system-strippingagain' and $pkgmngt='y'">
94 <xsl:apply-templates
95 select="document('packageManager.xml')//sect1[contains(@id,'ch-system')]"
96 mode="pkgmngt">
97 <xsl:with-param name="order" select="$order"/>
98 <xsl:with-param name="dirname" select="$dirname"/>
99 </xsl:apply-templates>
100 </xsl:if>
101 <!-- Creating dirs and files -->
102 <exsl:document href="{$dirname}/{$order}-{$filename}" method="text">
103 <xsl:choose>
104 <xsl:when test="@id='ch-system-creatingdirs' or
105 @id='ch-system-createfiles' or
106 @id='ch-system-strippingagain'">
107 <xsl:text>#!/tools/bin/bash&#xA;set +h&#xA;</xsl:text>
108 </xsl:when>
109 <xsl:otherwise>
110 <xsl:text>#!/bin/bash&#xA;set +h&#xA;</xsl:text>
111 </xsl:otherwise>
112 </xsl:choose>
113 <xsl:if test="not(@id='ch-tools-stripping') and
114 not(@id='ch-system-strippingagain')">
115 <xsl:text>set -e&#xA;</xsl:text>
116 </xsl:if>
117 <xsl:text>&#xA;</xsl:text>
118 <xsl:if test="sect2[@role='installation']">
119 <xsl:text>cd $PKGDIR&#xA;</xsl:text>
120 </xsl:if>
121 <xsl:apply-templates
122 select=".//screen[not(@role) or
123 @role != 'nodump']/userinput[
124 @remap = 'pre' or
125 @remap = 'configure' or
126 @remap = 'make' or
127 @remap = 'test' and
128 not(current()/@id='ch-tools-dejagnu')]"/>
129 <xsl:if
130 test="ancestor::chapter[@id != 'chapter-temporary-tools'] and
131 $pkgmngt = 'y' and
132 descendant::screen[not(@role) or
133 @role != 'nodump']/userinput[
134 @remap='install']">
135 <xsl:text>mkdir -pv $PKG_DEST/{boot,etc,lib,bin,sbin}
136mkdir -pv $PKG_DEST/usr/{lib,bin,sbin,include}
137mkdir -pv $PKG_DEST/usr/share/{doc,info,man}
138mkdir -pv $PKG_DEST/usr/share/man/man{1..8}
139ln -sv share/{man,doc,info} $PKG_DEST/usr
140case $(uname -m) in
141 x86_64) ln -sv lib $PKG_DEST/lib64 &amp;&amp; ln -sv lib $PKG_DEST/usr/lib64 ;;
142esac
143</xsl:text>
144 </xsl:if>
145 <xsl:if test="@id = 'ch-system-glibc' and
146 $pkgmngt = 'y'">
147 <xsl:text>mkdir -pv $PKG_DEST/usr/include/{rpc,rpcsvc}
148</xsl:text>
149 </xsl:if>
150 <xsl:apply-templates
151 select=".//screen[not(@role) or
152 @role != 'nodump']/userinput[@remap = 'install']"/>
153 <xsl:if test="ancestor::chapter[@id != 'chapter-temporary-tools'] and
154 $pkgmngt = 'y' and
155 descendant::screen[not(@role) or
156 @role != 'nodump']/userinput[
157 @remap='install']">
158 <xsl:if test="@id = 'ch-system-man-pages'">
159<!-- those files are provided by the shadow package -->
160 <xsl:text>rm -fv $PKG_DEST/usr/share/man/{man3/getspnam.3,man5/passwd.5}
161</xsl:text>
162 </xsl:if>
163 <xsl:text>rm -fv $PKG_DEST/{,usr/}lib64
164rm -fv $PKG_DEST/usr/{man,doc,info}
165for dir in $PKG_DEST/usr/share/man/man{1..8}; do
166 [[ -z $(ls $dir) ]] &amp;&amp; rmdir -v $dir
167done
168for dir in $PKG_DEST/usr/share/{doc,info,man}; do
169 [[ -z $(ls $dir) ]] &amp;&amp; rmdir -v $dir
170done
171for dir in $PKG_DEST/usr/{lib,bin,sbin,include}; do
172 [[ -z $(ls $dir) ]] &amp;&amp; rmdir -v $dir
173done
174for dir in $PKG_DEST/{boot,etc,lib,bin,sbin}; do
175 [[ -z $(ls $dir) ]] &amp;&amp; rmdir -v $dir
176done
177packInstall
178rm -rf $PKG_DEST
179</xsl:text>
180 </xsl:if>
181 <xsl:if test="$testsuite='3' and @id='ch-tools-glibc'">
182 <xsl:copy-of select="//userinput[@remap='locale-test']"/>
183 <xsl:text>&#xA;</xsl:text>
184 </xsl:if>
185 <xsl:if test="@id='ch-system-glibc'">
186 <xsl:choose>
187 <xsl:when test="$full-locale='y'">
188 <xsl:copy-of select="//userinput[@remap='locale-full']"/>
189 <xsl:text>&#xA;</xsl:text>
190 </xsl:when>
191 <xsl:otherwise>
192 <xsl:copy-of select="//userinput[@remap='locale-test']"/>
193 <xsl:text>&#xA;</xsl:text>
194 <xsl:if test="not(contains(string(//userinput[@remap='locale-test']),$lang)) and $lang!='C' and $lang!='POSIX'">
195 <xsl:text>if LOCALE=`grep "</xsl:text>
196 <xsl:value-of select="$lang"/>
197 <xsl:text>/" $PKGDIR/localedata/SUPPORTED`; then
198 CHARMAP=`echo $LOCALE | sed 's,[^/]*/\([^ ]*\) [\],\1,'`
199 INPUT=`echo $LOCALE | sed 's,[/.].*,,'`
200 LOCALE=`echo $LOCALE | sed 's,/.*,,'`
201 localedef -i $INPUT -f $CHARMAP $LOCALE
202fi
203</xsl:text>
204 </xsl:if>
205 </xsl:otherwise>
206 </xsl:choose>
207 </xsl:if>
208 <xsl:apply-templates
209 select=".//screen[
210 not(@role) or
211 @role != 'nodump'
212 ]/userinput[
213 not(@remap) or
214 @remap='adjust' or
215 @remap='test' and current()/@id='ch-tools-dejagnu'
216 ]"/>
217 <xsl:if test="@id='ch-system-creatingdirs'">
218 <xsl:apply-templates
219 select="document('packageManager.xml')//sect1[
220 @id='ch-pkgmngt-creatingdirs'
221 ]//userinput"/>
222 </xsl:if>
223 <xsl:if test="@id='ch-system-createfiles'">
224 <xsl:apply-templates
225 select="document('packageManager.xml')//sect1[
226 @id='ch-pkgmngt-createfiles'
227 ]//userinput"/>
228 </xsl:if>
229 <xsl:if test="not(@id='ch-system-chroot') and
230 not(@id='ch-system-revisedchroot')">
231 <xsl:text>echo -e "\n\nTotalseconds: $SECONDS\n"&#xA;</xsl:text>
232 </xsl:if>
233 <xsl:text>exit&#xA;</xsl:text>
234 </exsl:document>
235 </xsl:if>
236 </xsl:template>
237
238<xsl:template match="sect1" mode="pkgmngt">
239 <xsl:param name="dirname" select="chapter05"/>
240 <!-- The build order -->
241 <xsl:param name="order" select="062"/>
242<!-- The file names -->
243 <xsl:variable name="pi-file" select="processing-instruction('dbhtml')"/>
244 <xsl:variable name="pi-file-value" select="substring-after($pi-file,'filename=')"/>
245 <xsl:variable name="filename" select="substring-before(substring($pi-file-value,2),'.html')"/>
246 <!-- Creating dirs and files -->
247 <exsl:document href="{$dirname}/{$order}-{position()}-{$filename}" method="text">
248 <xsl:text>#!/bin/bash
249set +h
250set -e
251
252cd $PKGDIR
253</xsl:text>
254 <xsl:apply-templates
255 select=".//screen[not(@role) or @role != 'nodump']/userinput[@remap != 'adjust']"
256 mode="pkgmngt"/>
257 <xsl:if test="$dirname = 'chapter06'">
258 <xsl:text>packInstall
259rm -rf $PKG_DEST
260</xsl:text>
261 </xsl:if>
262 <xsl:apply-templates
263 select=".//screen[
264 not(@role) or
265 @role != 'nodump'
266 ]/userinput[
267 not(@remap) or
268 @remap='adjust'
269 ]"
270 mode="pkgmngt"/>
271 <xsl:text>
272echo -e "\n\nTotalseconds: $SECONDS\n"
273exit
274</xsl:text>
275 </exsl:document>
276 </xsl:template>
277
278 <xsl:template match="userinput" mode="pkgmngt">
279 <xsl:apply-templates/>
280 <xsl:text>&#xA;</xsl:text>
281 </xsl:template>
282
283 <xsl:template match="userinput">
284 <xsl:choose>
285 <!-- Copying the kernel config file -->
286 <xsl:when test="string() = 'make mrproper'">
287 <xsl:text>make mrproper&#xA;</xsl:text>
288 <xsl:if test="ancestor::sect1[@id='ch-bootable-kernel']">
289 <xsl:text>cp -v ../kernel-config .config&#xA;</xsl:text>
290 </xsl:if>
291 </xsl:when>
292<!-- test instructions -->
293 <xsl:when test="@remap = 'test'">
294 <xsl:choose>
295 <xsl:when test="$testsuite = '0'"/>
296 <xsl:when test="$testsuite = '1' and
297 not(ancestor::sect1[@id='ch-system-gcc']) and
298 not(ancestor::sect1[@id='ch-system-glibc']) and
299 not(ancestor::sect1[@id='ch-system-gmp']) and
300 not(ancestor::sect1[@id='ch-system-mpfr']) and
301 not(ancestor::sect1[@id='ch-system-binutils'])"/>
302 <xsl:when test="$testsuite = '2' and
303 ancestor::chapter[@id='chapter-temporary-tools']"/>
304 <xsl:otherwise>
305 <xsl:choose>
306 <xsl:when test="$bomb-testsuite = 'n'">
307 <xsl:choose>
308 <!-- special case for glibc -->
309 <xsl:when test="contains(string(), 'glibc-check-log')">
310 <xsl:value-of
311 select="substring-before(string(),'2&gt;&amp;1')"/>
312 <xsl:text>&gt;&gt; $TEST_LOG 2&gt;&amp;1 || true&#xA;</xsl:text>
313 </xsl:when>
314 <!-- special case for procps-ng -->
315 <xsl:when test="contains(string(), 'pushd')">
316 <xsl:text>{ </xsl:text>
317 <xsl:apply-templates/>
318 <xsl:text>; } &gt;&gt; $TEST_LOG 2&gt;&amp;1 || true&#xA;</xsl:text>
319 </xsl:when>
320 <xsl:when test="contains(string(), 'make -k')">
321 <xsl:apply-templates/>
322 <xsl:text> &gt;&gt; $TEST_LOG 2&gt;&amp;1 || true&#xA;</xsl:text>
323 </xsl:when>
324 <xsl:when test="contains(string(), 'make')">
325 <xsl:value-of select="substring-before(string(),'make')"/>
326 <xsl:text>make -k</xsl:text>
327 <xsl:value-of select="substring-after(string(),'make')"/>
328 <xsl:text> &gt;&gt; $TEST_LOG 2&gt;&amp;1 || true&#xA;</xsl:text>
329 </xsl:when>
330 <xsl:otherwise>
331 <xsl:apply-templates/>
332 <xsl:if test="not(contains(string(), '&gt;&gt;'))">
333 <xsl:text> &gt;&gt; $TEST_LOG 2&gt;&amp;1</xsl:text>
334 </xsl:if>
335 <xsl:text>&#xA;</xsl:text>
336 </xsl:otherwise>
337 </xsl:choose>
338 </xsl:when>
339 <xsl:otherwise>
340 <!-- bomb-testsuite != 'n'-->
341 <xsl:choose>
342 <!-- special case for glibc -->
343 <xsl:when test="contains(string(), 'glibc-check-log')">
344 <xsl:value-of
345 select="substring-before(string(),'2&gt;&amp;1')"/>
346 <xsl:text>&gt;&gt; $TEST_LOG 2&gt;&amp;1 || true&#xA;</xsl:text>
347 </xsl:when>
348 <!-- special case for gmp -->
349 <xsl:when test="contains(string(), 'tee gmp-check-log')">
350 <xsl:text>(</xsl:text>
351 <xsl:apply-templates/>
352 <xsl:text>&gt;&gt; $TEST_LOG 2&gt;&amp;1 &amp;&amp; exit $PIPESTATUS)&#xA;</xsl:text>
353 </xsl:when>
354 <!-- special case for procps-ng -->
355 <xsl:when test="contains(string(), 'pushd')">
356 <xsl:text>{ </xsl:text>
357 <xsl:apply-templates/>
358 <xsl:text>; } &gt;&gt; $TEST_LOG 2&gt;&amp;1&#xA;</xsl:text>
359 </xsl:when>
360 <xsl:when test="contains(string(), 'make -k')">
361 <xsl:apply-templates/>
362 <xsl:text> &gt;&gt; $TEST_LOG 2&gt;&amp;1 || true&#xA;</xsl:text>
363 </xsl:when>
364 <xsl:otherwise>
365 <xsl:apply-templates/>
366 <xsl:if test="not(contains(string(), '&gt;&gt;'))">
367 <xsl:text> &gt;&gt; $TEST_LOG 2&gt;&amp;1</xsl:text>
368 </xsl:if>
369 <xsl:text>&#xA;</xsl:text>
370 </xsl:otherwise>
371 </xsl:choose>
372 </xsl:otherwise>
373 </xsl:choose>
374 </xsl:otherwise>
375 </xsl:choose>
376 </xsl:when>
377<!-- End of test instructions -->
378 <!-- Don't stop on strip run -->
379 <xsl:when test="contains(string(),'strip ')">
380 <xsl:apply-templates/>
381 <xsl:text> || true&#xA;</xsl:text>
382 </xsl:when>
383<!-- Package management -->
384<!-- Add $PKG_DEST to installation commands -->
385 <xsl:when test="@remap='install' and
386 not(ancestor::chapter[
387 @id='chapter-temporary-tools'
388 ])">
389 <xsl:choose>
390 <xsl:when test="$pkgmngt='n'">
391 <xsl:choose>
392 <xsl:when test="contains(string(),'firmware,udev')">
393 <xsl:text>if [[ ! -d /lib/udev/devices ]] ; then&#xA;</xsl:text>
394 <xsl:apply-templates/>
395 <xsl:text>&#xA;fi&#xA;</xsl:text>
396 </xsl:when>
397 <xsl:otherwise>
398 <xsl:apply-templates/>
399 <xsl:text>&#xA;</xsl:text>
400 </xsl:otherwise>
401 </xsl:choose>
402 </xsl:when>
403 <xsl:otherwise><!--pkgmngt = 'y'-->
404 <xsl:choose>
405 <xsl:when test="./literal">
406 <xsl:call-template name="outputpkgdest">
407 <xsl:with-param name="outputstring"
408 select="text()[1]"/>
409 </xsl:call-template>
410 <xsl:apply-templates select="literal"/>
411 <xsl:call-template name="outputpkgdest">
412 <xsl:with-param name="outputstring"
413 select="text()[2]"/>
414 </xsl:call-template>
415 </xsl:when>
416 <xsl:otherwise>
417 <xsl:call-template name="outputpkgdest">
418 <xsl:with-param name="outputstring" select="string()"/>
419 </xsl:call-template>
420 </xsl:otherwise>
421 </xsl:choose>
422 </xsl:otherwise>
423 </xsl:choose>
424 </xsl:when>
425 <!-- End addition for package management -->
426 <!-- The rest of commands -->
427 <xsl:otherwise>
428 <xsl:apply-templates/>
429 <xsl:text>&#xA;</xsl:text>
430 </xsl:otherwise>
431 </xsl:choose>
432 </xsl:template>
433
434 <xsl:template match="replaceable">
435 <xsl:choose>
436 <xsl:when test="ancestor::sect1[@id='ch-system-glibc']">
437 <xsl:value-of select="$timezone"/>
438 </xsl:when>
439 <xsl:when test="ancestor::sect1[@id='ch-system-groff']">
440 <xsl:value-of select="$page"/>
441 </xsl:when>
442 <xsl:when test="contains(string(.),'&lt;ll&gt;_&lt;CC&gt;')">
443 <xsl:value-of select="$lang"/>
444 </xsl:when>
445 <xsl:otherwise>
446 <xsl:text>**EDITME</xsl:text>
447 <xsl:apply-templates/>
448 <xsl:text>EDITME**</xsl:text>
449 </xsl:otherwise>
450 </xsl:choose>
451 </xsl:template>
452
453 <xsl:template name="outputpkgdest">
454 <xsl:param name="outputstring" select="foo"/>
455 <xsl:choose>
456 <xsl:when test="contains($outputstring,'make ')">
457 <xsl:choose>
458 <xsl:when test="not(starts-with($outputstring,'make'))">
459 <xsl:call-template name="outputpkgdest">
460 <xsl:with-param name="outputstring"
461 select="substring-before($outputstring,'make')"/>
462 </xsl:call-template>
463 <xsl:call-template name="outputpkgdest">
464 <xsl:with-param
465 name="outputstring"
466 select="substring-after($outputstring,
467 substring-before($outputstring,'make'))"/>
468 </xsl:call-template>
469 </xsl:when>
470 <xsl:otherwise>
471 <xsl:choose>
472<!-- special cases (no DESTDIR) here -->
473 <xsl:when test="ancestor::sect1[@id='ch-system-glibc']">
474 <xsl:text>make install_root=$PKG_DEST -j1</xsl:text>
475 <xsl:value-of
476 select="substring-before(substring-after(string(),'make'),
477 'install')"/>
478 <xsl:text>install&#xA;</xsl:text>
479 </xsl:when>
480 <xsl:when test="ancestor::sect1[@id='ch-system-bzip2']">
481 <xsl:text>make PREFIX=$PKG_DEST/usr install&#xA;</xsl:text>
482 </xsl:when>
483 <xsl:when test="ancestor::sect1[@id='ch-system-sysklogd']">
484 <xsl:text>make BINDIR=$PKG_DEST/sbin prefix=$PKG_DEST install&#xA;</xsl:text>
485 </xsl:when>
486 <xsl:when test="ancestor::sect1[@id='ch-system-iproute2']">
487 <xsl:text>make DESTDIR=$PKG_DEST</xsl:text>
488 <xsl:value-of
489 select="substring-before(substring-after(string(),'DESTDIR='),
490 'install')"/>
491 <xsl:text>install&#xA;</xsl:text>
492 </xsl:when>
493 <xsl:when test="ancestor::sect1[@id='ch-system-sysvinit']">
494 <xsl:text>make ROOT=$PKG_DEST</xsl:text>
495 <xsl:value-of
496 select="substring-before(substring-after(string(),'make'),
497 'install')"/>
498 <xsl:text>install&#xA;</xsl:text>
499 </xsl:when>
500 <xsl:when test="ancestor::sect1[@id='ch-bootable-kernel']">
501 <xsl:text>make INSTALL_MOD_PATH=$PKG_DEST</xsl:text>
502 <xsl:value-of
503 select="substring-before(substring-after(string(),'make'),
504 'install')"/>
505 <xsl:text>install&#xA;</xsl:text>
506 </xsl:when>
507 <xsl:otherwise>
508 <xsl:text>make DESTDIR=$PKG_DEST</xsl:text>
509 <xsl:call-template name="outputpkgdest">
510 <xsl:with-param
511 name="outputstring"
512 select="substring-after($outputstring,'make')"/>
513 </xsl:call-template>
514 </xsl:otherwise>
515 </xsl:choose>
516 </xsl:otherwise>
517 </xsl:choose>
518 </xsl:when>
519 <xsl:otherwise> <!-- no make in this string -->
520 <xsl:choose>
521 <xsl:when test="contains($outputstring,'&gt;/') and
522 not(contains(substring-before($outputstring,'&gt;/'),' /'))">
523 <xsl:value-of select="substring-before($outputstring,'&gt;/')"/>
524 <xsl:text>&gt;$PKG_DEST/</xsl:text>
525 <xsl:call-template name="outputpkgdest">
526 <xsl:with-param name="outputstring" select="substring-after($outputstring,'&gt;/')"/>
527 </xsl:call-template>
528 </xsl:when>
529 <xsl:when test="contains($outputstring,' /')">
530 <xsl:value-of select="substring-before($outputstring,' /')"/>
531 <xsl:text> $PKG_DEST/</xsl:text>
532 <xsl:call-template name="outputpkgdest">
533 <xsl:with-param name="outputstring" select="substring-after($outputstring,' /')"/>
534 </xsl:call-template>
535 </xsl:when>
536 <xsl:otherwise>
537 <xsl:value-of select="$outputstring"/>
538 <xsl:text>&#xA;</xsl:text>
539 </xsl:otherwise>
540 </xsl:choose>
541 </xsl:otherwise>
542 </xsl:choose>
543 </xsl:template>
544</xsl:stylesheet>
Note: See TracBrowser for help on using the repository browser.