source: LFS/lfs.xsl@ fc8b962

2.3 2.3.x 2.4 ablfs ablfs-more legacy new_features trunk
Last change on this file since fc8b962 was 49d4af4, checked in by Manuel Canales Esparcia <manuel@…>, 18 years ago

LFS: Fixed Bash testsuite run.
  • Property mode set to 100644
File size: 12.2 KB
Line 
1<?xml version="1.0"?>
2<!DOCTYPE xsl:stylesheet [
3 <!ENTITY % general-entities SYSTEM "FAKEDIR/general.ent">
4 %general-entities;
5]>
6
7<!-- $Id$ -->
8
9<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
10 xmlns:exsl="http://exslt.org/common"
11 extension-element-prefixes="exsl"
12 version="1.0">
13
14<!-- XSLT stylesheet to create shell scripts from LFS books. -->
15
16 <!-- Run test suites?
17 0 = none
18 1 = only chapter06 Glibc, GCC and Binutils testsuites
19 2 = all chapter06 testsuites
20 3 = all chapter05 and chapter06 testsuites
21 -->
22 <xsl:param name="testsuite" select="1"/>
23
24 <!-- Bomb on test suites failures?
25 n = no, I want to build the full system and review the logs
26 y = yes, bomb at the first test suite failure to can review the build dir
27 -->
28 <xsl:param name="bomb-testsuite" select="n"/>
29
30 <!-- Install vim-lang package? -->
31 <xsl:param name="vim-lang" select="y"/>
32
33 <!-- Time zone -->
34 <xsl:param name="timezone" select="GMT"/>
35
36 <!-- Page size -->
37 <xsl:param name="page" select="letter"/>
38
39 <!-- Locale settings -->
40 <xsl:param name="lang" select="C"/>
41
42 <xsl:template match="/">
43 <xsl:apply-templates select="//sect1"/>
44 </xsl:template>
45
46 <xsl:template match="sect1">
47 <xsl:if test="(../@id='chapter-temporary-tools' or
48 ../@id='chapter-building-system' or
49 ../@id='chapter-bootscripts' or
50 ../@id='chapter-bootable') and
51 count(descendant::screen/userinput) &gt; 0 and
52 count(descendant::screen/userinput) &gt;
53 count(descendant::screen[@role='nodump'])">
54 <!-- The dirs names -->
55 <xsl:variable name="pi-dir" select="../processing-instruction('dbhtml')"/>
56 <xsl:variable name="pi-dir-value" select="substring-after($pi-dir,'dir=')"/>
57 <xsl:variable name="quote-dir" select="substring($pi-dir-value,1,1)"/>
58 <xsl:variable name="dirname" select="substring-before(substring($pi-dir-value,2),$quote-dir)"/>
59 <!-- The file names -->
60 <xsl:variable name="pi-file" select="processing-instruction('dbhtml')"/>
61 <xsl:variable name="pi-file-value" select="substring-after($pi-file,'filename=')"/>
62 <xsl:variable name="filename" select="substring-before(substring($pi-file-value,2),'.html')"/>
63 <!-- The build order -->
64 <xsl:variable name="position" select="position()"/>
65 <xsl:variable name="order">
66 <xsl:choose>
67 <xsl:when test="string-length($position) = 1">
68 <xsl:text>00</xsl:text>
69 <xsl:value-of select="$position"/>
70 </xsl:when>
71 <xsl:when test="string-length($position) = 2">
72 <xsl:text>0</xsl:text>
73 <xsl:value-of select="$position"/>
74 </xsl:when>
75 <xsl:otherwise>
76 <xsl:value-of select="$position"/>
77 </xsl:otherwise>
78 </xsl:choose>
79 </xsl:variable>
80 <!-- Creating dirs and files -->
81 <exsl:document href="{$dirname}/{$order}-{$filename}" method="text">
82 <xsl:choose>
83 <xsl:when test="@id='ch-system-creatingdirs' or
84 @id='ch-system-createfiles' or
85 @id='ch-system-strippingagain'">
86 <xsl:text>#!/tools/bin/bash&#xA;set +h&#xA;</xsl:text>
87 </xsl:when>
88 <xsl:otherwise>
89 <xsl:text>#!/bin/bash&#xA;set +h&#xA;</xsl:text>
90 </xsl:otherwise>
91 </xsl:choose>
92 <xsl:if test="not(@id='ch-tools-stripping') and
93 not(@id='ch-system-strippingagain')">
94 <xsl:text>set -e&#xA;</xsl:text>
95 </xsl:if>
96 <xsl:text>&#xA;</xsl:text>
97 <xsl:if test="sect2[@role='installation']">
98 <xsl:text>cd $PKGDIR&#xA;</xsl:text>
99 <xsl:if test="@id='ch-system-vim' and $vim-lang = 'y'">
100 <xsl:text>tar -xvf ../vim-&vim-version;-lang.* --strip-components=1&#xA;</xsl:text>
101 </xsl:if>
102 </xsl:if>
103 <xsl:apply-templates select=".//para/userinput | .//screen"/>
104 <xsl:if test="$testsuite='3' and @id='ch-tools-glibc'">
105 <xsl:copy-of select="//sect1[@id='ch-system-glibc']/sect2[2]/screen[@role='nodump']"/>
106 <xsl:text>&#xA;</xsl:text>
107 </xsl:if>
108 <xsl:text>exit</xsl:text>
109 </exsl:document>
110 </xsl:if>
111 </xsl:template>
112
113 <xsl:template match="screen">
114 <xsl:if test="child::* = userinput and not(@role = 'nodump')">
115 <xsl:apply-templates select="userinput" mode="screen"/>
116 </xsl:if>
117 </xsl:template>
118
119 <xsl:template match="para/userinput">
120 <xsl:if test="(contains(string(),'test') or
121 contains(string(),'check')) and
122 (($testsuite = '2' and
123 ancestor::chapter[@id='chapter-building-system']) or
124 $testsuite = '3')">
125 <xsl:choose>
126 <xsl:when test="$bomb-testsuite = 'n'">
127 <xsl:value-of select="substring-before(string(),'make')"/>
128 <xsl:text>make -k</xsl:text>
129 <xsl:value-of select="substring-after(string(),'make')"/>
130 <xsl:text> &gt;&gt; $TEST_LOG 2&gt;&amp;1 || true&#xA;</xsl:text>
131 </xsl:when>
132 <xsl:otherwise>
133 <xsl:apply-templates/>
134 <xsl:text> &gt;&gt; $TEST_LOG 2&gt;&amp;1</xsl:text>
135 <xsl:if test="contains(string(),' -k ')">
136 <xsl:text> || true</xsl:text>
137 </xsl:if>
138 <xsl:text>&#xA;</xsl:text>
139 </xsl:otherwise>
140 </xsl:choose>
141 </xsl:if>
142 </xsl:template>
143
144 <xsl:template match="userinput" mode="screen">
145 <xsl:choose>
146 <!-- Estandarized package formats -->
147 <xsl:when test="contains(string(),'tar.gz')">
148 <xsl:value-of select="substring-before(string(),'tar.gz')"/>
149 <xsl:text>tar.*</xsl:text>
150 <xsl:value-of select="substring-after(string(),'tar.gz')"/>
151 <xsl:text>&#xA;</xsl:text>
152 </xsl:when>
153 <!-- Avoiding a race condition in a patch -->
154 <xsl:when test="contains(string(),'debian_fixes')">
155 <xsl:value-of select="substring-before(string(),'patch')"/>
156 <xsl:text>patch -Z</xsl:text>
157 <xsl:value-of select="substring-after(string(),'patch')"/>
158 <xsl:text>&#xA;</xsl:text>
159 </xsl:when>
160 <!-- Fix Udev reinstallation after a build failure -->
161 <xsl:when test="contains(string(),'firmware,udev')">
162 <xsl:text>if [[ ! -d /lib/udev/devices ]] ; then&#xA;</xsl:text>
163 <xsl:apply-templates/>
164 <xsl:text>&#xA;fi&#xA;</xsl:text>
165 </xsl:when>
166 <!-- Setting $LANG for /etc/profile -->
167 <xsl:when test="ancestor::sect1[@id='ch-scripts-profile'] and
168 contains(string(),'export LANG=')">
169 <xsl:value-of select="substring-before(string(),'export LANG=')"/>
170 <xsl:text>export LANG=</xsl:text>
171 <xsl:value-of select="$lang"/>
172 <xsl:value-of select="substring-after(string(),'modifiers>')"/>
173 <xsl:text>&#xA;</xsl:text>
174 </xsl:when>
175 <!-- Copying the kernel config file -->
176 <xsl:when test="string() = 'make mrproper'">
177 <xsl:text>make mrproper&#xA;</xsl:text>
178 <xsl:text>cp -v ../kernel-config .config&#xA;</xsl:text>
179 </xsl:when>
180 <!-- The Bash, Coreutils, and Module-Init-Tools test suites are optional -->
181 <xsl:when test="(ancestor::sect1[@id='ch-system-coreutils'] or
182 ancestor::sect1[@id='ch-system-bash'] or
183 ancestor::sect1[@id='ch-system-module-init-tools']) and
184 (contains(string(),'check') or contains(string(),'nobody')
185 or contains(string(),'dummy'))">
186 <xsl:choose>
187 <xsl:when test="$testsuite = '0' or $testsuite = '1'"/>
188 <xsl:otherwise>
189 <xsl:if test="not(contains(string(),'check')) and
190 not(contains(string(),'tests'))">
191 <xsl:apply-templates/>
192 <xsl:text>&#xA;</xsl:text>
193 </xsl:if>
194 <!-- Coreutils and Module-Init-Tools -->
195 <xsl:if test="contains(string(),'check')">
196 <xsl:choose>
197 <xsl:when test="$bomb-testsuite = 'n'">
198 <xsl:value-of select="substring-before(string(),'check')"/>
199 <xsl:text>-k check</xsl:text>
200 <xsl:value-of select="substring-after(string(),'check')"/>
201 <xsl:text> &gt;&gt; $TEST_LOG 2&gt;&amp;1 || true&#xA;</xsl:text>
202 </xsl:when>
203 <xsl:otherwise>
204 <xsl:apply-templates/>
205 <xsl:text> &gt;&gt; $TEST_LOG 2&gt;&amp;1</xsl:text>
206 <xsl:if test="contains(string(),' -k ')">
207 <xsl:text> || true</xsl:text>
208 </xsl:if>
209 <xsl:text>&#xA;</xsl:text>
210 </xsl:otherwise>
211 </xsl:choose>
212 </xsl:if>
213 <!-- Bash -->
214 <xsl:if test="contains(string(),'tests')">
215 <xsl:choose>
216 <xsl:when test="$bomb-testsuite = 'n'">
217 <xsl:value-of select="substring-before(string(),'tests')"/>
218 <xsl:text>-k tests</xsl:text>
219 <xsl:value-of select="substring-after(string(),'tests')"/>
220 <xsl:text> &gt;&gt; $TEST_LOG 2&gt;&amp;1 || true&#xA;</xsl:text>
221 </xsl:when>
222 <xsl:otherwise>
223 <xsl:apply-templates/>
224 <xsl:text> &gt;&gt; $TEST_LOG 2&gt;&amp;1</xsl:text>
225 <xsl:if test="contains(string(),' -k ')">
226 <xsl:text> || true</xsl:text>
227 </xsl:if>
228 <xsl:text>&#xA;</xsl:text>
229 </xsl:otherwise>
230 </xsl:choose>
231 </xsl:if>
232 </xsl:otherwise>
233 </xsl:choose>
234 </xsl:when>
235 <!-- Fixing toolchain test suites run -->
236 <xsl:when test="string() = 'make check' or
237 string() = 'make -k check'">
238 <xsl:choose>
239 <xsl:when test="(($testsuite = '1' or $testsuite = '2') and
240 ancestor::chapter[@id='chapter-building-system']) or
241 $testsuite = '3'">
242 <xsl:choose>
243 <xsl:when test="$bomb-testsuite = 'n'">
244 <xsl:text>make -k check &gt;&gt; $TEST_LOG 2&gt;&amp;1 || true&#xA;</xsl:text>
245 </xsl:when>
246 <xsl:otherwise>
247 <xsl:apply-templates/>
248 <xsl:text> &gt;&gt; $TEST_LOG 2&gt;&amp;1</xsl:text>
249 <xsl:if test="contains(string(),' -k ')">
250 <xsl:text> || true</xsl:text>
251 </xsl:if>
252 <xsl:text>&#xA;</xsl:text>
253 </xsl:otherwise>
254 </xsl:choose>
255 </xsl:when>
256 </xsl:choose>
257 </xsl:when>
258 <xsl:when test="contains(string(),'glibc-check-log')">
259 <xsl:choose>
260 <xsl:when test="$testsuite != '0'">
261 <xsl:value-of select="substring-before(string(),'2&gt;&amp;1')"/>
262 <xsl:text>&gt;&gt; $TEST_LOG 2&gt;&amp;1 || true&#xA;</xsl:text>
263 </xsl:when>
264 </xsl:choose>
265 </xsl:when>
266 <xsl:when test="contains(string(),'test_summary') or
267 contains(string(),'expect -c')">
268 <xsl:choose>
269 <xsl:when test="(($testsuite = '1' or $testsuite = '2') and
270 ancestor::chapter[@id='chapter-building-system']) or
271 $testsuite = '3'">
272 <xsl:apply-templates/>
273 <xsl:text> &gt;&gt; $TEST_LOG&#xA;</xsl:text>
274 </xsl:when>
275 </xsl:choose>
276 </xsl:when>
277 <!-- Don't stop on strip run -->
278 <xsl:when test="contains(string(),'strip ')">
279 <xsl:apply-templates/>
280 <xsl:text> || true&#xA;</xsl:text>
281 </xsl:when>
282 <!-- The rest of commands -->
283 <xsl:otherwise>
284 <xsl:apply-templates/>
285 <xsl:text>&#xA;</xsl:text>
286 </xsl:otherwise>
287 </xsl:choose>
288 </xsl:template>
289
290 <xsl:template match="replaceable">
291 <xsl:choose>
292 <xsl:when test="ancestor::sect1[@id='ch-system-glibc']">
293 <xsl:value-of select="$timezone"/>
294 </xsl:when>
295 <xsl:when test="ancestor::sect1[@id='ch-system-groff']">
296 <xsl:value-of select="$page"/>
297 </xsl:when>
298 <xsl:otherwise>
299 <xsl:text>**EDITME</xsl:text>
300 <xsl:apply-templates/>
301 <xsl:text>EDITME**</xsl:text>
302 </xsl:otherwise>
303 </xsl:choose>
304 </xsl:template>
305
306</xsl:stylesheet>
Note: See TracBrowser for help on using the repository browser.