source: LFS/lfs.xsl@ 936efa8

2.3 2.3.x 2.4 ablfs ablfs-more legacy new_features trunk
Last change on this file since 936efa8 was 14eaa9f, checked in by Manuel Canales Esparcia <manuel@…>, 18 years ago

LFS changes:
Skip creation of chapters 4 and 9 scripts.
Creating /etc/lfs-release as part af all target.
Removed hardcoded script number.
  • Property mode set to 100644
File size: 10.7 KB
Line 
1<?xml version="1.0"?>
2<!DOCTYPE xsl:stylesheet [
3 <!ENTITY % general-entities SYSTEM "FAKEDIR/general.ent">
4 %general-entities;
5]>
6
7<!-- $Id$ -->
8
9<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
10 xmlns:exsl="http://exslt.org/common"
11 extension-element-prefixes="exsl"
12 version="1.0">
13
14<!-- XSLT stylesheet to create shell scripts from LFS books. -->
15
16 <!-- Run test suites?
17 0 = none
18 1 = only chapter06 Glibc, GCC and Binutils testsuites
19 2 = all chapter06 testsuites
20 3 = all chapter05 and chapter06 testsuites
21 -->
22 <xsl:param name="testsuite" select="1"/>
23
24 <!-- Bomb on test suites failures?
25 n = no, I want to build the full system and review the logs
26 y = yes, bomb at the first test suite failure to can review the build dir
27 -->
28 <xsl:param name="bomb-testsuite" select="n"/>
29
30 <!-- Install vim-lang package? -->
31 <xsl:param name="vim-lang" select="y"/>
32
33 <!-- Time zone -->
34 <xsl:param name="timezone" select="GMT"/>
35
36 <!-- Page size -->
37 <xsl:param name="page" select="letter"/>
38
39 <!-- Locale settings -->
40 <xsl:param name="lang" select="C"/>
41
42 <xsl:template match="/">
43 <xsl:apply-templates select="//sect1"/>
44 </xsl:template>
45
46 <xsl:template match="sect1">
47 <xsl:if test="(../@id='chapter-temporary-tools' or
48 ../@id='chapter-building-system' or
49 ../@id='chapter-bootscripts' or
50 ../@id='chapter-bootable') and
51 count(descendant::screen/userinput) &gt; 0 and
52 count(descendant::screen/userinput) &gt;
53 count(descendant::screen[@role='nodump'])">
54 <!-- The dirs names -->
55 <xsl:variable name="pi-dir" select="../processing-instruction('dbhtml')"/>
56 <xsl:variable name="pi-dir-value" select="substring-after($pi-dir,'dir=')"/>
57 <xsl:variable name="quote-dir" select="substring($pi-dir-value,1,1)"/>
58 <xsl:variable name="dirname" select="substring-before(substring($pi-dir-value,2),$quote-dir)"/>
59 <!-- The file names -->
60 <xsl:variable name="pi-file" select="processing-instruction('dbhtml')"/>
61 <xsl:variable name="pi-file-value" select="substring-after($pi-file,'filename=')"/>
62 <xsl:variable name="filename" select="substring-before(substring($pi-file-value,2),'.html')"/>
63 <!-- The build order -->
64 <xsl:variable name="position" select="position()"/>
65 <xsl:variable name="order">
66 <xsl:choose>
67 <xsl:when test="string-length($position) = 1">
68 <xsl:text>00</xsl:text>
69 <xsl:value-of select="$position"/>
70 </xsl:when>
71 <xsl:when test="string-length($position) = 2">
72 <xsl:text>0</xsl:text>
73 <xsl:value-of select="$position"/>
74 </xsl:when>
75 <xsl:otherwise>
76 <xsl:value-of select="$position"/>
77 </xsl:otherwise>
78 </xsl:choose>
79 </xsl:variable>
80 <!-- Creating dirs and files -->
81 <exsl:document href="{$dirname}/{$order}-{$filename}" method="text">
82 <xsl:text>#!/bin/bash&#xA;set +h&#xA;</xsl:text>
83 <xsl:if test="not(@id='ch-tools-stripping') and
84 not(@id='ch-system-strippingagain')">
85 <xsl:text>set -e&#xA;</xsl:text>
86 </xsl:if>
87 <xsl:text>&#xA;</xsl:text>
88 <xsl:if test="sect2[@role='installation']">
89 <xsl:text>cd $PKGDIR&#xA;</xsl:text>
90 <xsl:if test="@id='ch-system-vim' and $vim-lang = 'y'">
91 <xsl:text>tar -xvf ../vim-&vim-version;-lang.* --strip-components=1&#xA;</xsl:text>
92 </xsl:if>
93 </xsl:if>
94 <xsl:apply-templates select=".//para/userinput | .//screen"/>
95 <xsl:if test="$testsuite='3' and @id='ch-tools-glibc'">
96 <xsl:copy-of select="//sect1[@id='ch-system-glibc']/sect2[2]/screen[@role='nodump']"/>
97 <xsl:text>&#xA;</xsl:text>
98 </xsl:if>
99 <xsl:text>exit</xsl:text>
100 </exsl:document>
101 </xsl:if>
102 </xsl:template>
103
104 <xsl:template match="screen">
105 <xsl:if test="child::* = userinput and not(@role = 'nodump')">
106 <xsl:apply-templates select="userinput" mode="screen"/>
107 </xsl:if>
108 </xsl:template>
109
110 <xsl:template match="para/userinput">
111 <xsl:if test="(contains(string(),'test') or
112 contains(string(),'check')) and
113 (($testsuite = '2' and
114 ancestor::chapter[@id='chapter-building-system']) or
115 $testsuite = '3')">
116 <xsl:choose>
117 <xsl:when test="$bomb-testsuite = 'n'">
118 <xsl:value-of select="substring-before(string(),'make')"/>
119 <xsl:text>make -k</xsl:text>
120 <xsl:value-of select="substring-after(string(),'make')"/>
121 <xsl:text> &gt;&gt; $TEST_LOG 2&gt;&amp;1 || true&#xA;</xsl:text>
122 </xsl:when>
123 <xsl:otherwise>
124 <xsl:apply-templates/>
125 <xsl:text> &gt;&gt; $TEST_LOG 2&gt;&amp;1</xsl:text>
126 <xsl:if test="contains(string(),' -k ')">
127 <xsl:text> || true</xsl:text>
128 </xsl:if>
129 <xsl:text>&#xA;</xsl:text>
130 </xsl:otherwise>
131 </xsl:choose>
132 </xsl:if>
133 </xsl:template>
134
135 <xsl:template match="userinput" mode="screen">
136 <xsl:choose>
137 <!-- Estandarized package formats -->
138 <xsl:when test="contains(string(),'tar.gz')">
139 <xsl:value-of select="substring-before(string(),'tar.gz')"/>
140 <xsl:text>tar.*</xsl:text>
141 <xsl:value-of select="substring-after(string(),'tar.gz')"/>
142 <xsl:text>&#xA;</xsl:text>
143 </xsl:when>
144 <!-- Avoiding a race condition in a patch -->
145 <xsl:when test="contains(string(),'debian_fixes')">
146 <xsl:value-of select="substring-before(string(),'patch')"/>
147 <xsl:text>patch -Z</xsl:text>
148 <xsl:value-of select="substring-after(string(),'patch')"/>
149 <xsl:text>&#xA;</xsl:text>
150 </xsl:when>
151 <!-- Fix Udev reinstallation after a build failure -->
152 <xsl:when test="contains(string(),'firmware,udev')">
153 <xsl:text>if [[ ! -d /lib/udev/devices ]] ; then&#xA;</xsl:text>
154 <xsl:apply-templates/>
155 <xsl:text>&#xA;fi&#xA;</xsl:text>
156 </xsl:when>
157 <!-- Setting $LANG for /etc/profile -->
158 <xsl:when test="ancestor::sect1[@id='ch-scripts-profile'] and
159 contains(string(),'export LANG=')">
160 <xsl:value-of select="substring-before(string(),'export LANG=')"/>
161 <xsl:text>export LANG=</xsl:text>
162 <xsl:value-of select="$lang"/>
163 <xsl:value-of select="substring-after(string(),'modifiers>')"/>
164 <xsl:text>&#xA;</xsl:text>
165 </xsl:when>
166 <!-- Copying the kernel config file -->
167 <xsl:when test="string() = 'make mrproper'">
168 <xsl:text>make mrproper&#xA;</xsl:text>
169 <xsl:text>cp -v ../kernel-config .config&#xA;</xsl:text>
170 </xsl:when>
171 <!-- The Coreutils and Module-Init-Tools test suites are optional -->
172 <xsl:when test="(ancestor::sect1[@id='ch-system-coreutils'] or
173 ancestor::sect1[@id='ch-system-module-init-tools']) and
174 (contains(string(),'check') or
175 contains(string(),'dummy'))">
176 <xsl:choose>
177 <xsl:when test="$testsuite = '0' or $testsuite = '1'"/>
178 <xsl:otherwise>
179 <xsl:if test="not(contains(string(),'check'))">
180 <xsl:apply-templates/>
181 <xsl:text>&#xA;</xsl:text>
182 </xsl:if>
183 <xsl:if test="contains(string(),'check')">
184 <xsl:choose>
185 <xsl:when test="$bomb-testsuite = 'n'">
186 <xsl:value-of select="substring-before(string(),'check')"/>
187 <xsl:text>-k check</xsl:text>
188 <xsl:value-of select="substring-after(string(),'check')"/>
189 <xsl:text> &gt;&gt; $TEST_LOG 2&gt;&amp;1 || true&#xA;</xsl:text>
190 </xsl:when>
191 <xsl:otherwise>
192 <xsl:apply-templates/>
193 <xsl:text> &gt;&gt; $TEST_LOG 2&gt;&amp;1</xsl:text>
194 <xsl:if test="contains(string(),' -k ')">
195 <xsl:text> || true</xsl:text>
196 </xsl:if>
197 <xsl:text>&#xA;</xsl:text>
198 </xsl:otherwise>
199 </xsl:choose>
200 </xsl:if>
201 </xsl:otherwise>
202 </xsl:choose>
203 </xsl:when>
204 <!-- Fixing toolchain test suites run -->
205 <xsl:when test="string() = 'make check' or
206 string() = 'make -k check'">
207 <xsl:choose>
208 <xsl:when test="(($testsuite = '1' or $testsuite = '2') and
209 ancestor::chapter[@id='chapter-building-system']) or
210 $testsuite = '3'">
211 <xsl:choose>
212 <xsl:when test="$bomb-testsuite = 'n'">
213 <xsl:text>make -k check &gt;&gt; $TEST_LOG 2&gt;&amp;1 || true&#xA;</xsl:text>
214 </xsl:when>
215 <xsl:otherwise>
216 <xsl:apply-templates/>
217 <xsl:text> &gt;&gt; $TEST_LOG 2&gt;&amp;1</xsl:text>
218 <xsl:if test="contains(string(),' -k ')">
219 <xsl:text> || true</xsl:text>
220 </xsl:if>
221 <xsl:text>&#xA;</xsl:text>
222 </xsl:otherwise>
223 </xsl:choose>
224 </xsl:when>
225 </xsl:choose>
226 </xsl:when>
227 <xsl:when test="contains(string(),'glibc-check-log')">
228 <xsl:choose>
229 <xsl:when test="$testsuite != '0'">
230 <xsl:value-of select="substring-before(string(),'2&gt;&amp;1')"/>
231 <xsl:text>&gt;&gt; $TEST_LOG 2&gt;&amp;1 || true&#xA;</xsl:text>
232 </xsl:when>
233 </xsl:choose>
234 </xsl:when>
235 <xsl:when test="contains(string(),'test_summary') or
236 contains(string(),'expect -c')">
237 <xsl:choose>
238 <xsl:when test="(($testsuite = '1' or $testsuite = '2') and
239 ancestor::chapter[@id='chapter-building-system']) or
240 $testsuite = '3'">
241 <xsl:apply-templates/>
242 <xsl:text> &gt;&gt; $TEST_LOG&#xA;</xsl:text>
243 </xsl:when>
244 </xsl:choose>
245 </xsl:when>
246 <!-- Don't stop on strip run -->
247 <xsl:when test="contains(string(),'strip ')">
248 <xsl:apply-templates/>
249 <xsl:text> || true&#xA;</xsl:text>
250 </xsl:when>
251 <!-- The rest of commands -->
252 <xsl:otherwise>
253 <xsl:apply-templates/>
254 <xsl:text>&#xA;</xsl:text>
255 </xsl:otherwise>
256 </xsl:choose>
257 </xsl:template>
258
259 <xsl:template match="replaceable">
260 <xsl:choose>
261 <xsl:when test="ancestor::sect1[@id='ch-system-glibc']">
262 <xsl:value-of select="$timezone"/>
263 </xsl:when>
264 <xsl:when test="ancestor::sect1[@id='ch-system-groff']">
265 <xsl:value-of select="$page"/>
266 </xsl:when>
267 <xsl:otherwise>
268 <xsl:text>**EDITME</xsl:text>
269 <xsl:apply-templates/>
270 <xsl:text>EDITME**</xsl:text>
271 </xsl:otherwise>
272 </xsl:choose>
273 </xsl:template>
274
275</xsl:stylesheet>
Note: See TracBrowser for help on using the repository browser.