source: dump-lfs-scripts.xsl@ 0d52034

1.0 2.3 2.3.x 2.4 ablfs ablfs-more legacy new_features trunk
Last change on this file since 0d52034 was 0d52034, checked in by Manuel Canales Esparcia <manuel@…>, 19 years ago

No longer need to retain binutils source package. Finixed the fix started on r2292.
Updated TODO.
  • Property mode set to 100644
File size: 7.2 KB
Line 
1<?xml version="1.0"?>
2<!DOCTYPE xsl:stylesheet [
3 <!ENTITY % general-entities SYSTEM "FAKEDIR/general.ent">
4 %general-entities;
5]>
6
7<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
8 xmlns:exsl="http://exslt.org/common"
9 extension-element-prefixes="exsl"
10 version="1.0">
11
12<!-- XSLT stylesheet to create shell scripts from LFS books. -->
13
14 <!-- Run optional test suites? -->
15 <xsl:param name="testsuite" select="0"/>
16
17 <!-- Run toolchain test suites? -->
18 <xsl:param name="toolchaintest" select="1"/>
19
20 <!-- Install vim-lang package? -->
21 <xsl:param name="vim-lang" select="1"/>
22
23 <xsl:template match="/">
24 <xsl:apply-templates select="//sect1"/>
25 </xsl:template>
26
27 <xsl:template match="sect1">
28 <xsl:if test="count(descendant::screen/userinput) &gt; 0 and
29 count(descendant::screen/userinput) &gt; count(descendant::screen[@role='nodump'])">
30 <!-- The dirs names -->
31 <xsl:variable name="pi-dir" select="../processing-instruction('dbhtml')"/>
32 <xsl:variable name="pi-dir-value" select="substring-after($pi-dir,'dir=')"/>
33 <xsl:variable name="quote-dir" select="substring($pi-dir-value,1,1)"/>
34 <xsl:variable name="dirname" select="substring-before(substring($pi-dir-value,2),$quote-dir)"/>
35 <!-- The file names -->
36 <xsl:variable name="pi-file" select="processing-instruction('dbhtml')"/>
37 <xsl:variable name="pi-file-value" select="substring-after($pi-file,'filename=')"/>
38 <xsl:variable name="filename" select="substring-before(substring($pi-file-value,2),'.html')"/>
39 <!-- The build order -->
40 <xsl:variable name="position" select="position()"/>
41 <xsl:variable name="order">
42 <xsl:choose>
43 <xsl:when test="string-length($position) = 1">
44 <xsl:text>00</xsl:text>
45 <xsl:value-of select="$position"/>
46 </xsl:when>
47 <xsl:when test="string-length($position) = 2">
48 <xsl:text>0</xsl:text>
49 <xsl:value-of select="$position"/>
50 </xsl:when>
51 <xsl:otherwise>
52 <xsl:value-of select="$position"/>
53 </xsl:otherwise>
54 </xsl:choose>
55 </xsl:variable>
56 <!-- Creating dirs and files -->
57 <exsl:document href="{$dirname}/{$order}-{$filename}" method="text">
58 <xsl:choose>
59 <xsl:when test="@id='ch-system-changingowner' or
60 @id='ch-system-creatingdirs' or
61 @id='ch-system-createfiles'">
62 <xsl:text>#!/tools/bin/bash&#xA;set -e&#xA;&#xA;</xsl:text>
63 </xsl:when>
64 <xsl:when test="@id='ch-tools-stripping' or
65 @id='ch-system-strippingagain'">
66 <xsl:text>#!/bin/sh&#xA;</xsl:text>
67 </xsl:when>
68 <xsl:otherwise>
69 <xsl:text>#!/bin/sh&#xA;set -e&#xA;&#xA;</xsl:text>
70 </xsl:otherwise>
71 </xsl:choose>
72 <xsl:if test="sect2[@role='installation']">
73 <xsl:text>cd $PKGDIR&#xA;</xsl:text>
74 <xsl:if test="@id='ch-system-vim' and $vim-lang = '1'">
75 <xsl:text>tar -xvf ../vim-&vim-version;-lang.* --strip-components=1&#xA;</xsl:text>
76 </xsl:if>
77 </xsl:if>
78 <xsl:apply-templates select=".//para/userinput | .//screen"/>
79 <xsl:text>exit</xsl:text>
80 </exsl:document>
81 </xsl:if>
82 </xsl:template>
83
84 <xsl:template match="screen">
85 <xsl:if test="child::* = userinput">
86 <xsl:choose>
87 <xsl:when test="@role = 'nodump'"/>
88 <xsl:otherwise>
89 <xsl:apply-templates select="userinput" mode="screen"/>
90 </xsl:otherwise>
91 </xsl:choose>
92 </xsl:if>
93 </xsl:template>
94
95 <xsl:template match="para/userinput">
96 <xsl:if test="$testsuite != '0' and
97 (contains(string(),'test') or
98 contains(string(),'check'))">
99 <xsl:value-of select="substring-before(string(),'make')"/>
100 <xsl:text>make -k</xsl:text>
101 <xsl:value-of select="substring-after(string(),'make')"/>
102 <xsl:text> || true&#xA;</xsl:text>
103 </xsl:if>
104 </xsl:template>
105
106 <xsl:template match="userinput" mode="screen">
107 <xsl:choose>
108 <!-- Estandarized package formats -->
109 <xsl:when test="contains(string(),'tar.gz')">
110 <xsl:value-of select="substring-before(string(),'tar.gz')"/>
111 <xsl:text>tar.*</xsl:text>
112 <xsl:value-of select="substring-after(string(),'tar.gz')"/>
113 <xsl:text>&#xA;</xsl:text>
114 </xsl:when>
115 <!-- Avoiding a race condition in a patch -->
116 <xsl:when test="contains(string(),'debian_fixes')">
117 <xsl:value-of select="substring-before(string(),'patch')"/>
118 <xsl:text>patch -Z</xsl:text>
119 <xsl:value-of select="substring-after(string(),'patch')"/>
120 <xsl:text>&#xA;</xsl:text>
121 </xsl:when>
122 <!-- Copying the kernel config file -->
123 <xsl:when test="string() = 'make mrproper'">
124 <xsl:text>make mrproper&#xA;</xsl:text>
125 <xsl:text>cp -v ../kernel-config .config&#xA;</xsl:text>
126 </xsl:when>
127 <!-- The Coreutils and Module-Init-Tools test suites are optional -->
128 <xsl:when test="$testsuite = '0' and
129 (ancestor::sect1[@id='ch-system-coreutils'] or
130 ancestor::sect1[@id='ch-system-module-init-tools']) and
131 (contains(string(),'check') or
132 contains(string(),'dummy'))"/>
133 <!-- Fixing toolchain test suites run -->
134 <xsl:when test="string() = 'make check' or
135 string() = 'make -k check'">
136 <xsl:choose>
137 <xsl:when test="$toolchaintest = '0'"/>
138 <xsl:otherwise>
139 <xsl:text>make -k check || true</xsl:text>
140 <xsl:text>&#xA;</xsl:text>
141 </xsl:otherwise>
142 </xsl:choose>
143 </xsl:when>
144 <xsl:when test="contains(string(),'glibc-check-log')">
145 <xsl:choose>
146 <xsl:when test="$toolchaintest = '0'"/>
147 <xsl:otherwise>
148 <xsl:value-of select="substring-before(string(),'&#xA;')"/>
149 <xsl:text> || true&#xA;</xsl:text>
150 <xsl:value-of select="substring-after(string(),'&#xA;')"/>
151 <xsl:text>&#xA;</xsl:text>
152 </xsl:otherwise>
153 </xsl:choose>
154 </xsl:when>
155 <xsl:when test="contains(string(),'test_summary') or
156 contains(string(),'expect -c')">
157 <xsl:choose>
158 <xsl:when test="$toolchaintest = '0'"/>
159 <xsl:otherwise>
160 <xsl:apply-templates/>
161 <xsl:text>&#xA;</xsl:text>
162 </xsl:otherwise>
163 </xsl:choose>
164 </xsl:when>
165 <!-- Don't stop on strip run -->
166 <xsl:when test="contains(string(),'strip ')">
167 <xsl:apply-templates/>
168 <xsl:text> || true&#xA;</xsl:text>
169 </xsl:when>
170 <!-- The rest of commands -->
171 <xsl:otherwise>
172 <xsl:apply-templates/>
173 <xsl:text>&#xA;</xsl:text>
174 </xsl:otherwise>
175 </xsl:choose>
176 </xsl:template>
177
178 <xsl:template match="replaceable">
179 <xsl:choose>
180 <xsl:when test="ancestor::sect1[@id='ch-system-glibc']">
181 <xsl:text>$TIMEZONE</xsl:text>
182 </xsl:when>
183 <xsl:when test="ancestor::sect1[@id='ch-system-groff']">
184 <xsl:text>$PAGE</xsl:text>
185 </xsl:when>
186 <xsl:otherwise>
187 <xsl:text>**EDITME</xsl:text>
188 <xsl:apply-templates/>
189 <xsl:text>EDITME**</xsl:text>
190 </xsl:otherwise>
191 </xsl:choose>
192 </xsl:template>
193
194</xsl:stylesheet>
Note: See TracBrowser for help on using the repository browser.