source: LFS/lfs.xsl@ 9b09518

2.3 2.3.x 2.4 ablfs ablfs-more legacy new_features trunk
Last change on this file since 9b09518 was ccc7c2b, checked in by Manuel Canales Esparcia <manuel@…>, 18 years ago

Fixed Udev script re-run after a build failure in LFS.
  • Property mode set to 100644
File size: 9.0 KB
Line 
1<?xml version="1.0"?>
2<!DOCTYPE xsl:stylesheet [
3 <!ENTITY % general-entities SYSTEM "FAKEDIR/general.ent">
4 %general-entities;
5]>
6
7<!-- $Id$ -->
8
9<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
10 xmlns:exsl="http://exslt.org/common"
11 extension-element-prefixes="exsl"
12 version="1.0">
13
14<!-- XSLT stylesheet to create shell scripts from LFS books. -->
15
16 <!-- Run test suites?
17 0 = none
18 1 = only chapter06 Glibc, GCC and Binutils testsuites
19 2 = all chapter06 testsuites
20 3 = all chapter05 and chapter06 testsuites-->
21 <xsl:param name="testsuite" select="1"/>
22
23 <!-- Install vim-lang package? -->
24 <xsl:param name="vim-lang" select="1"/>
25
26 <!-- Time zone -->
27 <xsl:param name="timezone" select="GMT"/>
28
29 <!-- Page size -->
30 <xsl:param name="page" select="letter"/>
31
32 <!-- Locale settings -->
33 <xsl:param name="lang" select="C"/>
34
35 <xsl:template match="/">
36 <xsl:apply-templates select="//sect1"/>
37 </xsl:template>
38
39 <xsl:template match="sect1">
40 <xsl:if test="count(descendant::screen/userinput) &gt; 0 and
41 count(descendant::screen/userinput) &gt; count(descendant::screen[@role='nodump'])">
42 <!-- The dirs names -->
43 <xsl:variable name="pi-dir" select="../processing-instruction('dbhtml')"/>
44 <xsl:variable name="pi-dir-value" select="substring-after($pi-dir,'dir=')"/>
45 <xsl:variable name="quote-dir" select="substring($pi-dir-value,1,1)"/>
46 <xsl:variable name="dirname" select="substring-before(substring($pi-dir-value,2),$quote-dir)"/>
47 <!-- The file names -->
48 <xsl:variable name="pi-file" select="processing-instruction('dbhtml')"/>
49 <xsl:variable name="pi-file-value" select="substring-after($pi-file,'filename=')"/>
50 <xsl:variable name="filename" select="substring-before(substring($pi-file-value,2),'.html')"/>
51 <!-- The build order -->
52 <xsl:variable name="position" select="position()"/>
53 <xsl:variable name="order">
54 <xsl:choose>
55 <xsl:when test="string-length($position) = 1">
56 <xsl:text>00</xsl:text>
57 <xsl:value-of select="$position"/>
58 </xsl:when>
59 <xsl:when test="string-length($position) = 2">
60 <xsl:text>0</xsl:text>
61 <xsl:value-of select="$position"/>
62 </xsl:when>
63 <xsl:otherwise>
64 <xsl:value-of select="$position"/>
65 </xsl:otherwise>
66 </xsl:choose>
67 </xsl:variable>
68 <!-- Creating dirs and files -->
69 <exsl:document href="{$dirname}/{$order}-{$filename}" method="text">
70 <xsl:choose>
71 <xsl:when test="@id='ch-system-changingowner' or
72 @id='ch-system-creatingdirs' or
73 @id='ch-system-createfiles'">
74 <xsl:text>#!/tools/bin/bash&#xA;set -e&#xA;&#xA;</xsl:text>
75 </xsl:when>
76 <xsl:when test="@id='ch-tools-stripping' or
77 @id='ch-system-strippingagain'">
78 <xsl:text>#!/bin/sh&#xA;</xsl:text>
79 </xsl:when>
80 <xsl:otherwise>
81 <xsl:text>#!/bin/sh&#xA;set -e&#xA;&#xA;</xsl:text>
82 </xsl:otherwise>
83 </xsl:choose>
84 <xsl:if test="sect2[@role='installation']">
85 <xsl:text>cd $PKGDIR&#xA;</xsl:text>
86 <xsl:if test="@id='ch-system-vim' and $vim-lang = '1'">
87 <xsl:text>tar -xvf ../vim-&vim-version;-lang.* --strip-components=1&#xA;</xsl:text>
88 </xsl:if>
89 </xsl:if>
90 <xsl:apply-templates select=".//para/userinput | .//screen"/>
91 <xsl:if test="$testsuite='3' and @id='ch-tools-glibc'">
92 <xsl:copy-of select="//sect1[@id='ch-system-glibc']/sect2[2]/screen[@role='nodump']"/>
93 <xsl:text>&#xA;</xsl:text>
94 </xsl:if>
95 <xsl:text>exit</xsl:text>
96 </exsl:document>
97 </xsl:if>
98 </xsl:template>
99
100 <xsl:template match="screen">
101 <xsl:if test="child::* = userinput and not(@role = 'nodump')">
102 <xsl:apply-templates select="userinput" mode="screen"/>
103 </xsl:if>
104 </xsl:template>
105
106 <xsl:template match="para/userinput">
107 <xsl:if test="(contains(string(),'test') or
108 contains(string(),'check')) and
109 (($testsuite = '2' and
110 ancestor::chapter[@id='chapter-building-system']) or
111 $testsuite = '3')">
112 <xsl:value-of select="substring-before(string(),'make')"/>
113 <xsl:text>make -k</xsl:text>
114 <xsl:value-of select="substring-after(string(),'make')"/>
115 <xsl:text> &gt;&gt; $TEST_LOG 2&gt;&amp;1 || true&#xA;</xsl:text>
116 </xsl:if>
117 </xsl:template>
118
119 <xsl:template match="userinput" mode="screen">
120 <xsl:choose>
121 <!-- Estandarized package formats -->
122 <xsl:when test="contains(string(),'tar.gz')">
123 <xsl:value-of select="substring-before(string(),'tar.gz')"/>
124 <xsl:text>tar.*</xsl:text>
125 <xsl:value-of select="substring-after(string(),'tar.gz')"/>
126 <xsl:text>&#xA;</xsl:text>
127 </xsl:when>
128 <!-- Avoiding a race condition in a patch -->
129 <xsl:when test="contains(string(),'debian_fixes')">
130 <xsl:value-of select="substring-before(string(),'patch')"/>
131 <xsl:text>patch -Z</xsl:text>
132 <xsl:value-of select="substring-after(string(),'patch')"/>
133 <xsl:text>&#xA;</xsl:text>
134 </xsl:when>
135 <!-- Fix Udev reinstallation after a build failure -->
136 <xsl:when test="contains(string(),'firmware,udev')">
137 <xsl:text>if [[ ! -d /lib/udev/devices ]] ; then&#xA;</xsl:text>
138 <xsl:apply-templates/>
139 <xsl:text>&#xA;fi&#xA;</xsl:text>
140 </xsl:when>
141 <!-- Setting $LANG for /etc/profile -->
142 <xsl:when test="ancestor::sect1[@id='ch-scripts-profile'] and
143 contains(string(),'export LANG=')">
144 <xsl:value-of select="substring-before(string(),'export LANG=')"/>
145 <xsl:text>export LANG=</xsl:text>
146 <xsl:value-of select="$lang"/>
147 <xsl:value-of select="substring-after(string(),'modifiers>')"/>
148 <xsl:text>&#xA;</xsl:text>
149 </xsl:when>
150 <!-- Copying the kernel config file -->
151 <xsl:when test="string() = 'make mrproper'">
152 <xsl:text>make mrproper&#xA;</xsl:text>
153 <xsl:text>cp -v ../kernel-config .config&#xA;</xsl:text>
154 </xsl:when>
155 <!-- The Coreutils and Module-Init-Tools test suites are optional -->
156 <xsl:when test="(ancestor::sect1[@id='ch-system-coreutils'] or
157 ancestor::sect1[@id='ch-system-module-init-tools']) and
158 (contains(string(),'check') or
159 contains(string(),'dummy'))">
160 <xsl:choose>
161 <xsl:when test="$testsuite = '0' or $testsuite = '1'"/>
162 <xsl:otherwise>
163 <xsl:apply-templates/>
164 <xsl:if test="contains(string(),'check')">
165 <xsl:text> &gt;&gt; $TEST_LOG 2&gt;&amp;1 || true</xsl:text>
166 </xsl:if>
167 <xsl:text>&#xA;</xsl:text>
168 </xsl:otherwise>
169 </xsl:choose>
170 </xsl:when>
171 <!-- Fixing toolchain test suites run -->
172 <xsl:when test="string() = 'make check' or
173 string() = 'make -k check'">
174 <xsl:choose>
175 <xsl:when test="(($testsuite = '1' or $testsuite = '2') and
176 ancestor::chapter[@id='chapter-building-system']) or
177 $testsuite = '3'">
178 <xsl:text>make -k check &gt;&gt; $TEST_LOG 2&gt;&amp;1 || true&#xA;</xsl:text>
179 </xsl:when>
180 </xsl:choose>
181 </xsl:when>
182 <xsl:when test="contains(string(),'glibc-check-log')">
183 <xsl:choose>
184 <xsl:when test="$testsuite != '0'">
185 <xsl:value-of select="substring-before(string(),'2&gt;&amp;1')"/>
186 <xsl:text>&gt;&gt; $TEST_LOG 2&gt;&amp;1 || true&#xA;</xsl:text>
187 </xsl:when>
188 </xsl:choose>
189 </xsl:when>
190 <xsl:when test="contains(string(),'test_summary') or
191 contains(string(),'expect -c')">
192 <xsl:choose>
193 <xsl:when test="(($testsuite = '1' or $testsuite = '2') and
194 ancestor::chapter[@id='chapter-building-system']) or
195 $testsuite = '3'">
196 <xsl:apply-templates/>
197 <xsl:if test="contains(string(),'test_summary')">
198 <xsl:text> &gt;&gt; $TEST_LOG</xsl:text>
199 </xsl:if>
200 <xsl:text>&#xA;</xsl:text>
201 </xsl:when>
202 </xsl:choose>
203 </xsl:when>
204 <!-- Don't stop on strip run -->
205 <xsl:when test="contains(string(),'strip ')">
206 <xsl:apply-templates/>
207 <xsl:text> || true&#xA;</xsl:text>
208 </xsl:when>
209 <!-- The rest of commands -->
210 <xsl:otherwise>
211 <xsl:apply-templates/>
212 <xsl:text>&#xA;</xsl:text>
213 </xsl:otherwise>
214 </xsl:choose>
215 </xsl:template>
216
217 <xsl:template match="replaceable">
218 <xsl:choose>
219 <xsl:when test="ancestor::sect1[@id='ch-system-glibc']">
220 <xsl:value-of select="$timezone"/>
221 </xsl:when>
222 <xsl:when test="ancestor::sect1[@id='ch-system-groff']">
223 <xsl:value-of select="$page"/>
224 </xsl:when>
225 <xsl:otherwise>
226 <xsl:text>**EDITME</xsl:text>
227 <xsl:apply-templates/>
228 <xsl:text>EDITME**</xsl:text>
229 </xsl:otherwise>
230 </xsl:choose>
231 </xsl:template>
232
233</xsl:stylesheet>
Note: See TracBrowser for help on using the repository browser.