source: LFS/lfs.xsl@ e5842d6

2.3 2.4 ablfs ablfs-more legacy new_features trunk
Last change on this file since e5842d6 was 68713c9, checked in by Manuel Canales Esparcia <manuel@…>, 17 years ago

Dump build time using Bash $SECONDS internal variable instead of using date calls + Perl-based calculations.
  • Property mode set to 100644
File size: 12.4 KB
Line 
1<?xml version="1.0"?>
2<!DOCTYPE xsl:stylesheet [
3 <!ENTITY % general-entities SYSTEM "FAKEDIR/general.ent">
4 %general-entities;
5]>
6
7<!-- $Id$ -->
8
9<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
10 xmlns:exsl="http://exslt.org/common"
11 extension-element-prefixes="exsl"
12 version="1.0">
13
14<!-- XSLT stylesheet to create shell scripts from LFS books. -->
15
16 <!-- Run test suites?
17 0 = none
18 1 = only chapter06 Glibc, GCC and Binutils testsuites
19 2 = all chapter06 testsuites
20 3 = all chapter05 and chapter06 testsuites
21 -->
22 <xsl:param name="testsuite" select="1"/>
23
24 <!-- Bomb on test suites failures?
25 n = no, I want to build the full system and review the logs
26 y = yes, bomb at the first test suite failure to can review the build dir
27 -->
28 <xsl:param name="bomb-testsuite" select="n"/>
29
30 <!-- Install vim-lang package? -->
31 <xsl:param name="vim-lang" select="y"/>
32
33 <!-- Time zone -->
34 <xsl:param name="timezone" select="GMT"/>
35
36 <!-- Page size -->
37 <xsl:param name="page" select="letter"/>
38
39 <!-- Locale settings -->
40 <xsl:param name="lang" select="C"/>
41
42 <xsl:template match="/">
43 <xsl:apply-templates select="//sect1"/>
44 </xsl:template>
45
46 <xsl:template match="sect1">
47 <xsl:if test="(../@id='chapter-temporary-tools' or
48 ../@id='chapter-building-system' or
49 ../@id='chapter-bootscripts' or
50 ../@id='chapter-bootable') and
51 count(descendant::screen/userinput) &gt; 0 and
52 count(descendant::screen/userinput) &gt;
53 count(descendant::screen[@role='nodump'])">
54 <!-- The dirs names -->
55 <xsl:variable name="pi-dir" select="../processing-instruction('dbhtml')"/>
56 <xsl:variable name="pi-dir-value" select="substring-after($pi-dir,'dir=')"/>
57 <xsl:variable name="quote-dir" select="substring($pi-dir-value,1,1)"/>
58 <xsl:variable name="dirname" select="substring-before(substring($pi-dir-value,2),$quote-dir)"/>
59 <!-- The file names -->
60 <xsl:variable name="pi-file" select="processing-instruction('dbhtml')"/>
61 <xsl:variable name="pi-file-value" select="substring-after($pi-file,'filename=')"/>
62 <xsl:variable name="filename" select="substring-before(substring($pi-file-value,2),'.html')"/>
63 <!-- The build order -->
64 <xsl:variable name="position" select="position()"/>
65 <xsl:variable name="order">
66 <xsl:choose>
67 <xsl:when test="string-length($position) = 1">
68 <xsl:text>00</xsl:text>
69 <xsl:value-of select="$position"/>
70 </xsl:when>
71 <xsl:when test="string-length($position) = 2">
72 <xsl:text>0</xsl:text>
73 <xsl:value-of select="$position"/>
74 </xsl:when>
75 <xsl:otherwise>
76 <xsl:value-of select="$position"/>
77 </xsl:otherwise>
78 </xsl:choose>
79 </xsl:variable>
80 <!-- Creating dirs and files -->
81 <exsl:document href="{$dirname}/{$order}-{$filename}" method="text">
82 <xsl:choose>
83 <xsl:when test="@id='ch-system-creatingdirs' or
84 @id='ch-system-createfiles' or
85 @id='ch-system-strippingagain'">
86 <xsl:text>#!/tools/bin/bash&#xA;set +h&#xA;</xsl:text>
87 </xsl:when>
88 <xsl:otherwise>
89 <xsl:text>#!/bin/bash&#xA;set +h&#xA;</xsl:text>
90 </xsl:otherwise>
91 </xsl:choose>
92 <xsl:if test="not(@id='ch-tools-stripping') and
93 not(@id='ch-system-strippingagain')">
94 <xsl:text>set -e&#xA;</xsl:text>
95 </xsl:if>
96 <xsl:text>&#xA;</xsl:text>
97 <xsl:if test="sect2[@role='installation']">
98 <xsl:text>cd $PKGDIR&#xA;</xsl:text>
99 <xsl:if test="@id='ch-system-vim' and $vim-lang = 'y'">
100 <xsl:text>tar -xvf ../vim-&vim-version;-lang.* --strip-components=1&#xA;</xsl:text>
101 </xsl:if>
102 </xsl:if>
103 <xsl:apply-templates select=".//para/userinput | .//screen"/>
104 <xsl:if test="$testsuite='3' and @id='ch-tools-glibc'">
105 <xsl:copy-of select="//sect1[@id='ch-system-glibc']/sect2[2]/screen[@role='nodump']"/>
106 <xsl:text>&#xA;</xsl:text>
107 </xsl:if>
108 <xsl:if test="not(@id='ch-system-chroot') and
109 not(@id='ch-system-revisedchroot')">
110 <xsl:text>echo -e "\n\nTotalseconds: $SECONDS\n"&#xA;</xsl:text>
111 </xsl:if>
112 <xsl:text>exit&#xA;</xsl:text>
113 </exsl:document>
114 </xsl:if>
115 </xsl:template>
116
117 <xsl:template match="screen">
118 <xsl:if test="child::* = userinput and not(@role = 'nodump')">
119 <xsl:apply-templates select="userinput" mode="screen"/>
120 </xsl:if>
121 </xsl:template>
122
123 <xsl:template match="para/userinput">
124 <xsl:if test="(contains(string(),'test') or
125 contains(string(),'check')) and
126 (($testsuite = '2' and
127 ancestor::chapter[@id='chapter-building-system']) or
128 $testsuite = '3')">
129 <xsl:choose>
130 <xsl:when test="$bomb-testsuite = 'n'">
131 <xsl:value-of select="substring-before(string(),'make')"/>
132 <xsl:text>make -k</xsl:text>
133 <xsl:value-of select="substring-after(string(),'make')"/>
134 <xsl:text> &gt;&gt; $TEST_LOG 2&gt;&amp;1 || true&#xA;</xsl:text>
135 </xsl:when>
136 <xsl:otherwise>
137 <xsl:apply-templates/>
138 <xsl:text> &gt;&gt; $TEST_LOG 2&gt;&amp;1</xsl:text>
139 <xsl:if test="contains(string(),' -k ')">
140 <xsl:text> || true</xsl:text>
141 </xsl:if>
142 <xsl:text>&#xA;</xsl:text>
143 </xsl:otherwise>
144 </xsl:choose>
145 </xsl:if>
146 </xsl:template>
147
148 <xsl:template match="userinput" mode="screen">
149 <xsl:choose>
150 <!-- Estandarized package formats -->
151 <xsl:when test="contains(string(),'tar.gz')">
152 <xsl:value-of select="substring-before(string(),'tar.gz')"/>
153 <xsl:text>tar.*</xsl:text>
154 <xsl:value-of select="substring-after(string(),'tar.gz')"/>
155 <xsl:text>&#xA;</xsl:text>
156 </xsl:when>
157 <!-- Avoiding a race condition in a patch -->
158 <xsl:when test="contains(string(),'debian_fixes')">
159 <xsl:value-of select="substring-before(string(),'patch')"/>
160 <xsl:text>patch -Z</xsl:text>
161 <xsl:value-of select="substring-after(string(),'patch')"/>
162 <xsl:text>&#xA;</xsl:text>
163 </xsl:when>
164 <!-- Fix Udev reinstallation after a build failure -->
165 <xsl:when test="contains(string(),'firmware,udev')">
166 <xsl:text>if [[ ! -d /lib/udev/devices ]] ; then&#xA;</xsl:text>
167 <xsl:apply-templates/>
168 <xsl:text>&#xA;fi&#xA;</xsl:text>
169 </xsl:when>
170 <!-- Setting $LANG for /etc/profile -->
171 <xsl:when test="ancestor::sect1[@id='ch-scripts-profile'] and
172 contains(string(),'export LANG=')">
173 <xsl:value-of select="substring-before(string(),'export LANG=')"/>
174 <xsl:text>export LANG=</xsl:text>
175 <xsl:value-of select="$lang"/>
176 <xsl:value-of select="substring-after(string(),'modifiers>')"/>
177 <xsl:text>&#xA;</xsl:text>
178 </xsl:when>
179 <!-- Copying the kernel config file -->
180 <xsl:when test="string() = 'make mrproper'">
181 <xsl:text>make mrproper&#xA;</xsl:text>
182 <xsl:text>cp -v ../kernel-config .config&#xA;</xsl:text>
183 </xsl:when>
184 <!-- The Bash, Coreutils, and Module-Init-Tools test suites are optional -->
185 <xsl:when test="(ancestor::sect1[@id='ch-system-coreutils'] or
186 ancestor::sect1[@id='ch-system-bash'] or
187 ancestor::sect1[@id='ch-system-module-init-tools']) and
188 (contains(string(),'check') or contains(string(),'nobody')
189 or contains(string(),'dummy'))">
190 <xsl:choose>
191 <xsl:when test="$testsuite = '0' or $testsuite = '1'"/>
192 <xsl:otherwise>
193 <xsl:if test="not(contains(string(),'check')) and
194 not(contains(string(),'make tests'))">
195 <xsl:apply-templates/>
196 <xsl:text>&#xA;</xsl:text>
197 </xsl:if>
198 <!-- Coreutils and Module-Init-Tools -->
199 <xsl:if test="contains(string(),'check')">
200 <xsl:choose>
201 <xsl:when test="$bomb-testsuite = 'n'">
202 <xsl:value-of select="substring-before(string(),'check')"/>
203 <xsl:text>-k check</xsl:text>
204 <xsl:value-of select="substring-after(string(),'check')"/>
205 <xsl:text> &gt;&gt; $TEST_LOG 2&gt;&amp;1 || true&#xA;</xsl:text>
206 </xsl:when>
207 <xsl:otherwise>
208 <xsl:apply-templates/>
209 <xsl:text> &gt;&gt; $TEST_LOG 2&gt;&amp;1</xsl:text>
210 <xsl:if test="contains(string(),' -k ')">
211 <xsl:text> || true</xsl:text>
212 </xsl:if>
213 <xsl:text>&#xA;</xsl:text>
214 </xsl:otherwise>
215 </xsl:choose>
216 </xsl:if>
217 <!-- Bash -->
218 <xsl:if test="contains(string(),'make tests')">
219 <xsl:choose>
220 <xsl:when test="$bomb-testsuite = 'n'">
221 <xsl:value-of select="substring-before(string(),'tests')"/>
222 <xsl:text>-k tests</xsl:text>
223 <xsl:value-of select="substring-after(string(),'tests')"/>
224 <xsl:text> &gt;&gt; $TEST_LOG 2&gt;&amp;1 || true&#xA;</xsl:text>
225 </xsl:when>
226 <xsl:otherwise>
227 <xsl:apply-templates/>
228 <xsl:text> &gt;&gt; $TEST_LOG 2&gt;&amp;1</xsl:text>
229 <xsl:if test="contains(string(),' -k ')">
230 <xsl:text> || true</xsl:text>
231 </xsl:if>
232 <xsl:text>&#xA;</xsl:text>
233 </xsl:otherwise>
234 </xsl:choose>
235 </xsl:if>
236 </xsl:otherwise>
237 </xsl:choose>
238 </xsl:when>
239 <!-- Fixing toolchain test suites run -->
240 <xsl:when test="string() = 'make check' or
241 string() = 'make -k check'">
242 <xsl:choose>
243 <xsl:when test="(($testsuite = '1' or $testsuite = '2') and
244 ancestor::chapter[@id='chapter-building-system']) or
245 $testsuite = '3'">
246 <xsl:choose>
247 <xsl:when test="$bomb-testsuite = 'n'">
248 <xsl:text>make -k check &gt;&gt; $TEST_LOG 2&gt;&amp;1 || true&#xA;</xsl:text>
249 </xsl:when>
250 <xsl:otherwise>
251 <xsl:apply-templates/>
252 <xsl:text> &gt;&gt; $TEST_LOG 2&gt;&amp;1</xsl:text>
253 <xsl:if test="contains(string(),' -k ')">
254 <xsl:text> || true</xsl:text>
255 </xsl:if>
256 <xsl:text>&#xA;</xsl:text>
257 </xsl:otherwise>
258 </xsl:choose>
259 </xsl:when>
260 </xsl:choose>
261 </xsl:when>
262 <xsl:when test="contains(string(),'glibc-check-log')">
263 <xsl:choose>
264 <xsl:when test="$testsuite != '0'">
265 <xsl:value-of select="substring-before(string(),'2&gt;&amp;1')"/>
266 <xsl:text>&gt;&gt; $TEST_LOG 2&gt;&amp;1 || true&#xA;</xsl:text>
267 </xsl:when>
268 </xsl:choose>
269 </xsl:when>
270 <xsl:when test="contains(string(),'test_summary') or
271 contains(string(),'expect -c')">
272 <xsl:choose>
273 <xsl:when test="(($testsuite = '1' or $testsuite = '2') and
274 ancestor::chapter[@id='chapter-building-system']) or
275 $testsuite = '3'">
276 <xsl:apply-templates/>
277 <xsl:text> &gt;&gt; $TEST_LOG&#xA;</xsl:text>
278 </xsl:when>
279 </xsl:choose>
280 </xsl:when>
281 <!-- Don't stop on strip run -->
282 <xsl:when test="contains(string(),'strip ')">
283 <xsl:apply-templates/>
284 <xsl:text> || true&#xA;</xsl:text>
285 </xsl:when>
286 <!-- The rest of commands -->
287 <xsl:otherwise>
288 <xsl:apply-templates/>
289 <xsl:text>&#xA;</xsl:text>
290 </xsl:otherwise>
291 </xsl:choose>
292 </xsl:template>
293
294 <xsl:template match="replaceable">
295 <xsl:choose>
296 <xsl:when test="ancestor::sect1[@id='ch-system-glibc']">
297 <xsl:value-of select="$timezone"/>
298 </xsl:when>
299 <xsl:when test="ancestor::sect1[@id='ch-system-groff']">
300 <xsl:value-of select="$page"/>
301 </xsl:when>
302 <xsl:otherwise>
303 <xsl:text>**EDITME</xsl:text>
304 <xsl:apply-templates/>
305 <xsl:text>EDITME**</xsl:text>
306 </xsl:otherwise>
307 </xsl:choose>
308 </xsl:template>
309
310</xsl:stylesheet>
Note: See TracBrowser for help on using the repository browser.