source: LFS/lfs.xsl@ 2507cf7

ablfs
Last change on this file since 2507cf7 was 7e51281, checked in by Pierre Labastie <pierre@…>, 12 years ago

Changed the pkgmngt part of lfs.xsl so that no script is created if
packageManager.xml has not <screen><userinput> nodes for that
  • Property mode set to 100644
File size: 21.8 KB
Line 
1<?xml version="1.0" encoding="ISO-8859-1"?>
2
3<!-- $Id$ -->
4
5<xsl:stylesheet
6 xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
7 xmlns:exsl="http://exslt.org/common"
8 extension-element-prefixes="exsl"
9 version="1.0">
10
11 <!-- use package management ?
12 n = no, original behavior
13 y = yes, add PKG_DEST to scripts in install commands of chapter06-08
14 -->
15 <xsl:param name="pkgmngt" select="n"/>
16
17 <!-- Run test suites?
18 0 = none
19 1 = only chapter06 Glibc, GCC and Binutils testsuites
20 2 = all chapter06 testsuites
21 3 = all chapter05 and chapter06 testsuites
22 -->
23 <xsl:param name="testsuite" select="1"/>
24
25 <!-- Bomb on test suites failures?
26 n = no, I want to build the full system and review the logs
27 y = yes, bomb at the first test suite failure to can review the build dir
28 -->
29 <xsl:param name="bomb-testsuite" select="n"/>
30
31 <!-- Install vim-lang package? OBSOLETE should always be 'n'-->
32 <xsl:param name="vim-lang" select="n"/>
33
34 <!-- Time zone -->
35 <xsl:param name="timezone" select="GMT"/>
36
37 <!-- Page size -->
38 <xsl:param name="page" select="letter"/>
39
40 <!-- Locale settings -->
41 <xsl:param name="lang" select="C"/>
42
43 <!-- Install the whole set of locales -->
44 <xsl:param name='full-locale' select='n'/>
45
46 <xsl:template match="/">
47 <xsl:apply-templates select="//sect1"/>
48 </xsl:template>
49
50 <xsl:template match="sect1">
51 <xsl:if test="(../@id='chapter-temporary-tools' or
52 ../@id='chapter-building-system' or
53 ../@id='chapter-bootscripts' or
54 ../@id='chapter-bootable') and
55 count(descendant::screen/userinput) &gt; 0 and
56 count(descendant::screen/userinput) &gt;
57 count(descendant::screen[@role='nodump'])">
58 <!-- The dirs names -->
59 <xsl:variable name="pi-dir" select="../processing-instruction('dbhtml')"/>
60 <xsl:variable name="pi-dir-value" select="substring-after($pi-dir,'dir=')"/>
61 <xsl:variable name="quote-dir" select="substring($pi-dir-value,1,1)"/>
62 <xsl:variable name="dirname" select="substring-before(substring($pi-dir-value,2),$quote-dir)"/>
63 <!-- The file names -->
64 <xsl:variable name="pi-file" select="processing-instruction('dbhtml')"/>
65 <xsl:variable name="pi-file-value" select="substring-after($pi-file,'filename=')"/>
66 <xsl:variable name="filename" select="substring-before(substring($pi-file-value,2),'.html')"/>
67 <!-- The build order -->
68 <xsl:variable name="position" select="position()"/>
69 <xsl:variable name="order">
70 <xsl:choose>
71 <xsl:when test="string-length($position) = 1">
72 <xsl:text>00</xsl:text>
73 <xsl:value-of select="$position"/>
74 </xsl:when>
75 <xsl:when test="string-length($position) = 2">
76 <xsl:text>0</xsl:text>
77 <xsl:value-of select="$position"/>
78 </xsl:when>
79 <xsl:otherwise>
80 <xsl:value-of select="$position"/>
81 </xsl:otherwise>
82 </xsl:choose>
83 </xsl:variable>
84 <!-- Inclusion of package manager scriptlets -->
85 <xsl:if test="@id='ch-tools-stripping' and $pkgmngt='y'">
86 <xsl:apply-templates
87 select="document('packageManager.xml')//sect1[contains(@id,'ch-tools')]"
88 mode="pkgmngt">
89 <xsl:with-param name="order" select="$order"/>
90 <xsl:with-param name="dirname" select="$dirname"/>
91 </xsl:apply-templates>
92 </xsl:if>
93 <xsl:if test="@id='ch-system-strippingagain' and $pkgmngt='y'">
94 <xsl:apply-templates
95 select="document('packageManager.xml')//sect1[contains(@id,'ch-system')]"
96 mode="pkgmngt">
97 <xsl:with-param name="order" select="$order"/>
98 <xsl:with-param name="dirname" select="$dirname"/>
99 </xsl:apply-templates>
100 </xsl:if>
101 <!-- Creating dirs and files -->
102 <exsl:document href="{$dirname}/{$order}-{$filename}" method="text">
103 <xsl:choose>
104 <xsl:when test="@id='ch-system-creatingdirs' or
105 @id='ch-system-createfiles' or
106 @id='ch-system-strippingagain'">
107 <xsl:text>#!/tools/bin/bash&#xA;set +h&#xA;</xsl:text>
108 </xsl:when>
109 <xsl:otherwise>
110 <xsl:text>#!/bin/bash&#xA;set +h&#xA;</xsl:text>
111 </xsl:otherwise>
112 </xsl:choose>
113 <xsl:if test="not(@id='ch-tools-stripping') and
114 not(@id='ch-system-strippingagain')">
115 <xsl:text>set -e&#xA;</xsl:text>
116 </xsl:if>
117 <xsl:text>&#xA;</xsl:text>
118 <xsl:if test="sect2[@role='installation']">
119 <xsl:text>cd $PKGDIR&#xA;</xsl:text>
120 </xsl:if>
121 <xsl:apply-templates
122 select=".//screen[not(@role) or
123 @role != 'nodump']/userinput[
124 @remap = 'pre' or
125 @remap = 'configure' or
126 @remap = 'make' or
127 @remap = 'test' and
128 not(current()/@id='ch-tools-dejagnu')]"/>
129 <xsl:if
130 test="ancestor::chapter[@id != 'chapter-temporary-tools'] and
131 $pkgmngt = 'y' and
132 descendant::screen[not(@role) or
133 @role != 'nodump']/userinput[
134 @remap='install']">
135 <xsl:text>mkdir -pv $PKG_DEST/{boot,etc,lib,bin,sbin}
136mkdir -pv $PKG_DEST/usr/{lib,bin,sbin,include}
137mkdir -pv $PKG_DEST/usr/share/{doc,info,man}
138mkdir -pv $PKG_DEST/usr/share/man/man{1..8}
139ln -sv share/{man,doc,info} $PKG_DEST/usr
140case $(uname -m) in
141 x86_64) ln -sv lib $PKG_DEST/lib64 &amp;&amp; ln -sv lib $PKG_DEST/usr/lib64 ;;
142esac
143</xsl:text>
144 </xsl:if>
145 <xsl:if test="@id = 'ch-system-glibc' and
146 $pkgmngt = 'y'">
147 <xsl:text>mkdir -pv $PKG_DEST/usr/include/{rpc,rpcsvc}
148</xsl:text>
149 </xsl:if>
150 <xsl:apply-templates
151 select=".//screen[not(@role) or
152 @role != 'nodump']/userinput[@remap = 'install']"/>
153 <xsl:if test="ancestor::chapter[@id != 'chapter-temporary-tools'] and
154 $pkgmngt = 'y' and
155 descendant::screen[not(@role) or
156 @role != 'nodump']/userinput[
157 @remap='install']">
158 <xsl:if test="@id = 'ch-system-man-pages'">
159<!-- those files are provided by the shadow package -->
160 <xsl:text>rm -fv $PKG_DEST/usr/share/man/{man3/getspnam.3,man5/passwd.5}
161</xsl:text>
162 </xsl:if>
163 <xsl:text>rm -fv $PKG_DEST/{,usr/}lib64
164rm -fv $PKG_DEST/usr/{man,doc,info}
165for dir in $PKG_DEST/usr/share/man/man{1..8}; do
166 [[ -z $(ls $dir) ]] &amp;&amp; rmdir -v $dir
167done
168for dir in $PKG_DEST/usr/share/{doc,info,man}; do
169 [[ -z $(ls $dir) ]] &amp;&amp; rmdir -v $dir
170done
171for dir in $PKG_DEST/usr/{lib,bin,sbin,include}; do
172 [[ -z $(ls $dir) ]] &amp;&amp; rmdir -v $dir
173done
174for dir in $PKG_DEST/{boot,etc,lib,bin,sbin}; do
175 [[ -z $(ls $dir) ]] &amp;&amp; rmdir -v $dir
176done
177packInstall
178rm -rf $PKG_DEST
179</xsl:text>
180 </xsl:if>
181 <xsl:if test="$testsuite='3' and @id='ch-tools-glibc'">
182 <xsl:copy-of select="//userinput[@remap='locale-test']"/>
183 <xsl:text>&#xA;</xsl:text>
184 </xsl:if>
185 <xsl:if test="@id='ch-system-glibc'">
186 <xsl:choose>
187 <xsl:when test="$full-locale='y'">
188 <xsl:copy-of select="//userinput[@remap='locale-full']"/>
189 <xsl:text>&#xA;</xsl:text>
190 </xsl:when>
191 <xsl:otherwise>
192 <xsl:copy-of select="//userinput[@remap='locale-test']"/>
193 <xsl:text>&#xA;</xsl:text>
194 <xsl:if test="not(contains(string(//userinput[@remap='locale-test']),$lang)) and $lang!='C' and $lang!='POSIX'">
195 <xsl:text>if LOCALE=`grep "</xsl:text>
196 <xsl:value-of select="$lang"/>
197 <xsl:text>/" $PKGDIR/localedata/SUPPORTED`; then
198 CHARMAP=`echo $LOCALE | sed 's,[^/]*/\([^ ]*\) [\],\1,'`
199 INPUT=`echo $LOCALE | sed 's,[/.].*,,'`
200 LOCALE=`echo $LOCALE | sed 's,/.*,,'`
201 localedef -i $INPUT -f $CHARMAP $LOCALE
202fi
203</xsl:text>
204 </xsl:if>
205 </xsl:otherwise>
206 </xsl:choose>
207 </xsl:if>
208 <xsl:apply-templates
209 select=".//screen[
210 not(@role) or
211 @role != 'nodump'
212 ]/userinput[
213 not(@remap) or
214 @remap='adjust' or
215 @remap='test' and current()/@id='ch-tools-dejagnu'
216 ]"/>
217 <xsl:if test="@id='ch-system-creatingdirs'">
218 <xsl:apply-templates
219 select="document('packageManager.xml')//sect1[
220 @id='ch-pkgmngt-creatingdirs'
221 ]//userinput"/>
222 </xsl:if>
223 <xsl:if test="@id='ch-system-createfiles'">
224 <xsl:apply-templates
225 select="document('packageManager.xml')//sect1[
226 @id='ch-pkgmngt-createfiles'
227 ]//userinput"/>
228 </xsl:if>
229 <xsl:if test="not(@id='ch-system-chroot') and
230 not(@id='ch-system-revisedchroot')">
231 <xsl:text>echo -e "\n\nTotalseconds: $SECONDS\n"&#xA;</xsl:text>
232 </xsl:if>
233 <xsl:text>exit&#xA;</xsl:text>
234 </exsl:document>
235 </xsl:if>
236 </xsl:template>
237
238 <xsl:template match="sect1" mode="pkgmngt">
239 <xsl:param name="dirname" select="chapter05"/>
240 <!-- The build order -->
241 <xsl:param name="order" select="062"/>
242<!-- The file names -->
243 <xsl:variable name="pi-file" select="processing-instruction('dbhtml')"/>
244 <xsl:variable name="pi-file-value" select="substring-after($pi-file,'filename=')"/>
245 <xsl:variable name="filename" select="substring-before(substring($pi-file-value,2),'.html')"/>
246 <!-- Creating dirs and files -->
247 <xsl:if test="count(descendant::screen/userinput) &gt; 0 and
248 count(descendant::screen/userinput) &gt;
249 count(descendant::screen[@role='nodump'])">
250 <exsl:document href="{$dirname}/{$order}-{position()}-{$filename}"
251 method="text">
252 <xsl:text>#!/bin/bash
253set +h
254set -e
255
256cd $PKGDIR
257</xsl:text>
258 <xsl:apply-templates
259 select=".//screen[not(@role) or
260 @role != 'nodump']/userinput[@remap != 'adjust']"
261 mode="pkgmngt"/>
262 <xsl:if test="$dirname = 'chapter06'">
263 <xsl:text>packInstall
264rm -rf $PKG_DEST
265</xsl:text>
266 </xsl:if>
267 <xsl:apply-templates
268 select=".//screen[not(@role) or
269 @role != 'nodump'
270 ]/userinput[not(@remap) or
271 @remap='adjust'
272 ]"
273 mode="pkgmngt"/>
274 <xsl:text>
275echo -e "\n\nTotalseconds: $SECONDS\n"
276exit
277</xsl:text>
278 </exsl:document>
279 </xsl:if>
280 </xsl:template>
281
282 <xsl:template match="userinput" mode="pkgmngt">
283 <xsl:apply-templates/>
284 <xsl:text>&#xA;</xsl:text>
285 </xsl:template>
286
287 <xsl:template match="userinput">
288 <xsl:choose>
289 <!-- Copying the kernel config file -->
290 <xsl:when test="string() = 'make mrproper'">
291 <xsl:text>make mrproper&#xA;</xsl:text>
292 <xsl:if test="ancestor::sect1[@id='ch-bootable-kernel']">
293 <xsl:text>cp -v ../kernel-config .config&#xA;</xsl:text>
294 </xsl:if>
295 </xsl:when>
296<!-- test instructions -->
297 <xsl:when test="@remap = 'test'">
298 <xsl:choose>
299 <xsl:when test="$testsuite = '0'"/>
300 <xsl:when test="$testsuite = '1' and
301 not(ancestor::sect1[@id='ch-system-gcc']) and
302 not(ancestor::sect1[@id='ch-system-glibc']) and
303 not(ancestor::sect1[@id='ch-system-gmp']) and
304 not(ancestor::sect1[@id='ch-system-mpfr']) and
305 not(ancestor::sect1[@id='ch-system-binutils'])"/>
306 <xsl:when test="$testsuite = '2' and
307 ancestor::chapter[@id='chapter-temporary-tools']"/>
308 <xsl:otherwise>
309 <xsl:choose>
310 <xsl:when test="$bomb-testsuite = 'n'">
311 <xsl:choose>
312 <!-- special case for glibc -->
313 <xsl:when test="contains(string(), 'glibc-check-log')">
314 <xsl:value-of
315 select="substring-before(string(),'2&gt;&amp;1')"/>
316 <xsl:text>&gt;&gt; $TEST_LOG 2&gt;&amp;1 || true&#xA;</xsl:text>
317 </xsl:when>
318 <xsl:when test="contains(string(), 'make -k')">
319 <xsl:apply-templates/>
320 <xsl:text> &gt;&gt; $TEST_LOG 2&gt;&amp;1 || true&#xA;</xsl:text>
321 </xsl:when>
322 <xsl:when test="contains(string(), 'make')">
323 <xsl:value-of select="substring-before(string(),'make')"/>
324 <xsl:text>make -k</xsl:text>
325 <xsl:value-of select="substring-after(string(),'make')"/>
326 <xsl:text> &gt;&gt; $TEST_LOG 2&gt;&amp;1 || true&#xA;</xsl:text>
327 </xsl:when>
328 <xsl:otherwise>
329 <xsl:apply-templates/>
330 <xsl:if test="not(contains(string(), '&gt;&gt;'))">
331 <xsl:text> &gt;&gt; $TEST_LOG 2&gt;&amp;1</xsl:text>
332 </xsl:if>
333 <xsl:text>&#xA;</xsl:text>
334 </xsl:otherwise>
335 </xsl:choose>
336 </xsl:when>
337 <xsl:otherwise>
338 <!-- bomb-testsuite != 'n'-->
339 <xsl:choose>
340 <!-- special case for glibc -->
341 <xsl:when test="contains(string(), 'glibc-check-log')">
342 <xsl:value-of
343 select="substring-before(string(),'2&gt;&amp;1')"/>
344 <xsl:text>&gt;&gt; $TEST_LOG 2&gt;&amp;1 || true&#xA;</xsl:text>
345 </xsl:when>
346 <xsl:when test="contains(string(), 'tee gmp-check-log')">
347 <xsl:text>(</xsl:text>
348 <xsl:apply-templates/>
349 <xsl:text>&gt;&gt; $TEST_LOG 2&gt;&amp;1 &amp;&amp; exit $PIPESTATUS)&#xA;</xsl:text>
350 </xsl:when>
351 <xsl:when test="contains(string(), 'make -k')">
352 <xsl:apply-templates/>
353 <xsl:text> &gt;&gt; $TEST_LOG 2&gt;&amp;1 || true&#xA;</xsl:text>
354 </xsl:when>
355 <xsl:otherwise>
356 <xsl:apply-templates/>
357 <xsl:if test="not(contains(string(), '&gt;&gt;'))">
358 <xsl:text> &gt;&gt; $TEST_LOG 2&gt;&amp;1</xsl:text>
359 </xsl:if>
360 <xsl:text>&#xA;</xsl:text>
361 </xsl:otherwise>
362 </xsl:choose>
363 </xsl:otherwise>
364 </xsl:choose>
365 </xsl:otherwise>
366 </xsl:choose>
367 </xsl:when>
368<!-- End of test instructions -->
369 <!-- Don't stop on strip run -->
370 <xsl:when test="contains(string(),'strip ')">
371 <xsl:apply-templates/>
372 <xsl:text> || true&#xA;</xsl:text>
373 </xsl:when>
374<!-- Package management -->
375<!-- Add $PKG_DEST to installation commands -->
376 <xsl:when test="@remap='install' and
377 not(ancestor::chapter[
378 @id='chapter-temporary-tools'
379 ])">
380 <xsl:choose>
381 <xsl:when test="$pkgmngt='n'">
382 <xsl:choose>
383 <xsl:when test="contains(string(),'firmware,udev')">
384 <xsl:text>if [[ ! -d /lib/udev/devices ]] ; then&#xA;</xsl:text>
385 <xsl:apply-templates/>
386 <xsl:text>&#xA;fi&#xA;</xsl:text>
387 </xsl:when>
388 <xsl:otherwise>
389 <xsl:apply-templates/>
390 <xsl:text>&#xA;</xsl:text>
391 </xsl:otherwise>
392 </xsl:choose>
393 </xsl:when>
394 <xsl:otherwise><!--pkgmngt = 'y'-->
395 <xsl:choose>
396 <xsl:when test="./literal">
397 <xsl:call-template name="outputpkgdest">
398 <xsl:with-param name="outputstring"
399 select="text()[1]"/>
400 </xsl:call-template>
401 <xsl:apply-templates select="literal"/>
402 <xsl:call-template name="outputpkgdest">
403 <xsl:with-param name="outputstring"
404 select="text()[2]"/>
405 </xsl:call-template>
406 </xsl:when>
407 <xsl:otherwise>
408 <xsl:call-template name="outputpkgdest">
409 <xsl:with-param name="outputstring" select="string()"/>
410 </xsl:call-template>
411 </xsl:otherwise>
412 </xsl:choose>
413 </xsl:otherwise>
414 </xsl:choose>
415 </xsl:when>
416 <!-- End addition for package management -->
417 <!-- The rest of commands -->
418 <xsl:otherwise>
419 <xsl:apply-templates/>
420 <xsl:text>&#xA;</xsl:text>
421 </xsl:otherwise>
422 </xsl:choose>
423 </xsl:template>
424
425 <xsl:template match="replaceable">
426 <xsl:choose>
427 <xsl:when test="ancestor::sect1[@id='ch-system-glibc']">
428 <xsl:value-of select="$timezone"/>
429 </xsl:when>
430 <xsl:when test="ancestor::sect1[@id='ch-system-groff']">
431 <xsl:value-of select="$page"/>
432 </xsl:when>
433 <xsl:when test="contains(string(.),'&lt;ll&gt;_&lt;CC&gt;')">
434 <xsl:value-of select="$lang"/>
435 </xsl:when>
436 <xsl:otherwise>
437 <xsl:text>**EDITME</xsl:text>
438 <xsl:apply-templates/>
439 <xsl:text>EDITME**</xsl:text>
440 </xsl:otherwise>
441 </xsl:choose>
442 </xsl:template>
443
444 <xsl:template name="outputpkgdest">
445 <xsl:param name="outputstring" select="foo"/>
446 <xsl:choose>
447 <xsl:when test="contains($outputstring,'make ')">
448 <xsl:choose>
449 <xsl:when test="not(starts-with($outputstring,'make'))">
450 <xsl:call-template name="outputpkgdest">
451 <xsl:with-param name="outputstring"
452 select="substring-before($outputstring,'make')"/>
453 </xsl:call-template>
454 <xsl:call-template name="outputpkgdest">
455 <xsl:with-param
456 name="outputstring"
457 select="substring-after($outputstring,
458 substring-before($outputstring,'make'))"/>
459 </xsl:call-template>
460 </xsl:when>
461 <xsl:otherwise>
462 <xsl:choose>
463<!-- special cases (no DESTDIR) here -->
464 <xsl:when test="ancestor::sect1[@id='ch-system-glibc']">
465 <xsl:text>make install_root=$PKG_DEST -j1</xsl:text>
466 <xsl:value-of
467 select="substring-before(substring-after(string(),'make'),
468 'install')"/>
469 <xsl:text>install&#xA;</xsl:text>
470 </xsl:when>
471 <xsl:when test="ancestor::sect1[@id='ch-system-bzip2']">
472 <xsl:text>make PREFIX=$PKG_DEST/usr install&#xA;</xsl:text>
473 </xsl:when>
474 <xsl:when test="ancestor::sect1[@id='ch-system-sysklogd']">
475 <xsl:text>make BINDIR=$PKG_DEST/sbin prefix=$PKG_DEST install&#xA;</xsl:text>
476 </xsl:when>
477 <xsl:when test="ancestor::sect1[@id='ch-system-iproute2']">
478 <xsl:text>make DESTDIR=$PKG_DEST</xsl:text>
479 <xsl:value-of
480 select="substring-before(substring-after(string(),'DESTDIR='),
481 'install')"/>
482 <xsl:text>install&#xA;</xsl:text>
483 </xsl:when>
484 <xsl:when test="ancestor::sect1[@id='ch-system-sysvinit']">
485 <xsl:text>make ROOT=$PKG_DEST</xsl:text>
486 <xsl:value-of
487 select="substring-before(substring-after(string(),'make'),
488 'install')"/>
489 <xsl:text>install&#xA;</xsl:text>
490 </xsl:when>
491 <xsl:when test="ancestor::sect1[@id='ch-bootable-kernel']">
492 <xsl:text>make INSTALL_MOD_PATH=$PKG_DEST</xsl:text>
493 <xsl:value-of
494 select="substring-before(substring-after(string(),'make'),
495 'install')"/>
496 <xsl:text>install&#xA;</xsl:text>
497 </xsl:when>
498 <xsl:otherwise>
499 <xsl:text>make DESTDIR=$PKG_DEST</xsl:text>
500 <xsl:call-template name="outputpkgdest">
501 <xsl:with-param
502 name="outputstring"
503 select="substring-after($outputstring,'make')"/>
504 </xsl:call-template>
505 </xsl:otherwise>
506 </xsl:choose>
507 </xsl:otherwise>
508 </xsl:choose>
509 </xsl:when>
510 <xsl:otherwise> <!-- no make in this string -->
511 <xsl:choose>
512 <xsl:when test="contains($outputstring,'&gt;/') and
513 not(contains(substring-before($outputstring,'&gt;/'),' /'))">
514 <xsl:value-of select="substring-before($outputstring,'&gt;/')"/>
515 <xsl:text>&gt;$PKG_DEST/</xsl:text>
516 <xsl:call-template name="outputpkgdest">
517 <xsl:with-param name="outputstring" select="substring-after($outputstring,'&gt;/')"/>
518 </xsl:call-template>
519 </xsl:when>
520 <xsl:when test="contains($outputstring,' /')">
521 <xsl:value-of select="substring-before($outputstring,' /')"/>
522 <xsl:text> $PKG_DEST/</xsl:text>
523 <xsl:call-template name="outputpkgdest">
524 <xsl:with-param name="outputstring" select="substring-after($outputstring,' /')"/>
525 </xsl:call-template>
526 </xsl:when>
527 <xsl:otherwise>
528 <xsl:value-of select="$outputstring"/>
529 <xsl:text>&#xA;</xsl:text>
530 </xsl:otherwise>
531 </xsl:choose>
532 </xsl:otherwise>
533 </xsl:choose>
534 </xsl:template>
535</xsl:stylesheet>
Note: See TracBrowser for help on using the repository browser.