source: stylesheets/lfs-xsl/docbook-xsl-1.78.1/xhtml-1_1/block.xsl@ 58675ce

10.0 10.0-rc1 10.1 10.1-rc1 11.0 11.0-rc1 11.0-rc2 11.0-rc3 11.1 11.1-rc1 11.2 11.2-rc1 11.3 11.3-rc1 12.0 12.0-rc1 12.1 12.1-rc1 7.5 7.6 7.7 7.8 7.9 8.0 8.1 8.2 8.3 8.4 9.0 9.1 arm bdubbs/gcc13 ml-11.0 multilib renodr/libudev-from-systemd s6-init trunk xry111/arm64 xry111/arm64-12.0 xry111/clfs-ng xry111/lfs-next xry111/loongarch xry111/loongarch-12.0 xry111/loongarch-12.1 xry111/mips64el xry111/pip3 xry111/rust-wip-20221008 xry111/update-glibc
Last change on this file since 58675ce was 15c7d39, checked in by Matthew Burgess <matthew@…>, 11 years ago

Update stylesheets to docbook-xsl-1.78.1.

git-svn-id: ​http://svn.linuxfromscratch.org/LFS/trunk/BOOK@10355 4aa44e1e-78dd-0310-a6d2-fbcd4c07a689
  • Property mode set to 100644
File size: 16.8 KB
Line 
1<?xml version="1.0" encoding="ASCII"?><!--This file was created automatically by html2xhtml--><!--from the HTML stylesheets.--><xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xmlns="http://www.w3.org/1999/xhtml" version="1.0">
2
3<!-- ********************************************************************
4 $Id: block.xsl 9667 2012-11-26 23:10:44Z bobstayton $
5 ********************************************************************
6
7 This file is part of the XSL DocBook Stylesheet distribution.
8 See ../README or http://docbook.sf.net/release/xsl/current/ for
9 copyright and other information.
10
11 ******************************************************************** -->
12
13<!-- ==================================================================== -->
14<!-- What should we do about styling blockinfo? -->
15
16<xsl:template match="blockinfo|info">
17 <!-- suppress -->
18</xsl:template>
19
20<!-- ==================================================================== -->
21
22<xsl:template name="block.object">
23 <div>
24 <xsl:call-template name="common.html.attributes"/>
25 <xsl:call-template name="id.attribute"/>
26 <xsl:call-template name="anchor"/>
27 <xsl:apply-templates/>
28 </div>
29</xsl:template>
30
31<!-- ==================================================================== -->
32
33<xsl:template match="para">
34 <xsl:call-template name="paragraph">
35 <xsl:with-param name="class">
36 <xsl:if test="@role and $para.propagates.style != 0">
37 <xsl:value-of select="@role"/>
38 </xsl:if>
39 </xsl:with-param>
40 <xsl:with-param name="content">
41 <xsl:if test="position() = 1 and parent::listitem">
42 <xsl:call-template name="anchor">
43 <xsl:with-param name="node" select="parent::listitem"/>
44 </xsl:call-template>
45 </xsl:if>
46
47 <xsl:call-template name="anchor"/>
48 <xsl:apply-templates/>
49 </xsl:with-param>
50 </xsl:call-template>
51</xsl:template>
52
53<xsl:template name="paragraph">
54 <xsl:param name="class" select="''"/>
55 <xsl:param name="content"/>
56
57 <xsl:variable name="p">
58 <p>
59 <xsl:call-template name="id.attribute"/>
60 <xsl:choose>
61 <xsl:when test="$class != ''">
62 <xsl:call-template name="common.html.attributes">
63 <xsl:with-param name="class" select="$class"/>
64 </xsl:call-template>
65 </xsl:when>
66 <xsl:otherwise>
67 <xsl:call-template name="common.html.attributes">
68 <xsl:with-param name="class" select="''"/>
69 </xsl:call-template>
70 </xsl:otherwise>
71 </xsl:choose>
72
73 <xsl:copy-of select="$content"/>
74 </p>
75 </xsl:variable>
76
77 <xsl:choose>
78 <xsl:when test="$html.cleanup != 0">
79 <xsl:call-template name="unwrap.p">
80 <xsl:with-param name="p" select="$p"/>
81 </xsl:call-template>
82 </xsl:when>
83 <xsl:otherwise>
84 <xsl:copy-of select="$p"/>
85 </xsl:otherwise>
86 </xsl:choose>
87</xsl:template>
88
89<xsl:template match="simpara">
90 <!-- see also listitem/simpara in lists.xsl -->
91 <p>
92 <xsl:call-template name="id.attribute"/>
93 <xsl:call-template name="locale.html.attributes"/>
94 <xsl:if test="@role and $para.propagates.style != 0">
95 <xsl:apply-templates select="." mode="class.attribute">
96 <xsl:with-param name="class" select="@role"/>
97 </xsl:apply-templates>
98 </xsl:if>
99
100 <xsl:call-template name="anchor"/>
101 <xsl:apply-templates/>
102 </p>
103</xsl:template>
104
105<xsl:template match="formalpara">
106 <xsl:call-template name="paragraph">
107 <xsl:with-param name="class">
108 <xsl:if test="@role and $para.propagates.style != 0">
109 <xsl:value-of select="@role"/>
110 </xsl:if>
111 </xsl:with-param>
112 <xsl:with-param name="content">
113 <xsl:call-template name="anchor"/>
114 <xsl:apply-templates/>
115 </xsl:with-param>
116 </xsl:call-template>
117</xsl:template>
118
119<!-- Only use title from info -->
120<xsl:template match="formalpara/info">
121 <xsl:apply-templates select="title"/>
122</xsl:template>
123
124<xsl:template match="formalpara/title|formalpara/info/title">
125 <xsl:variable name="titleStr">
126 <xsl:apply-templates/>
127 </xsl:variable>
128 <xsl:variable name="lastChar">
129 <xsl:if test="$titleStr != ''">
130 <xsl:value-of select="substring($titleStr,string-length($titleStr),1)"/>
131 </xsl:if>
132 </xsl:variable>
133
134 <xsl:choose>
135 <xsl:when test="$make.clean.html != 0">
136 <span class="formalpara-title">
137 <xsl:copy-of select="$titleStr"/>
138 <xsl:if test="$lastChar != '' and not(contains($runinhead.title.end.punct, $lastChar))">
139 <xsl:value-of select="$runinhead.default.title.end.punct"/>
140 </xsl:if>
141 <xsl:text>&#160;</xsl:text>
142 </span>
143 </xsl:when>
144 <xsl:otherwise>
145 <strong>
146 <xsl:copy-of select="$titleStr"/>
147 <xsl:if test="$lastChar != '' and not(contains($runinhead.title.end.punct, $lastChar))">
148 <xsl:value-of select="$runinhead.default.title.end.punct"/>
149 </xsl:if>
150 <xsl:text>&#160;</xsl:text>
151 </strong>
152 </xsl:otherwise>
153 </xsl:choose>
154</xsl:template>
155
156<xsl:template match="formalpara/para">
157 <xsl:apply-templates/>
158</xsl:template>
159
160<!-- ==================================================================== -->
161
162<xsl:template match="blockquote">
163 <div>
164 <xsl:call-template name="common.html.attributes"/>
165 <xsl:call-template name="id.attribute"/>
166 <xsl:call-template name="anchor"/>
167
168 <xsl:choose>
169 <xsl:when test="attribution">
170 <table border="{$table.border.off}" class="blockquote">
171 <xsl:if test="$css.decoration != 0">
172 <xsl:attribute name="style">
173 <xsl:text>width: 100%; cellspacing: 0; cellpadding: 0;</xsl:text>
174 </xsl:attribute>
175 </xsl:if>
176 <xsl:if test="$div.element != 'section'">
177 <xsl:attribute name="summary">Block quote</xsl:attribute>
178 </xsl:if>
179 <tr>
180 <td valign="top">&#160;</td>
181 <td valign="top">
182 <xsl:apply-templates select="child::*[local-name(.)!='attribution']"/>
183 </td>
184 <td valign="top">&#160;</td>
185 </tr>
186 <tr>
187 <td valign="top">&#160;</td>
188 <td colspan="2" align="{$direction.align.end}" valign="top">
189 <xsl:text>--</xsl:text>
190 <xsl:apply-templates select="attribution"/>
191 </td>
192 </tr>
193 </table>
194 </xsl:when>
195 <xsl:otherwise>
196 <blockquote>
197 <xsl:call-template name="common.html.attributes"/>
198 <xsl:apply-templates/>
199 </blockquote>
200 </xsl:otherwise>
201 </xsl:choose>
202 </div>
203</xsl:template>
204
205<xsl:template match="blockquote/title|blockquote/info/title">
206 <xsl:choose>
207 <xsl:when test="$make.clean.html != 0">
208 <div class="blockquote-title">
209 <xsl:apply-templates/>
210 </div>
211 </xsl:when>
212 <xsl:otherwise>
213 <div class="blockquote-title">
214 <p>
215 <strong>
216 <xsl:apply-templates/>
217 </strong>
218 </p>
219 </div>
220 </xsl:otherwise>
221 </xsl:choose>
222</xsl:template>
223
224<!-- Use an em dash per Chicago Manual of Style and https://sourceforge.net/tracker/index.php?func=detail&aid=2793878&group_id=21935&atid=373747 -->
225<xsl:template match="epigraph">
226 <div>
227 <xsl:call-template name="common.html.attributes"/>
228 <xsl:call-template name="id.attribute"/>
229 <xsl:apply-templates select="para|simpara|formalpara|literallayout"/>
230 <xsl:if test="attribution">
231 <div class="attribution">
232 <span>&#8212;<xsl:apply-templates select="attribution"/></span>
233 </div>
234 </xsl:if>
235 </div>
236</xsl:template>
237
238<xsl:template match="attribution">
239 <span>
240 <xsl:call-template name="common.html.attributes"/>
241 <xsl:call-template name="id.attribute"/>
242 <xsl:apply-templates/>
243 </span>
244</xsl:template>
245
246<!-- ==================================================================== -->
247
248<xsl:template match="sidebar">
249 <div>
250 <xsl:call-template name="common.html.attributes"/>
251 <xsl:call-template name="id.attribute"/>
252 <xsl:call-template name="anchor"/>
253 <xsl:call-template name="sidebar.titlepage"/>
254 <xsl:apply-templates/>
255 </div>
256</xsl:template>
257
258<xsl:template match="abstract/title|sidebar/title">
259</xsl:template>
260
261<xsl:template match="sidebar/sidebarinfo|sidebar/info"/>
262
263<xsl:template match="abstract">
264 <div>
265 <xsl:call-template name="common.html.attributes"/>
266 <xsl:call-template name="anchor"/>
267 <xsl:call-template name="formal.object.heading">
268 <xsl:with-param name="title">
269 <xsl:apply-templates select="." mode="title.markup">
270 <xsl:with-param name="allow-anchors" select="'1'"/>
271 </xsl:apply-templates>
272 </xsl:with-param>
273 </xsl:call-template>
274 <xsl:apply-templates/>
275 </div>
276</xsl:template>
277
278<!-- ==================================================================== -->
279
280<xsl:template match="msgset">
281 <xsl:apply-templates/>
282</xsl:template>
283
284<xsl:template match="msgentry">
285 <xsl:call-template name="block.object"/>
286</xsl:template>
287
288<xsl:template match="simplemsgentry">
289 <xsl:call-template name="block.object"/>
290</xsl:template>
291
292<xsl:template match="msg">
293 <xsl:call-template name="block.object"/>
294</xsl:template>
295
296<xsl:template match="msgmain">
297 <xsl:apply-templates/>
298</xsl:template>
299
300<xsl:template match="msgmain/title">
301 <xsl:choose>
302 <xsl:when test="$make.clean.html != 0">
303 <span class="msgmain-title">
304 <xsl:apply-templates/>
305 </span>
306 </xsl:when>
307 <xsl:otherwise>
308 <strong><xsl:apply-templates/></strong>
309 </xsl:otherwise>
310 </xsl:choose>
311</xsl:template>
312
313<xsl:template match="msgsub">
314 <xsl:apply-templates/>
315</xsl:template>
316
317<xsl:template match="msgsub/title">
318 <xsl:choose>
319 <xsl:when test="$make.clean.html != 0">
320 <span class="msgsub-title">
321 <xsl:apply-templates/>
322 </span>
323 </xsl:when>
324 <xsl:otherwise>
325 <strong><xsl:apply-templates/></strong>
326 </xsl:otherwise>
327 </xsl:choose>
328</xsl:template>
329
330<xsl:template match="msgrel">
331 <xsl:apply-templates/>
332</xsl:template>
333
334<xsl:template match="msgrel/title">
335 <xsl:choose>
336 <xsl:when test="$make.clean.html != 0">
337 <span class="msgrel-title">
338 <xsl:apply-templates/>
339 </span>
340 </xsl:when>
341 <xsl:otherwise>
342 <strong><xsl:apply-templates/></strong>
343 </xsl:otherwise>
344 </xsl:choose>
345</xsl:template>
346
347<xsl:template match="msgtext">
348 <xsl:apply-templates/>
349</xsl:template>
350
351<xsl:template match="msginfo">
352 <xsl:call-template name="block.object"/>
353</xsl:template>
354
355<xsl:template match="msglevel">
356 <xsl:choose>
357 <xsl:when test="$make.clean.html != 0">
358 <div class="msglevel">
359 <span class="msglevel-title">
360 <xsl:call-template name="gentext.template">
361 <xsl:with-param name="context" select="'msgset'"/>
362 <xsl:with-param name="name" select="'MsgLevel'"/>
363 </xsl:call-template>
364 </span>
365 <xsl:apply-templates/>
366 </div>
367 </xsl:when>
368 <xsl:otherwise>
369 <p>
370 <strong>
371 <xsl:call-template name="gentext.template">
372 <xsl:with-param name="context" select="'msgset'"/>
373 <xsl:with-param name="name" select="'MsgLevel'"/>
374 </xsl:call-template>
375 </strong>
376 <xsl:apply-templates/>
377 </p>
378 </xsl:otherwise>
379 </xsl:choose>
380</xsl:template>
381
382<xsl:template match="msgorig">
383 <xsl:choose>
384 <xsl:when test="$make.clean.html != 0">
385 <div class="msgorig">
386 <span class="msgorig-title">
387 <xsl:call-template name="gentext.template">
388 <xsl:with-param name="context" select="'msgset'"/>
389 <xsl:with-param name="name" select="'MsgOrig'"/>
390 </xsl:call-template>
391 </span>
392 <xsl:apply-templates/>
393 </div>
394 </xsl:when>
395 <xsl:otherwise>
396 <p>
397 <strong>
398 <xsl:call-template name="gentext.template">
399 <xsl:with-param name="context" select="'msgset'"/>
400 <xsl:with-param name="name" select="'MsgOrig'"/>
401 </xsl:call-template>
402 </strong>
403 <xsl:apply-templates/>
404 </p>
405 </xsl:otherwise>
406 </xsl:choose>
407</xsl:template>
408
409<xsl:template match="msgaud">
410 <xsl:choose>
411 <xsl:when test="$make.clean.html != 0">
412 <div class="msgaud">
413 <span class="msgaud-title">
414 <xsl:call-template name="gentext.template">
415 <xsl:with-param name="context" select="'msgset'"/>
416 <xsl:with-param name="name" select="'MsgAud'"/>
417 </xsl:call-template>
418 </span>
419 <xsl:apply-templates/>
420 </div>
421 </xsl:when>
422 <xsl:otherwise>
423 <p>
424 <strong>
425 <xsl:call-template name="gentext.template">
426 <xsl:with-param name="context" select="'msgset'"/>
427 <xsl:with-param name="name" select="'MsgAud'"/>
428 </xsl:call-template>
429 </strong>
430 <xsl:apply-templates/>
431 </p>
432 </xsl:otherwise>
433 </xsl:choose>
434</xsl:template>
435
436<xsl:template match="msgexplan">
437 <xsl:call-template name="block.object"/>
438</xsl:template>
439
440<xsl:template match="msgexplan/title">
441 <xsl:choose>
442 <xsl:when test="$make.clean.html != 0">
443 <div class="msgexplan">
444 <span class="msgexplan-title">
445 <xsl:apply-templates/>
446 </span>
447 </div>
448 </xsl:when>
449 <xsl:otherwise>
450 <p>
451 <strong>
452 <xsl:apply-templates/>
453 </strong>
454 </p>
455 </xsl:otherwise>
456 </xsl:choose>
457</xsl:template>
458
459<!-- ==================================================================== -->
460
461<xsl:template match="revhistory">
462 <div>
463 <xsl:call-template name="common.html.attributes"/>
464 <xsl:call-template name="id.attribute"/>
465 <table>
466 <xsl:if test="$css.decoration != 0">
467 <xsl:attribute name="style">
468 <xsl:text>border-style:solid; width:100%;</xsl:text>
469 </xsl:attribute>
470 </xsl:if>
471 <!-- include summary attribute if not HTML5 -->
472 <xsl:if test="$div.element != 'section'">
473 <xsl:attribute name="summary">
474 <xsl:call-template name="gentext">
475 <xsl:with-param name="key">revhistory</xsl:with-param>
476 </xsl:call-template>
477 </xsl:attribute>
478 </xsl:if>
479 <tr>
480 <th align="{$direction.align.start}" valign="top" colspan="3">
481 <strong>
482 <xsl:call-template name="gentext">
483 <xsl:with-param name="key" select="'RevHistory'"/>
484 </xsl:call-template>
485 </strong>
486 </th>
487 </tr>
488 <xsl:apply-templates/>
489 </table>
490 </div>
491</xsl:template>
492
493<xsl:template match="revhistory/revision">
494 <xsl:variable name="revnumber" select="revnumber"/>
495 <xsl:variable name="revdate" select="date"/>
496 <xsl:variable name="revauthor" select="authorinitials|author"/>
497 <xsl:variable name="revremark" select="revremark|revdescription"/>
498 <tr>
499 <td align="{$direction.align.start}">
500 <xsl:if test="$revnumber">
501 <xsl:call-template name="gentext">
502 <xsl:with-param name="key" select="'Revision'"/>
503 </xsl:call-template>
504 <xsl:call-template name="gentext.space"/>
505 <xsl:apply-templates select="$revnumber"/>
506 </xsl:if>
507 </td>
508 <td align="{$direction.align.start}">
509 <xsl:apply-templates select="$revdate"/>
510 </td>
511 <xsl:choose>
512 <xsl:when test="count($revauthor)=0">
513 <td align="{$direction.align.start}">
514 <xsl:call-template name="dingbat">
515 <xsl:with-param name="dingbat">nbsp</xsl:with-param>
516 </xsl:call-template>
517 </td>
518 </xsl:when>
519 <xsl:otherwise>
520 <td align="{$direction.align.start}">
521 <xsl:for-each select="$revauthor">
522 <xsl:apply-templates select="."/>
523 <xsl:if test="position() != last()">
524 <xsl:text>, </xsl:text>
525 </xsl:if>
526 </xsl:for-each>
527 </td>
528 </xsl:otherwise>
529 </xsl:choose>
530 </tr>
531 <xsl:if test="$revremark">
532 <tr>
533 <td align="{$direction.align.start}" colspan="3">
534 <xsl:apply-templates select="$revremark"/>
535 </td>
536 </tr>
537 </xsl:if>
538</xsl:template>
539
540<xsl:template match="revision/revnumber">
541 <xsl:apply-templates/>
542</xsl:template>
543
544<xsl:template match="revision/date">
545 <xsl:apply-templates/>
546</xsl:template>
547
548<xsl:template match="revision/authorinitials">
549 <xsl:text>, </xsl:text>
550 <xsl:apply-templates/>
551</xsl:template>
552
553<xsl:template match="revision/authorinitials[1]" priority="2">
554 <xsl:apply-templates/>
555</xsl:template>
556
557<xsl:template match="revision/revremark">
558 <xsl:apply-templates/>
559</xsl:template>
560
561<xsl:template match="revision/revdescription">
562 <xsl:apply-templates/>
563</xsl:template>
564
565<!-- ==================================================================== -->
566
567<xsl:template match="ackno|acknowledgements[parent::article]">
568 <xsl:call-template name="block.object"/>
569</xsl:template>
570
571<!-- ==================================================================== -->
572
573<xsl:template match="highlights">
574 <xsl:call-template name="block.object"/>
575</xsl:template>
576
577<!-- ==================================================================== -->
578
579</xsl:stylesheet>
Note: See TracBrowser for help on using the repository browser.