source: LFS/lfs.xsl@ 0700131

2.4 ablfs-more legacy new_features trunk
Last change on this file since 0700131 was 560bef1, checked in by Pierre Labastie <pierre@…>, 11 years ago

Fix package management instructions for attr.
Add attr to blacklist in opt_config.
  • Property mode set to 100644
File size: 23.4 KB
Line 
1<?xml version="1.0" encoding="ISO-8859-1"?>
2
3<!-- $Id$ -->
4
5<xsl:stylesheet
6 xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
7 xmlns:exsl="http://exslt.org/common"
8 extension-element-prefixes="exsl"
9 version="1.0">
10
11 <!-- use package management ?
12 n = no, original behavior
13 y = yes, add PKG_DEST to scripts in install commands of chapter06-08
14 -->
15 <xsl:param name="pkgmngt" select="n"/>
16
17 <!-- Run test suites?
18 0 = none
19 1 = only chapter06 Glibc, GCC and Binutils testsuites
20 2 = all chapter06 testsuites
21 3 = all chapter05 and chapter06 testsuites
22 -->
23 <xsl:param name="testsuite" select="1"/>
24
25 <!-- Bomb on test suites failures?
26 n = no, I want to build the full system and review the logs
27 y = yes, bomb at the first test suite failure to can review the build dir
28 -->
29 <xsl:param name="bomb-testsuite" select="n"/>
30
31 <!-- Install vim-lang package? OBSOLETE should always be 'n'-->
32 <xsl:param name="vim-lang" select="n"/>
33
34 <!-- Time zone -->
35 <xsl:param name="timezone" select="GMT"/>
36
37 <!-- Page size -->
38 <xsl:param name="page" select="letter"/>
39
40 <!-- Locale settings -->
41 <xsl:param name="lang" select="C"/>
42
43 <!-- Install the whole set of locales -->
44 <xsl:param name='full-locale' select='n'/>
45
46 <xsl:template match="/">
47 <xsl:apply-templates select="//sect1"/>
48 </xsl:template>
49
50 <xsl:template match="sect1">
51 <xsl:if test="(../@id='chapter-temporary-tools' or
52 ../@id='chapter-building-system' or
53 ../@id='chapter-bootscripts' or
54 ../@id='chapter-bootable') and
55 count(descendant::screen/userinput) &gt; 0 and
56 count(descendant::screen/userinput) &gt;
57 count(descendant::screen[@role='nodump'])">
58 <!-- The dirs names -->
59 <xsl:variable name="pi-dir" select="../processing-instruction('dbhtml')"/>
60 <xsl:variable name="pi-dir-value" select="substring-after($pi-dir,'dir=')"/>
61 <xsl:variable name="quote-dir" select="substring($pi-dir-value,1,1)"/>
62 <xsl:variable name="dirname" select="substring-before(substring($pi-dir-value,2),$quote-dir)"/>
63 <!-- The file names -->
64 <xsl:variable name="pi-file" select="processing-instruction('dbhtml')"/>
65 <xsl:variable name="pi-file-value" select="substring-after($pi-file,'filename=')"/>
66 <xsl:variable name="filename" select="substring-before(substring($pi-file-value,2),'.html')"/>
67 <!-- The build order -->
68 <xsl:variable name="position" select="position()"/>
69 <xsl:variable name="order">
70 <xsl:choose>
71 <xsl:when test="string-length($position) = 1">
72 <xsl:text>00</xsl:text>
73 <xsl:value-of select="$position"/>
74 </xsl:when>
75 <xsl:when test="string-length($position) = 2">
76 <xsl:text>0</xsl:text>
77 <xsl:value-of select="$position"/>
78 </xsl:when>
79 <xsl:otherwise>
80 <xsl:value-of select="$position"/>
81 </xsl:otherwise>
82 </xsl:choose>
83 </xsl:variable>
84 <!-- Inclusion of package manager scriptlets -->
85 <xsl:if test="@id='ch-tools-stripping' and $pkgmngt='y'">
86 <xsl:apply-templates
87 select="document('packageManager.xml')//sect1[contains(@id,'ch-tools')]"
88 mode="pkgmngt">
89 <xsl:with-param name="order" select="$order"/>
90 <xsl:with-param name="dirname" select="$dirname"/>
91 </xsl:apply-templates>
92 </xsl:if>
93 <xsl:if test="@id='ch-system-strippingagain' and $pkgmngt='y'">
94 <xsl:apply-templates
95 select="document('packageManager.xml')//sect1[contains(@id,'ch-system')]"
96 mode="pkgmngt">
97 <xsl:with-param name="order" select="$order"/>
98 <xsl:with-param name="dirname" select="$dirname"/>
99 </xsl:apply-templates>
100 </xsl:if>
101 <!-- Creating dirs and files -->
102 <exsl:document href="{$dirname}/{$order}-{$filename}" method="text">
103 <xsl:choose>
104 <xsl:when test="@id='ch-system-creatingdirs' or
105 @id='ch-system-createfiles' or
106 @id='ch-system-strippingagain'">
107 <xsl:text>#!/tools/bin/bash&#xA;set +h&#xA;</xsl:text>
108 </xsl:when>
109 <xsl:otherwise>
110 <xsl:text>#!/bin/bash&#xA;set +h&#xA;</xsl:text>
111 </xsl:otherwise>
112 </xsl:choose>
113 <xsl:if test="not(@id='ch-tools-stripping') and
114 not(@id='ch-system-strippingagain')">
115 <xsl:text>set -e&#xA;</xsl:text>
116 </xsl:if>
117 <xsl:text>&#xA;</xsl:text>
118 <xsl:if test="sect2[@role='installation']">
119 <xsl:text>cd $PKGDIR&#xA;</xsl:text>
120 </xsl:if>
121 <xsl:apply-templates select="sect2|
122 screen[not(@role) or
123 @role!='nodump']/userinput"/>
124 <xsl:if test="@id='ch-system-creatingdirs'">
125 <xsl:apply-templates
126 select="document('packageManager.xml')//sect1[
127 @id='ch-pkgmngt-creatingdirs'
128 ]//userinput"/>
129 </xsl:if>
130 <xsl:if test="@id='ch-system-createfiles'">
131 <xsl:apply-templates
132 select="document('packageManager.xml')//sect1[
133 @id='ch-pkgmngt-createfiles'
134 ]//userinput"/>
135 </xsl:if>
136 <xsl:if test="not(@id='ch-system-chroot') and
137 not(@id='ch-system-revisedchroot')">
138 <xsl:text>echo -e "\n\nTotalseconds: $SECONDS\n"&#xA;</xsl:text>
139 </xsl:if>
140 <xsl:text>exit&#xA;</xsl:text>
141 </exsl:document>
142 </xsl:if>
143 </xsl:template>
144
145 <xsl:template match="sect2">
146 <!--XML::Parser is on the same page as Perl. The present code is OK
147 except for PKG_DEST and PKGDIR, which would be the same as for Perl.
148 so set them to valid values.-->
149 <xsl:if test="contains(string(./title),'XML::Parser')">
150 <xsl:text>PKGDIR=$(dirname $PKGDIR)/</xsl:text>
151 <xsl:copy-of select="substring-after(.//userinput[@remap='pre'], 'cd ')"/>
152 <xsl:text>
153PKG_DEST=$(dirname $PKGDIR)/000-xml-parser
154</xsl:text>
155 </xsl:if>
156 <xsl:apply-templates
157 select=".//screen[not(@role) or
158 @role != 'nodump']/userinput[
159 @remap = 'pre' or
160 @remap = 'configure' or
161 @remap = 'make' or
162 @remap = 'test' and
163 not(current()/../@id='ch-tools-dejagnu')]"/>
164 <xsl:if
165 test="ancestor::chapter[@id != 'chapter-temporary-tools'] and
166 $pkgmngt = 'y' and
167 descendant::screen[not(@role) or
168 @role != 'nodump']/userinput[
169 @remap='install']">
170 <xsl:text>mkdir -pv $PKG_DEST/{boot,etc,lib,bin,sbin}
171mkdir -pv $PKG_DEST/usr/{lib,bin,sbin,include}
172mkdir -pv $PKG_DEST/usr/share/{doc,info,man}
173mkdir -pv $PKG_DEST/usr/share/man/man{1..8}
174ln -sv share/{man,doc,info} $PKG_DEST/usr
175case $(uname -m) in
176 x86_64) ln -sv lib $PKG_DEST/lib64 &amp;&amp; ln -sv lib $PKG_DEST/usr/lib64 ;;
177esac
178</xsl:text>
179 </xsl:if>
180 <xsl:if test="../@id = 'ch-system-glibc' and
181 @role='installation' and
182 $pkgmngt = 'y'">
183 <xsl:text>mkdir -pv $PKG_DEST/usr/include/{rpc,rpcsvc}
184</xsl:text>
185 </xsl:if>
186 <xsl:apply-templates
187 select=".//screen[not(@role) or
188 @role != 'nodump']/userinput[@remap = 'install']"/>
189 <xsl:if test="ancestor::chapter[@id != 'chapter-temporary-tools'] and
190 $pkgmngt = 'y' and
191 descendant::screen[not(@role) or
192 @role != 'nodump']/userinput[
193 @remap='install']">
194 <xsl:if test="../@id = 'ch-system-man-pages'">
195<!-- these files are provided by the shadow package -->
196 <xsl:text>rm -fv $PKG_DEST/usr/share/man/{man3/getspnam.3,man5/passwd.5}
197</xsl:text>
198 </xsl:if>
199<!-- Attr man/man2 pages are already installed by man-pages. As of
200 March 2013, they are the same pages. Check it sometimes... -->
201 <xsl:if test="../@id = 'ch-system-attr'">
202 <xsl:text>rm -fv $PKG_DEST/usr/share/man/man2/*
203</xsl:text>
204 </xsl:if>
205 <xsl:text>rm -fv $PKG_DEST/{,usr/}lib64
206rm -fv $PKG_DEST/usr/{man,doc,info}
207for dir in $PKG_DEST/usr/share/man/man{1..8}; do
208 [[ -z $(ls $dir) ]] &amp;&amp; rmdir -v $dir
209done
210for dir in $PKG_DEST/usr/share/{doc,info,man}; do
211 [[ -z $(ls $dir) ]] &amp;&amp; rmdir -v $dir
212done
213for dir in $PKG_DEST/usr/{lib,bin,sbin,include}; do
214 [[ -z $(ls $dir) ]] &amp;&amp; rmdir -v $dir
215done
216for dir in $PKG_DEST/{boot,etc,lib,bin,sbin}; do
217 [[ -z $(ls $dir) ]] &amp;&amp; rmdir -v $dir
218done
219packInstall
220rm -rf $PKG_DEST
221</xsl:text>
222 </xsl:if>
223 <xsl:if test="$testsuite='3' and
224 ../@id='ch-tools-glibc' and
225 @role='installation'">
226 <xsl:copy-of select="//userinput[@remap='locale-test']"/>
227 <xsl:text>&#xA;</xsl:text>
228 </xsl:if>
229 <xsl:if test="../@id='ch-system-glibc' and @role='installation'">
230 <xsl:choose>
231 <xsl:when test="$full-locale='y'">
232 <xsl:copy-of select="//userinput[@remap='locale-full']"/>
233 <xsl:text>&#xA;</xsl:text>
234 </xsl:when>
235 <xsl:otherwise>
236 <xsl:copy-of select="//userinput[@remap='locale-test']"/>
237 <xsl:text>&#xA;</xsl:text>
238 <xsl:if test="not(contains(string(//userinput[@remap='locale-test']),$lang)) and $lang!='C' and $lang!='POSIX'">
239 <xsl:text>if LOCALE=`grep "</xsl:text>
240 <xsl:value-of select="$lang"/>
241 <xsl:text>/" $PKGDIR/localedata/SUPPORTED`; then
242 CHARMAP=`echo $LOCALE | sed 's,[^/]*/\([^ ]*\) [\],\1,'`
243 INPUT=`echo $LOCALE | sed 's,[/.].*,,'`
244 LOCALE=`echo $LOCALE | sed 's,/.*,,'`
245 localedef -i $INPUT -f $CHARMAP $LOCALE
246fi
247</xsl:text>
248 </xsl:if>
249 </xsl:otherwise>
250 </xsl:choose>
251 </xsl:if>
252 <xsl:apply-templates
253 select=".//screen[
254 not(@role) or
255 @role != 'nodump'
256 ]/userinput[
257 not(@remap) or
258 @remap='adjust' or
259 @remap='test' and current()/../@id='ch-tools-dejagnu'
260 ]"/>
261 </xsl:template>
262
263 <xsl:template match="sect1" mode="pkgmngt">
264 <xsl:param name="dirname" select="chapter05"/>
265 <!-- The build order -->
266 <xsl:param name="order" select="062"/>
267<!-- The file names -->
268 <xsl:variable name="pi-file" select="processing-instruction('dbhtml')"/>
269 <xsl:variable name="pi-file-value" select="substring-after($pi-file,'filename=')"/>
270 <xsl:variable name="filename" select="substring-before(substring($pi-file-value,2),'.html')"/>
271 <!-- Creating dirs and files -->
272 <exsl:document href="{$dirname}/{$order}-{position()}-{$filename}" method="text">
273 <xsl:text>#!/bin/bash
274set +h
275set -e
276
277cd $PKGDIR
278</xsl:text>
279 <xsl:apply-templates
280 select=".//screen[not(@role) or @role != 'nodump']/userinput[@remap != 'adjust']"
281 mode="pkgmngt"/>
282 <xsl:if test="$dirname = 'chapter06'">
283 <xsl:text>packInstall
284rm -rf $PKG_DEST
285</xsl:text>
286 </xsl:if>
287 <xsl:apply-templates
288 select=".//screen[
289 not(@role) or
290 @role != 'nodump'
291 ]/userinput[
292 not(@remap) or
293 @remap='adjust'
294 ]"
295 mode="pkgmngt"/>
296 <xsl:text>
297echo -e "\n\nTotalseconds: $SECONDS\n"
298exit
299</xsl:text>
300 </exsl:document>
301 </xsl:template>
302
303 <xsl:template match="userinput" mode="pkgmngt">
304 <xsl:apply-templates/>
305 <xsl:text>&#xA;</xsl:text>
306 </xsl:template>
307
308 <xsl:template match="userinput">
309 <xsl:choose>
310 <!-- Copying the kernel config file -->
311 <xsl:when test="string() = 'make mrproper'">
312 <xsl:text>make mrproper&#xA;</xsl:text>
313 <xsl:if test="ancestor::sect1[@id='ch-bootable-kernel']">
314 <xsl:text>cp -v ../kernel-config .config&#xA;</xsl:text>
315 </xsl:if>
316 </xsl:when>
317<!-- test instructions -->
318 <xsl:when test="@remap = 'test'">
319 <xsl:choose>
320 <xsl:when test="$testsuite = '0'"/>
321 <xsl:when test="$testsuite = '1' and
322 not(ancestor::sect1[@id='ch-system-gcc']) and
323 not(ancestor::sect1[@id='ch-system-glibc']) and
324 not(ancestor::sect1[@id='ch-system-gmp']) and
325 not(ancestor::sect1[@id='ch-system-mpfr']) and
326 not(ancestor::sect1[@id='ch-system-binutils'])"/>
327 <xsl:when test="$testsuite = '2' and
328 ancestor::chapter[@id='chapter-temporary-tools']"/>
329 <xsl:otherwise>
330 <xsl:choose>
331 <xsl:when test="$bomb-testsuite = 'n'">
332 <xsl:choose>
333 <!-- special case for glibc -->
334 <xsl:when test="contains(string(), 'glibc-check-log')">
335 <xsl:value-of
336 select="substring-before(string(),'2&gt;&amp;1')"/>
337 <xsl:text>&gt;&gt; $TEST_LOG 2&gt;&amp;1 || true&#xA;</xsl:text>
338 </xsl:when>
339 <!-- special case for procps-ng -->
340 <xsl:when test="contains(string(), 'pushd')">
341 <xsl:text>{ </xsl:text>
342 <xsl:apply-templates/>
343 <xsl:text>; } &gt;&gt; $TEST_LOG 2&gt;&amp;1 || true&#xA;</xsl:text>
344 </xsl:when>
345 <xsl:when test="contains(string(), 'make -k')">
346 <xsl:apply-templates/>
347 <xsl:text> &gt;&gt; $TEST_LOG 2&gt;&amp;1 || true&#xA;</xsl:text>
348 </xsl:when>
349 <xsl:when test="contains(string(), 'make')">
350 <xsl:value-of select="substring-before(string(),'make')"/>
351 <xsl:text>make -k</xsl:text>
352 <xsl:value-of select="substring-after(string(),'make')"/>
353 <xsl:text> &gt;&gt; $TEST_LOG 2&gt;&amp;1 || true&#xA;</xsl:text>
354 </xsl:when>
355 <xsl:otherwise>
356 <xsl:apply-templates/>
357 <xsl:if test="not(contains(string(), '&gt;&gt;'))">
358 <xsl:text> &gt;&gt; $TEST_LOG 2&gt;&amp;1</xsl:text>
359 </xsl:if>
360 <xsl:text>&#xA;</xsl:text>
361 </xsl:otherwise>
362 </xsl:choose>
363 </xsl:when>
364 <xsl:otherwise>
365 <!-- bomb-testsuite != 'n'-->
366 <xsl:choose>
367 <!-- special case for glibc -->
368 <xsl:when test="contains(string(), 'glibc-check-log')">
369 <xsl:value-of
370 select="substring-before(string(),'2&gt;&amp;1')"/>
371 <xsl:text>&gt;&gt; $TEST_LOG 2&gt;&amp;1 || true&#xA;</xsl:text>
372 </xsl:when>
373 <!-- special case for gmp -->
374 <xsl:when test="contains(string(), 'tee gmp-check-log')">
375 <xsl:text>(</xsl:text>
376 <xsl:apply-templates/>
377 <xsl:text>&gt;&gt; $TEST_LOG 2&gt;&amp;1 &amp;&amp; exit $PIPESTATUS)&#xA;</xsl:text>
378 </xsl:when>
379 <!-- special case for procps-ng -->
380 <xsl:when test="contains(string(), 'pushd')">
381 <xsl:text>{ </xsl:text>
382 <xsl:apply-templates/>
383 <xsl:text>; } &gt;&gt; $TEST_LOG 2&gt;&amp;1&#xA;</xsl:text>
384 </xsl:when>
385 <xsl:when test="contains(string(), 'make -k')">
386 <xsl:apply-templates/>
387 <xsl:text> &gt;&gt; $TEST_LOG 2&gt;&amp;1 || true&#xA;</xsl:text>
388 </xsl:when>
389 <xsl:otherwise>
390 <xsl:apply-templates/>
391 <xsl:if test="not(contains(string(), '&gt;&gt;'))">
392 <xsl:text> &gt;&gt; $TEST_LOG 2&gt;&amp;1</xsl:text>
393 </xsl:if>
394 <xsl:text>&#xA;</xsl:text>
395 </xsl:otherwise>
396 </xsl:choose>
397 </xsl:otherwise>
398 </xsl:choose>
399 </xsl:otherwise>
400 </xsl:choose>
401 </xsl:when>
402<!-- End of test instructions -->
403 <!-- Don't stop on strip run -->
404 <xsl:when test="contains(string(),'strip ')">
405 <xsl:apply-templates/>
406 <xsl:text> || true&#xA;</xsl:text>
407 </xsl:when>
408<!-- Package management -->
409<!-- Add $PKG_DEST to installation commands -->
410 <xsl:when test="@remap='install' and
411 not(ancestor::chapter[
412 @id='chapter-temporary-tools'
413 ])">
414 <xsl:choose>
415 <xsl:when test="$pkgmngt='n'">
416 <xsl:choose>
417 <xsl:when test="contains(string(),'firmware,udev')">
418 <xsl:text>if [[ ! -d /lib/udev/devices ]] ; then&#xA;</xsl:text>
419 <xsl:apply-templates/>
420 <xsl:text>&#xA;fi&#xA;</xsl:text>
421 </xsl:when>
422 <xsl:otherwise>
423 <xsl:apply-templates/>
424 <xsl:text>&#xA;</xsl:text>
425 </xsl:otherwise>
426 </xsl:choose>
427 </xsl:when>
428 <xsl:otherwise><!--pkgmngt = 'y'-->
429 <xsl:choose>
430 <xsl:when test="./literal">
431 <xsl:call-template name="outputpkgdest">
432 <xsl:with-param name="outputstring" select="text()[1]"/>
433 </xsl:call-template>
434 <xsl:apply-templates select="literal"/>
435 <xsl:call-template name="outputpkgdest">
436 <xsl:with-param name="outputstring" select="text()[2]"/>
437 </xsl:call-template>
438 </xsl:when>
439 <xsl:otherwise>
440 <xsl:call-template name="outputpkgdest">
441 <xsl:with-param name="outputstring" select="string()"/>
442 </xsl:call-template>
443 </xsl:otherwise>
444 </xsl:choose>
445 </xsl:otherwise>
446 </xsl:choose>
447 </xsl:when>
448 <!-- End addition for package management -->
449 <!-- The rest of commands -->
450 <xsl:otherwise>
451 <xsl:apply-templates/>
452 <xsl:text>&#xA;</xsl:text>
453 </xsl:otherwise>
454 </xsl:choose>
455 </xsl:template>
456
457 <xsl:template match="replaceable">
458 <xsl:choose>
459 <xsl:when test="ancestor::sect1[@id='ch-system-glibc']">
460 <xsl:value-of select="$timezone"/>
461 </xsl:when>
462 <xsl:when test="ancestor::sect1[@id='ch-system-groff']">
463 <xsl:value-of select="$page"/>
464 </xsl:when>
465 <xsl:when test="contains(string(.),'&lt;ll&gt;_&lt;CC&gt;')">
466 <xsl:value-of select="$lang"/>
467 </xsl:when>
468 <xsl:otherwise>
469 <xsl:text>**EDITME</xsl:text>
470 <xsl:apply-templates/>
471 <xsl:text>EDITME**</xsl:text>
472 </xsl:otherwise>
473 </xsl:choose>
474 </xsl:template>
475
476 <xsl:template name="outputpkgdest">
477 <xsl:param name="outputstring" select="foo"/>
478 <xsl:choose>
479 <xsl:when test="contains($outputstring,'make ')">
480 <xsl:choose>
481 <xsl:when test="not(starts-with($outputstring,'make'))">
482 <xsl:call-template name="outputpkgdest">
483 <xsl:with-param name="outputstring"
484 select="substring-before($outputstring,'make')"/>
485 </xsl:call-template>
486 <xsl:call-template name="outputpkgdest">
487 <xsl:with-param
488 name="outputstring"
489 select="substring-after($outputstring,
490 substring-before($outputstring,'make'))"/>
491 </xsl:call-template>
492 </xsl:when>
493 <xsl:otherwise>
494 <xsl:choose>
495<!-- special cases (no DESTDIR) here -->
496 <xsl:when test="ancestor::sect1[@id='ch-system-glibc']">
497 <xsl:text>make install_root=$PKG_DEST -j1</xsl:text>
498 <xsl:value-of
499 select="substring-before(substring-after(string(),'make'),
500 'install')"/>
501 <xsl:text>install&#xA;</xsl:text>
502 </xsl:when>
503 <xsl:when test="ancestor::sect1[@id='ch-system-bzip2']">
504 <xsl:text>make PREFIX=$PKG_DEST/usr install&#xA;</xsl:text>
505 </xsl:when>
506 <xsl:when test="ancestor::sect1[@id='ch-system-sysklogd']">
507 <xsl:text>make BINDIR=$PKG_DEST/sbin prefix=$PKG_DEST install&#xA;</xsl:text>
508 </xsl:when>
509 <xsl:when test="ancestor::sect1[@id='ch-system-iproute2']">
510 <xsl:text>make DESTDIR=$PKG_DEST</xsl:text>
511 <xsl:value-of
512 select="substring-before(substring-after(string(),'DESTDIR='),
513 'install')"/>
514 <xsl:text>install&#xA;</xsl:text>
515 </xsl:when>
516 <xsl:when test="ancestor::sect1[@id='ch-system-sysvinit']">
517 <xsl:text>make ROOT=$PKG_DEST</xsl:text>
518 <xsl:value-of
519 select="substring-before(substring-after(string(),'make'),
520 'install')"/>
521 <xsl:text>install&#xA;</xsl:text>
522 </xsl:when>
523 <xsl:when test="ancestor::sect1[@id='ch-bootable-kernel']">
524 <xsl:text>make INSTALL_MOD_PATH=$PKG_DEST</xsl:text>
525 <xsl:value-of
526 select="substring-before(substring-after(string(),'make'),
527 'install')"/>
528 <xsl:text>install&#xA;</xsl:text>
529 </xsl:when>
530 <xsl:when test="ancestor::sect1[@id='ch-system-attr']">
531 <xsl:text>DIST_ROOT=$PKG_DEST make</xsl:text>
532 <xsl:call-template name="outputpkgdest">
533 <xsl:with-param name="outputstring"
534 select="substring-after($outputstring,'make')"/>
535 </xsl:call-template>
536 </xsl:when>
537 <xsl:otherwise>
538 <xsl:text>make DESTDIR=$PKG_DEST</xsl:text>
539 <xsl:call-template name="outputpkgdest">>
540 <xsl:with-param
541 name="outputstring"
542 select="substring-after($outputstring,'make')"/>
543 </xsl:call-template>
544 </xsl:otherwise>
545 </xsl:choose>
546 </xsl:otherwise>
547 </xsl:choose>
548 </xsl:when>
549 <xsl:otherwise> <!-- no make in this string -->
550 <xsl:choose>
551 <xsl:when test="contains($outputstring,'&gt;/') and
552 not(contains(substring-before($outputstring,'&gt;/'),' /'))">
553 <xsl:value-of select="substring-before($outputstring,'&gt;/')"/>
554 <xsl:text>&gt;$PKG_DEST/</xsl:text>
555 <xsl:call-template name="outputpkgdest">
556 <xsl:with-param name="outputstring" select="substring-after($outputstring,'&gt;/')"/>
557 </xsl:call-template>
558 </xsl:when>
559 <xsl:when test="contains($outputstring,' /')">
560 <xsl:value-of select="substring-before($outputstring,' /')"/>
561 <xsl:text> $PKG_DEST/</xsl:text>
562 <xsl:call-template name="outputpkgdest">
563 <xsl:with-param name="outputstring" select="substring-after($outputstring,' /')"/>
564 </xsl:call-template>
565 </xsl:when>
566 <xsl:otherwise>
567 <xsl:value-of select="$outputstring"/>
568 <xsl:text>&#xA;</xsl:text>
569 </xsl:otherwise>
570 </xsl:choose>
571 </xsl:otherwise>
572 </xsl:choose>
573 </xsl:template>
574</xsl:stylesheet>
Note: See TracBrowser for help on using the repository browser.